flameeyes    08/03/05 17:06:16

  Modified:             ChangeLog
  Added:                pambase-20080305.ebuild
  Removed:              pambase-20080301.ebuild
  Log:
  Bump to avoid calling git during ebuild phases. Closes bug #212395.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.15                 sys-auth/pambase/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-auth/pambase/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-auth/pambase/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-auth/pambase/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/pambase/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	4 Mar 2008 23:09:32 -0000	1.14
+++ ChangeLog	5 Mar 2008 17:06:15 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for sys-auth/pambase
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/ChangeLog,v 1.14 2008/03/04 23:09:32 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/ChangeLog,v 1.15 2008/03/05 17:06:15 flameeyes Exp $
+
+*pambase-20080305 (05 Mar 2008)
+
+  05 Mar 2008; Diego Pettenò <flameeyes@g.o>
+  -pambase-20080301.ebuild, +pambase-20080305.ebuild:
+  Bump to avoid calling git during ebuild phases. Closes bug #212395.
 
   04 Mar 2008; Brent Baude <ranger@g.o> ChangeLog:
   keyworded ~arch for ppc64, bug 210769



1.1                  sys-auth/pambase/pambase-20080305.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-auth/pambase/pambase-20080305.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-auth/pambase/pambase-20080305.ebuild?rev=1.1&content-type=text/plain

Index: pambase-20080305.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/pambase/pambase-20080305.ebuild,v 1.1 2008/03/05 17:06:15 flameeyes Exp $

inherit eutils

DESCRIPTION="PAM base configuration files"
SRC_URI="http://www.flameeyes.eu/gentoo-distfiles/${P}.tar.bz2"
HOMEPAGE="http://www.gentoo.org/proj/en/base/pam/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~hppa ~ppc64 ~x86"
IUSE="debug cracklib consolekit gnome selinux"

RDEPEND="
	|| (
		>=sys-libs/pam-0.99.9.0-r1
		( sys-auth/openpam
		  || ( sys-freebsd/freebsd-pam-modules sys-netbsd/netbsd-pam-modules )
		)
	)
	cracklib? ( >=sys-libs/pam-0.99 )
	consolekit? ( sys-auth/consolekit )
	gnome? ( >=gnome-base/gnome-keyring-2.20 )
	selinux? ( >=sys-libs/pam-0.99 )
	!<sys-freebsd/freebsd-pam-modules-6.2-r1
	!<sys-libs/pam-0.99.9.0-r1"
DEPEND=""

RESTRICT="binchecks"

pkg_setup() {
	if use cracklib && ! built_with_use sys-libs/pam cracklib; then
		eerror "To enable cracklib support in the main PAM configuration"
		eerror "you need to enable cracklib USE flag on sys-libs/pam"
		eerror "first."
		die "Missing pam_cracklib"
	fi

	if use selinux && ! built_with_use sys-libs/pam selinux; then
		eerror "To enable selinux support in the main PAM configuration"
		eerror "you need to enable selinux USE flag on sys-libs/pam"
		eerror "first."
		die "Missing pam_selinux"
	fi

	if use consolekit && ! built_with_use sys-auth/consolekit pam; then
		eerror "To enable ConsoleKit support in the main PAM configuration"
		eerror "you need to enable pam USE flag on sys-auth/consolekit"
		eerror "first."
		die "Missing pam_ck_connector"
	fi

	if use gnome && ! built_with_use gnome-base/gnome-keyring pam; then
		eerror "To enable GNOME Keyring support in the main PAM configuration"
		eerror "you need to enable pam USE flag on gnome-base/gnome-keyring"
		eerror "first."
		die "Missing pam_gnome_keyring"
	fi
}

src_compile() {
	has_version sys-libs/pam && implementation="linux-pam"
	has_version sys-auth/openpam && implementation="openpam"

	emake \
		GIT=true \
		DEBUG=$(use debug && echo yes || echo no) \
		CRACKLIB=$(use cracklib && echo yes || echo no) \
		CONSOLEKIT=$(use consolekit && echo yes || echo no) \
		GNOME_KEYRING=$(use gnome && echo yes || echo no) \
		SELINUX=$(use selinux && echo yes || echo no) \
		IMPLEMENTATION=${implementation} \
		|| die "emake failed"
}

src_install() {
	emake GIT=true DESTDIR="${D}" install || die "emake install failed"
}



-- 
gentoo-commits@g.o mailing list