[gentoo-commits] gentoo-x86 commit in net-im/bitlbee: ChangeLog bitlbee-1.1.ebuild

[Cedric Krier (cedk)]

cedk        07/09/18 21:16:12

  Modified:             ChangeLog
  Added:                bitlbee-1.1.ebuild
  Log:
  Version bump
  (Portage version: 2.1.2.12)

Revision  Changes    Path
1.85                 net-im/bitlbee/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/bitlbee/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/bitlbee/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/bitlbee/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	18 Sep 2007 20:39:50 -0000	1.84
+++ ChangeLog	18 Sep 2007 21:16:12 -0000	1.85
@@ -1,6 +1,11 @@
 # ChangeLog for net-im/bitlbee
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v 1.84 2007/09/18 20:39:50 cedk Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/ChangeLog,v 1.85 2007/09/18 21:16:12 cedk Exp $
+
+*bitlbee-1.1 (18 Sep 2007)
+
+  18 Sep 2007; Cédric Krier <cedk@g.o> +bitlbee-1.1.ebuild:
+  Version bump
 
   18 Sep 2007; Cédric Krier <cedk@g.o> bitlbee-1.0.4.ebuild:
   Fix ssl option for bug #134202



1.1                  net-im/bitlbee/bitlbee-1.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/bitlbee/bitlbee-1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-im/bitlbee/bitlbee-1.1.ebuild?rev=1.1&content-type=text/plain

Index: bitlbee-1.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/bitlbee/bitlbee-1.1.ebuild,v 1.1 2007/09/18 21:16:12 cedk Exp $

inherit eutils toolchain-funcs

MY_P="${P}dev"

DESCRIPTION="irc to IM gateway that support multiple IM protocols"
HOMEPAGE="http://www.bitlbee.org/"
SRC_URI="http://get.bitlbee.org/src/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
IUSE="debug jabber msn oscar yahoo gnutls ssl nss xinetd ipv6 ldap"

DEPEND=">=dev-libs/glib-2.4
	msn? ( gnutls? ( net-libs/gnutls )
		ssl? ( dev-libs/openssl )
		nss? ( dev-libs/nss ) )
	jabber? ( gnutls? ( net-libs/gnutls )
			ssl? ( dev-libs/openssl )
			nss? ( dev-libs/nss ) )
	ldap? ( net-nds/openldap )"
RDEPEND=$DEPEND

S="${WORKDIR}/${MY_P}"

no_flags_die() {
	eerror ""
	eerror "Please choose a protocol or protocols to use with"
	eerror "bitlbee by enabling the useflag for the protocol"
	eerror "desired."
	eerror ""
	eerror " Valid useflags are;"
	eerror " jabber, msn, oscar and yahoo"
	die "No IM protocols selected!"
}

pkg_setup() {
	elog "Note: Support for all IM protocols are controlled by use flags."
	elog "      Make sure you've enabled the flags you want."
	elog ""

	# Warn but not die if jabber is enabled but SSL is not
	if ( use jabber && ( use !ssl && use !gnutls && use !nss ) ); then
		ewarn ""
		ewarn "You have enabled support for Jabber but do not have SSL"
		ewarn "support enabled.  This *will* prevent bitlbee from being"
		ewarn "able to connect to SSL enabled Jabber servers.  If you need to"
		ewarn "connect to Jabber over SSL, enable one of the following use"
		ewarn "flags: gnutls, nss ssl"
		ewarn ""
	fi

	# At the request of upstream, die if MSN Messenger support is enabled
	# but no SSL support has been enabled
	if  ( use msn && ( use !ssl && use !gnutls && use !nss ) ); then
		eerror ""
		eerror "In order to enable support for the MSN Messenger protocol,"
		eerror "SSL support needs to be enabled.  Please enable the ssl,"
		eerror "gnutls or nss use flags to provide SSL support".
		die "MSN support enabled without any SSL support enabled."
	fi

	if use ldap; then
		ewarn ""
		ewarn "LDAP support is a work in progress "
		ewarn "and does NOT work AT ALL right now."
		ewarn ""
	fi

	use jabber || use msn || use oscar || use yahoo || no_flags_die

	enewgroup bitlbee
	enewuser bitlbee -1 -1 /var/lib/bitlbee bitlbee
}

src_unpack() {
	unpack ${MY_P}.tar.gz
	cd "${S}"

	sed -i \
		-e "s@/usr/local/sbin/bitlbee@/usr/sbin/bitlbee@" \
		-e "s/nobody/bitlbee/" \
		-e "s/}/	disable         = yes\n}/" \
		doc/bitlbee.xinetd || die "sed failed"
}

src_compile() {
	# setup protocol, ipv6 and debug
	local myconf
	if use debug; then
		myconf="${myconf} --debug=1"
	else
		myconf="${myconf} --debug=0"
	fi
	if use ipv6; then
		myconf="${myconf} --ipv6=1"
	else
		myconf="${myconf} --ipv6=0"
	fi
	if use msn; then
		myconf="${myconf} --msn=1"
	else
		myconf="${myconf} --msn=0"
	fi
	if use jabber; then
		myconf="${myconf} --jabber=1"
	else
		myconf="${myconf} --jabber=0"
	fi
	if use oscar; then
		myconf="${myconf} --oscar=1"
	else
		myconf="${myconf} --oscar=0"
	fi
	if use yahoo; then
		myconf="${myconf} --yahoo=1"
	else
		myconf="${myconf} --yahoo=0"
	fi
	if use ldap; then
		myconf="${myconf} --ldap=1"
	else
		myconf="${myconf} --ldap=0"
	fi

	# setup ssl use flags
	use ssl && use gnutls && myconf="${myconf} --ssl=gnutls"
	use ssl && use nss && myconf="${myconf} --ssl=nss"
	use ssl && use !gnutls && use !nss && \
		myconf="${myconf} --ssl=openssl"

	if ( use jabber || use msn ) \
		&&  use !ssl && use !gnutls && use !nss; then
		myconf="${myconf} --ssl=bogus"
	fi

	# NOTE: bitlbee's configure script is not an autotool creation,
	# so that is why we don't use econf.

	./configure --prefix=/usr --datadir=/usr/share/bitlbee \
		--etcdir=/etc/bitlbee --strip=0 ${myconf} || die "econf failed"

	sed -i \
		-e "s/CFLAGS=.*$/CFLAGS=${CFLAGS}/" \
		Makefile.settings || die "sed failed"

	emake || die "make failed"

	# make bitlbeed forking server
	cd utils
	$(tc-getCC) ${CFLAGS} bitlbeed.c -o bitlbeed \
		|| die "bitlbeed failed to compile"
}

src_install() {
	make install DESTDIR=${D} || die "install failed"
	make install-etc DESTDIR=${D} || die "install failed"
	make install-doc DESTDIR=${D} || die "install failed"
	keepdir /var/lib/bitlbee
	fperms 700 /var/lib/bitlbee
	fowners bitlbee:bitlbee /var/lib/bitlbee

	dodoc doc/{AUTHORS,CHANGES,CREDITS,FAQ,README}
	dodoc doc/user-guide/user-guide.txt
	dohtml -A xml doc/user-guide/*.xml
	dohtml -A xsl doc/user-guide/*.xsl
	dohtml doc/user-guide/*.html

	doman doc/bitlbee.8 doc/bitlbee.conf.5

	dobin utils/bitlbeed

	if use xinetd; then
		insinto /etc/xinetd.d
		newins doc/bitlbee.xinetd bitlbee
	fi

	newinitd "${FILESDIR}"/bitlbeed.initd bitlbeed || die
	newconfd "${FILESDIR}"/bitlbeed.confd2 bitlbeed || die

	keepdir /var/run/bitlbeed

	dodir /usr/share/bitlbee
	insinto /usr/share/bitlbee
	cd utils
	doins centericq2bitlbee.sh convert_gnomeicu.txt create_nicksfile.pl
	doins bitlbee-ctl.pl
}

pkg_postinst() {
	chown -R bitlbee:bitlbee ${ROOT}/var/lib/bitlbee

	elog "The utils included in bitlbee (other than bitlbeed) are now"
	elog "located in /usr/share/bitlbee"
	elog
	elog "NOTE: The IRSSI script is no longer provided by BitlBee."
}



-- 
gentoo-commits@g.o mailing list