[gentoo-commits] gentoo-x86 commit in sys-apps/util-linux: ChangeLog util-linux-2.14.1.ebuild

[Mike Frysinger (vapier)]

vapier      08/10/20 07:23:30

  Modified:             ChangeLog
  Added:                util-linux-2.14.1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.26.2 x86_64)

Revision  Changes    Path
1.243                sys-apps/util-linux/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.243&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.243&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?r1=1.242&r2=1.243

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v
retrieving revision 1.242
retrieving revision 1.243
diff -u -r1.242 -r1.243
--- ChangeLog	23 Aug 2008 06:28:29 -0000	1.242
+++ ChangeLog	20 Oct 2008 07:23:30 -0000	1.243
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.242 2008/08/23 06:28:29 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.243 2008/10/20 07:23:30 vapier Exp $
+
+*util-linux-2.14.1 (20 Oct 2008)
+
+  20 Oct 2008; Mike Frysinger <vapier@g.o> +util-linux-2.14.1.ebuild:
+  Version bump.
 
   23 Aug 2008; Doug Goldstein <cardoe@g.o> metadata.xml:
   add GLEP 56 USE flag desc from use.local.desc



1.1                  sys-apps/util-linux/util-linux-2.14.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/util-linux-2.14.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/util-linux-2.14.1.ebuild?rev=1.1&content-type=text/plain

Index: util-linux-2.14.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.14.1.ebuild,v 1.1 2008/10/20 07:23:30 vapier Exp $

EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
inherit eutils
[[ ${PV} == "9999" ]] && inherit git

MY_PV=${PV/_/-}
MY_P=${PN}-ng-${MY_PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Various useful Linux utilities"
HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
if [[ ${PV} == "9999" ]] ; then
	SRC_URI=""
else
	SRC_URI="http://www.kernel.org/pub/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.14-20080624.diff.bz2 )"
#		loop-aes? ( http://loop-aes.sourceforge.net/loop-AES/loop-AES-v3.2c.tar.bz2 )"
fi

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="crypt loop-aes nls old-linux selinux slang unicode"

RDEPEND="!sys-process/schedutils
	!sys-apps/setarch
	>=sys-libs/ncurses-5.2-r2
	>=sys-fs/e2fsprogs-1.34
	selinux? ( sys-libs/libselinux )
	slang? ( sys-libs/slang )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/os-headers"

src_unpack() {
	if [[ ${PV} == "9999" ]] ; then
		git_src_unpack
		cd "${S}"
		./autogen.sh || die
	else
		unpack ${A}
		cd "${S}"
		#epatch "${FILESDIR}"/${PN}-2.13-uclibc.patch #203711
		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-2.14-20080624.diff
		epatch "${FILESDIR}"/${PN}-2.13.1-no-a.out.patch #221939
	fi
}

src_compile() {
	econf \
		--with-fsprobe=blkid \
		$(use_enable nls) \
		--enable-agetty \
		--enable-cramfs \
		$(use_enable old-linux elvtune) \
		--disable-init \
		--disable-kill \
		--disable-last \
		--disable-mesg \
		--enable-partx \
		--enable-raw \
		--enable-rdev \
		--enable-rename \
		--disable-reset \
		--disable-login-utils \
		--enable-schedutils \
		--disable-wall \
		--enable-write \
		--without-pam \
		$(use unicode || echo --with-ncurses) \
		$(use_with selinux) \
		$(use_with slang) \
		|| die "configure failed"
	emake || die "emake failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "install failed"
	dodoc AUTHORS NEWS README* TODO docs/*

	if use crypt ; then
		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
	fi
}

pkg_postinst() {
	ewarn "USE=crypt has been changed to USE=loop-aes.  If you need"
	ewarn "support for it, make sure to update your USE accordingly."
}