[gentoo-commits] gentoo-x86 commit in sci-electronics/gspiceui: ChangeLog gspiceui-1.0.0.ebuild

[Thomas Beierlein (tomjbe)]

tomjbe      12/02/11 13:50:23

  Modified:             ChangeLog
  Added:                gspiceui-1.0.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.45/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  sci-electronics/gspiceui/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/gspiceui/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/gspiceui/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/gspiceui/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/gspiceui/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	15 Jul 2011 22:56:38 -0000	1.6
+++ ChangeLog	11 Feb 2012 13:50:23 -0000	1.7
@@ -1,6 +1,12 @@
 # ChangeLog for sci-electronics/gspiceui
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gspiceui/ChangeLog,v 1.6 2011/07/15 22:56:38 calchan Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gspiceui/ChangeLog,v 1.7 2012/02/11 13:50:23 tomjbe Exp $
+
+*gspiceui-1.0.0 (11 Feb 2012)
+
+  11 Feb 2012; Thomas Beierlein <tomjbe@g.o> +gspiceui-1.0.0.ebuild,
+  +files/gspiceui-1.0.0-flags.patch:
+  Version bump
 
   15 Jul 2011; Denis Dupeyron <calchan@g.o> gspiceui-0.9.99.ebuild,
   gspiceui-0.9.99-r1.ebuild:



1.1                  sci-electronics/gspiceui/gspiceui-1.0.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/gspiceui/gspiceui-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/gspiceui/gspiceui-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: gspiceui-1.0.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/gspiceui/gspiceui-1.0.0.ebuild,v 1.1 2012/02/11 13:50:23 tomjbe Exp $

EAPI="2"

WX_GTK_VER="2.8"
inherit eutils wxwidgets

MY_P="${PN}-v${PV}0"

DESCRIPTION="GUI frontend for Ngspice and Gnucap"
HOMEPAGE="http://www.geda.seul.org/tools/gspiceui/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="examples schematics waveform"

DEPEND="x11-libs/wxGTK:2.8[X]
	sci-electronics/electronics-menu"
RDEPEND="${DEPEND}
	|| ( sci-electronics/ngspice sci-electronics/gnucap )
	waveform? ( sci-electronics/gwave )
	schematics? ( sci-electronics/geda )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Use Gentoo LDFLAGS and CXXFLAGS
	epatch "${FILESDIR}/${P}-flags.patch"

	# Adjusting the doc path at src/main/HelpTasks.cpp
	sed -i -e \
		"s:/share/gspiceui/html/User-Manual.html:/share/doc/${PF}/html/User-Manual.html:g" \
		src/main/HelpTasks.cpp || die
}

src_install() {
	dobin bin/gspiceui || die
	dodoc ChangeLog ReadMe ToDo || die
	doman gspiceui.1 || die
	newicon src/icons/gspiceui-48x48.xpm gspiceui.xpm || die

	dohtml html/*.html html/*.jpg || die

	# installing examples and according model and symbol files
	if use examples ; then
		insinto /usr/share/doc/${PF}/sch
		doins -r sch/* || die
		insinto /usr/share/doc/${PF}/lib
		doins -r lib/* || die
	fi

	make_desktop_entry gspiceui "GNU Spice GUI" gspiceui "Electronics"
}

pkg_postinst() {
	if use examples ; then
		elog "If you want to use the examples, copy from"
		elog "/usr/share/doc/${PF} the sch and lib directory"
		elog "side by side to your home directory to be able"
		elog "to generate the netlists as normal user."
	fi
}