[gentoo-commits] gentoo-x86 commit in app-arch/unrar: ChangeLog unrar-4.2.3.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/05/28 08:32:21

  Modified:             ChangeLog
  Added:                unrar-4.2.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.175                app-arch/unrar/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/unrar/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/unrar/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/unrar/ChangeLog?r1=1.174&r2=1.175

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/unrar/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog	17 May 2012 12:00:51 -0000	1.174
+++ ChangeLog	28 May 2012 08:32:21 -0000	1.175
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/unrar
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/unrar/ChangeLog,v 1.174 2012/05/17 12:00:51 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/unrar/ChangeLog,v 1.175 2012/05/28 08:32:21 ssuominen Exp $
+
+*unrar-4.2.3 (28 May 2012)
+
+  28 May 2012; Samuli Suominen <ssuominen@g.o> +unrar-4.2.3.ebuild:
+  Version bump.
 
 *unrar-4.2.2 (17 May 2012)
 



1.1                  app-arch/unrar/unrar-4.2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/unrar/unrar-4.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/unrar/unrar-4.2.3.ebuild?rev=1.1&content-type=text/plain

Index: unrar-4.2.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/unrar/unrar-4.2.3.ebuild,v 1.1 2012/05/28 08:32:21 ssuominen Exp $

EAPI=4
inherit flag-o-matic multilib toolchain-funcs

MY_PN=${PN}src

DESCRIPTION="Uncompress rar files"
HOMEPAGE="http://www.rarlab.com/rar_add.htm"
SRC_URI="http://www.rarlab.com/rar/${MY_PN}-${PV}.tar.gz"

LICENSE="unRAR"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE=""

RDEPEND="!<=app-arch/unrar-gpl-0.0.1_p20080417"

S=${WORKDIR}/unrar

src_prepare() {
	sed -i \
		-e "/libunrar/s:.so:$(get_libname ${PV%.*.*}):" \
		-e "s:-shared:& -Wl,-soname -Wl,libunrar$(get_libname ${PV%.*.*}):" \
		makefile.unix || die
}

src_compile() {
	unrar_make() {
		emake -f makefile.unix CXX="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS}" STRIP=true "$@"
	}

	unrar_make CXXFLAGS+=" -fPIC" lib
	ln -s libunrar$(get_libname ${PV%.*.*}) libunrar$(get_libname)
	ln -s libunrar$(get_libname ${PV%.*.*}) libunrar$(get_libname ${PV})

	unrar_make clean
	unrar_make
}

src_install() {
	dobin unrar
	dodoc readme.txt

	dolib.so libunrar*

	insinto /usr/include/libunrar${PV%.*.*}
	doins *.hpp
	dosym libunrar${PV%.*.*} /usr/include/libunrar
}