[gentoo-commits] gentoo-x86 commit in games-strategy/widelands: ChangeLog widelands-0.0.12.ebuild

[Stefan Schweizer (genstef)]

genstef     08/04/05 16:14:54

  Modified:             ChangeLog
  Added:                widelands-0.0.12.ebuild
  Log:
  version bump
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.14                 games-strategy/widelands/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/widelands/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/widelands/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/widelands/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/widelands/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	22 Jan 2008 08:39:33 -0000	1.13
+++ ChangeLog	5 Apr 2008 16:14:53 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/widelands
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/ChangeLog,v 1.13 2008/01/22 08:39:33 nyhm Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/ChangeLog,v 1.14 2008/04/05 16:14:53 genstef Exp $
+
+*widelands-0.0.12 (05 Apr 2008)
+
+  05 Apr 2008; Stefan Schweizer <genstef@g.o>
+  +widelands-0.0.12.ebuild:
+  version bump
 
   22 Jan 2008; Tristan Heaven <nyhm@g.o> widelands-0.0.11.ebuild:
   Add libpng dep, bug #206432



1.1                  games-strategy/widelands/widelands-0.0.12.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/widelands/widelands-0.0.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/widelands/widelands-0.0.12.ebuild?rev=1.1&content-type=text/plain

Index: widelands-0.0.12.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/widelands/widelands-0.0.12.ebuild,v 1.1 2008/04/05 16:14:53 genstef Exp $

inherit eutils flag-o-matic toolchain-funcs versionator games

MY_PV=$(get_version_component_range 3)
DESCRIPTION="A game similar to Settlers 2"
HOMEPAGE="http://www.widelands.org/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-build-${MY_PV}-source.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls"

RDEPEND="media-libs/libsdl
	media-libs/sdl-image
	media-libs/sdl-mixer
	media-libs/sdl-net
	media-libs/sdl-ttf
	media-libs/sdl-gfx
	media-libs/libpng
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${A}
	cd "${S}"
	rm -f $(find . -name SConscript)

	epatch "${FILESDIR}"/widelands-0.0.11-build.patch

	sed -i 's:__ppc__:__PPC__:' src/s2map.cc \
		|| die "sed s2map.cc failed"
	sed -i "s:/usr/share/games:${GAMES_DATADIR}:" src/wlapplication.cc \
		|| die "sed wlapplication.cc failed"
	sed -i "s:/l/WiLa/Setup:${GAMES_DATADIR}/${PN}:" src/config.h.default \
		|| die "sed config.h.default failed"
}

src_compile() {
	filter-flags -fomit-frame-pointer
	emake CXX=$(tc-getCXX) all || die "emake failed"

	if use nls ; then
		utils/buildlocale.py || die "buildlocale.py failed"
	fi
}

src_install() {
	dogamesbin ${PN} || die "dogamesbin failed"

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r campaigns fonts maps music pics sound tribes txts worlds \
		|| die "doins failed"

	insinto "${GAMES_DATADIR}"/${PN}/locale
	local d
	for d in locale/* ; do
		if [[ -d ${d} ]] ; then
			doins -r ${d} || die "doins ${d} failed"
		fi
	done

	newicon pics/wl-ico-48.png ${PN}.png
	make_desktop_entry ${PN} Widelands

	dodoc ChangeLog CREDITS
	prepgamesdirs
}



-- 
gentoo-commits@l.g.o mailing list