[gentoo-commits] gentoo-x86 commit in sci-chemistry/refmac: metadata.xml ChangeLog refmac-5.5.0109.ebuild

[Justin Lecher (jlec)]

jlec        10/02/02 22:43:56

  Added:                metadata.xml ChangeLog refmac-5.5.0109.ebuild
  Log:
  refmac splitted from ccp4 package
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  sci-chemistry/refmac/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sci</herd>
<maintainer>
  <email>sci@g.o</email>
</maintainer>
<maintainer>
 <email>jlec@g.o</email>
  <name>Justin Lecher (jlec)</name>
 </maintainer>
</pkgmetadata>



1.1                  sci-chemistry/refmac/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sci-chemistry/refmac
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/ChangeLog,v 1.1 2010/02/02 22:43:56 jlec Exp $

*refmac-5.5.0109 (02 Feb 2010)

  02 Feb 2010; Justin Lecher (jlec) <jlec@g.o>
  +files/5.5-allow-dynamic-linking.patch, +files/5.5-test.log.patch,
  +refmac-5.5.0109.ebuild, +metadata.xml:
  refmac splitted from ccp4 package




1.1                  sci-chemistry/refmac/refmac-5.5.0109.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/refmac-5.5.0109.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-chemistry/refmac/refmac-5.5.0109.ebuild?rev=1.1&content-type=text/plain

Index: refmac-5.5.0109.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/refmac/refmac-5.5.0109.ebuild,v 1.1 2010/02/02 22:43:56 jlec Exp $

EAPI="2"

inherit fortran base toolchain-funcs versionator

DESCRIPTION="Macromolecular crystallographic refinement program"
HOMEPAGE="http://www.ysbl.york.ac.uk/~garib/refmac/"
SRC_URI="${HOMEPAGE}data/refmac_stable/refmac_${PV}.tar.gz
	test? ( http://dev.gentooexperimental.org/~jlec/distfiles/test-framework.tar.gz )"

SLOT="0"
LICENSE="ccp4"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="
	sci-libs/ccp4-libs
	sci-libs/mmdb
	virtual/blas
	virtual/lapack"
DEPEND="${RDEPEND}"

S="${WORKDIR}"

PATCHES=(
	"${FILESDIR}"/$(get_version_component_range 1-2 ${PV})-allow-dynamic-linking.patch
	)

src_prepare() {
	base_src_prepare
	use test && epatch "${FILESDIR}"/test.log.patch
}

src_compile() {
	emake \
		FC=$(tc-getFC) \
		CC=$(tc-getCC) \
		CXX=$(tc-getCXX) \
		COPTIM="${CFLAGS}" \
		FOPTIM="${FFLAGS:- -O2}" \
		VERSION="" \
		XFFLAGS="-fno-second-underscore" \
		LLIBCCP="-lccp4f -lccp4c -lccif -lmmdb -lstdc++" \
		LLIBLAPACK="-llapack -lblas" \
		|| die
}

src_test() {
	einfo "Starting tests ..."
	export PATH="${WORKDIR}/test-framework/scripts:${S}:${PATH}"
	export CCP4_TEST="${WORKDIR}"/test-framework
	export CCP4_SCR="${T}"
	ln -sf refmac "${S}"/refmac5
	sed '/^ANISOU/d' -i ${CCP4_TEST}/data/pdb/1vr7.pdb
	ccp4-run-thorough-tests -v test_refmac5 || die
}

src_install() {
	for i in refmac libcheck makecif; do
		dobin ${i} || die
	done
	dosym refmac /usr/bin/refmac5 || die
	dodoc refmac_keywords.pdf bugs_and_features.pdf || die
}