eva         09/05/10 22:07:57

  Modified:             ChangeLog
  Added:                epiphany-2.26.1.ebuild
  Removed:              epiphany-2.22.3-r1.ebuild
                        epiphany-2.22.3-r11.ebuild
                        epiphany-2.24.2.1-r10.ebuild
                        epiphany-2.22.3-r2.ebuild epiphany-2.24.2.1.ebuild
                        epiphany-2.22.3-r12.ebuild
  Log:
  New version for GNOME 2.26. Clean up old revisions.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.208                www-client/epiphany/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.208&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?rev=1.208&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/ChangeLog?r1=1.207&r2=1.208

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v
retrieving revision 1.207
retrieving revision 1.208
diff -u -r1.207 -r1.208
--- ChangeLog	27 Apr 2009 14:34:58 -0000	1.207
+++ ChangeLog	10 May 2009 22:07:57 -0000	1.208
@@ -1,6 +1,16 @@
 # ChangeLog for www-client/epiphany
-# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.207 2009/04/27 14:34:58 jer Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/ChangeLog,v 1.208 2009/05/10 22:07:57 eva Exp $
+
+*epiphany-2.26.1 (10 May 2009)
+
+  10 May 2009; Gilles Dartiguelongue <eva@g.o>
+  -epiphany-2.22.3-r1.ebuild, -epiphany-2.22.3-r2.ebuild,
+  -epiphany-2.22.3-r11.ebuild, -epiphany-2.22.3-r12.ebuild,
+  -epiphany-2.24.2.1.ebuild, -epiphany-2.24.2.1-r10.ebuild,
+  +files/epiphany-2.26.0-xulrunner191.patch, +epiphany-2.26.1.ebuild,
+  +files/epiphany-2.26.1-automagic-libcanberra.patch:
+  New version for GNOME 2.26. Clean up old revisions.
 
   27 Apr 2009; Jeroen Roovers <jer@g.o> epiphany-2.24.3-r10:
   Stable for HPPA (bug #260063).



1.1                  www-client/epiphany/epiphany-2.26.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/epiphany-2.26.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/epiphany/epiphany-2.26.1.ebuild?rev=1.1&content-type=text/plain

Index: epiphany-2.26.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/epiphany/epiphany-2.26.1.ebuild,v 1.1 2009/05/10 22:07:57 eva Exp $

EAPI="2"

inherit gnome2 eutils multilib autotools

DESCRIPTION="GNOME webbrowser based on the mozilla rendering engine"
HOMEPAGE="http://www.gnome.org/projects/epiphany/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="avahi doc networkmanager python spell"

RDEPEND=">=dev-libs/glib-2.18.0
	>=x11-libs/gtk+-2.16.0
	>=dev-libs/libxml2-2.6.12
	>=dev-libs/libxslt-1.1.7
	>=gnome-base/libglade-2.3.1
	>=gnome-base/libgnome-2.14
	>=gnome-base/libgnomeui-2.14
	>=gnome-base/gnome-desktop-2.9.91
	>=x11-libs/startup-notification-0.5
	>=x11-libs/libnotify-0.4
	>=media-libs/libcanberra-0.3[gtk]
	>=dev-libs/dbus-glib-0.71
	>=gnome-base/gconf-2
	>=app-text/iso-codes-0.35
	avahi? ( >=net-dns/avahi-0.6.22 )
	networkmanager? ( net-misc/networkmanager )
	=net-libs/xulrunner-1.9*
	python? (
		>=dev-lang/python-2.3
		>=dev-python/pygtk-2.7.1
		>=dev-python/gnome-python-2.6 )
	spell? ( app-text/enchant )
	x11-themes/gnome-icon-theme"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40
	>=app-text/gnome-doc-utils-0.3.2
	doc? ( >=dev-util/gtk-doc-1 )"

DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-scrollkeeper
		--with-gecko=libxul-embedding
		--enable-certificate-manager
		--with-distributor-name=Gentoo
		--enable-canberra
		$(use_enable avahi zeroconf)
		$(use_enable networkmanager network-manager)
		$(use_enable spell spell-checker)
		$(use_enable python)"
}

src_prepare() {
	gnome2_src_prepare

	# Fix compilation with xulrunner 1.9.1, bug #263990
	epatch "${FILESDIR}/${PN}-2.26.0-xulrunner191.patch"

	# Fix libcanberra automagic support, bug #266232
	epatch "${FILESDIR}/${P}-automagic-libcanberra.patch"

	# Make it libtool-1 compatible
	rm -v m4/lt* m4/libtool.m4 || die "removing libtool macros failed"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

src_configure() {
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/xpti.dat.tmp
	addpredict /usr/$(get_libdir)/xulrunner-1.9/components/compreg.dat.tmp

	# Why are these write-opened per bug #228589 and bug #253043
	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat
	addpredict /usr/$(get_libdir)/mozilla/components/xpti.dat.tmp
	addpredict /usr/$(get_libdir)/mozilla/components/compreg.dat.tmp

	gnome2_src_configure
}