Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Theo Chatzimichos (tampakrap)" <tampakrap@g.o>
Subject: gentoo-x86 commit in dev-libs/libindicate: ChangeLog libindicate-0.4.4.ebuild libindicate-0.3.6.ebuild
Date: Mon, 17 Jan 2011 09:34:20 +0000 (UTC)
tampakrap    11/01/17 09:34:20

  Modified:             ChangeLog
  Added:                libindicate-0.4.4.ebuild
  Removed:              libindicate-0.3.6.ebuild
  Log:
  Version bump, remove old, ebuild and patches by Dennis Schridde, bug 332375
  
  (Portage version: 2.2.0_alpha14/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 dev-libs/libindicate/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	3 Jan 2011 16:28:41 -0000	1.9
+++ ChangeLog	17 Jan 2011 09:34:19 -0000	1.10
@@ -1,6 +1,22 @@
 # ChangeLog for dev-libs/libindicate
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.9 2011/01/03 16:28:41 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/ChangeLog,v 1.10 2011/01/17 09:34:19 tampakrap Exp $
+
+*libindicate-0.4.4 (17 Jan 2011)
+
+  17 Jan 2011; Theo Chatzimichos <tampakrap@g.o>
+  -libindicate-0.3.6.ebuild,
+  -files/libindicate-0.3.6-no-gobject-introspection.patch,
+  -files/libindicate-0.3.6-optional-gtk-support.patch,
+  +libindicate-0.4.4.ebuild, +files/libindicate-0.4.4-fix-aclocal.patch,
+  +files/libindicate-0.4.4-fix-introspection.patch,
+  +files/libindicate-0.4.4-fix-out-of-source-build.patch,
+  +files/libindicate-0.4.4-fix-python-version.patch,
+  +files/libindicate-0.4.4-optional-doc.patch,
+  +files/libindicate-0.4.4-optional-examples.patch,
+  +files/libindicate-0.4.4-optional-gtk.patch,
+  +files/libindicate-0.4.4-optional-mono-example.patch:
+  Version bump, remove old, ebuild and patches by Dennis Schridde, bug 332375
 
   03 Jan 2011; Andreas K. Huettel <dilfridge@g.o>
   libindicate-0.3.6.ebuild:



1.1                  dev-libs/libindicate/libindicate-0.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/libindicate-0.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/libindicate/libindicate-0.4.4.ebuild?rev=1.1&content-type=text/plain

Index: libindicate-0.4.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/libindicate/libindicate-0.4.4.ebuild,v 1.1 2011/01/17 09:34:20 tampakrap Exp $

EAPI=2

inherit autotools eutils versionator

DESCRIPTION="Library to raise flags on DBus for other components of the desktop to pick up and visualize"
HOMEPAGE="https://launchpad.net/libindicate/"
SRC_URI="http://launchpad.net/${PN}/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc"

RESTRICT="test"

# For the dependency on dev-libs/libdbusmenu see launchpad-bug #552667
RDEPEND="dev-libs/glib:2
	dev-libs/dbus-glib
	dev-libs/libdbusmenu
	dev-libs/libxml2:2
	x11-libs/gtk+:2
	dev-python/pygtk
	dev-dotnet/gtk-sharp
	dev-dotnet/gtk-sharp-gapi"
DEPEND="${RDEPEND}
	doc? ( dev-util/gtk-doc )
	dev-util/gtk-doc-am
	dev-util/pkgconfig"

src_prepare() {
	# Without patches:
	# Make python optional, launchpad-bug #643921
	# Make mono optional, launchpad-bug #643922

	# Incomplete patches:
	# Make gtk optional, needs optional-python or code modifications, launchpad-bug #431311
	#epatch "${FILESDIR}/${P}-optional-gtk.patch"

	# Make doc optional, launchpad-bug #643911
	epatch "${FILESDIR}/${P}-optional-doc.patch"
	# Do not compile mono-example by default, launchpad-bug #643912
	epatch "${FILESDIR}/${P}-optional-mono-example.patch"
	# Do not compile examples by default, launchpad-bug #643917
	epatch "${FILESDIR}/${P}-optional-examples.patch"
	# Fix trouble with autoreconf and m4 directory, launchpad-bug #683552
	epatch "${FILESDIR}/${P}-fix-aclocal.patch"
	# Fixup undeclared HAVE_INTROSPECTION, launchpad-bug #552537
	epatch "${FILESDIR}/${P}-fix-introspection.patch"
	# Fix out-of-source builds, launchpad-bug #643913
	epatch "${FILESDIR}/${P}-fix-out-of-source-build.patch"
	# Fix compilation for python != 2.6, launchpad-bug #594992
	epatch "${FILESDIR}/${P}-fix-python-version.patch"
	# Drop -Werror in a release
	sed -e 's:-Werror::g' -i libindicate/Makefile.am libindicate-gtk/Makefile.am || die "sed failed"
	eautoreconf
}

src_configure() {
	# gobject-instrospection is a nightmare in this package, it's fixable for libindicate
	# and not for libindicate-gtk, disable it until its fixed on upstream
	econf \
		--disable-dependency-tracking \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable doc) \
		|| die "configure failed"
}

src_test() {
	emake check || die "testsuite failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS || die "dodoc failed"
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in app-emacs/auctex: auctex-11.86-r1.ebuild
Next by thread:
gentoo-x86 commit in dev-libs/libindicate/files: libindicate-0.4.4-fix-out-of-source-build.patch libindicate-0.4.4-fix-aclocal.patch libindicate-0.4.4-fix-python-version.patch libindicate-0.4.4-fix-introspection.patch libindicate-0.4.4-optional-examples.patch libindicate-0.4.4-optional-gtk.patch libindicate-0.4.4-optional-mono-example.patch libindicate-0.4.4-optional-doc.patch libindicate-0.3.6-optional-gtk-support.patch libindicate-0.3.6-no-gobject-introspection.patch
Previous by date:
gentoo commit in xml/htdocs/doc/es: openrc-migration.xml
Next by date:
gentoo-x86 commit in dev-libs/libindicate/files: libindicate-0.4.4-fix-out-of-source-build.patch libindicate-0.4.4-fix-aclocal.patch libindicate-0.4.4-fix-python-version.patch libindicate-0.4.4-fix-introspection.patch libindicate-0.4.4-optional-examples.patch libindicate-0.4.4-optional-gtk.patch libindicate-0.4.4-optional-mono-example.patch libindicate-0.4.4-optional-doc.patch libindicate-0.3.6-optional-gtk-support.patch libindicate-0.3.6-no-gobject-introspection.patch


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.