[gentoo-commits] gentoo-x86 commit in net-proxy/squidclamav: squidclamav-6.6.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/05/29 06:02:24

  Modified:             ChangeLog
  Added:                squidclamav-6.6.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.21                 net-proxy/squidclamav/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	15 Jan 2012 22:03:12 -0000	1.20
+++ ChangeLog	29 May 2012 06:02:24 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/squidclamav
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v 1.20 2012/01/15 22:03:12 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/ChangeLog,v 1.21 2012/05/29 06:02:24 flameeyes Exp $
+
+*squidclamav-6.6 (29 May 2012)
+
+  29 May 2012; Diego E. Pettenò <flameeyes@g.o> +squidclamav-6.6.ebuild:
+  Version bump.
 
 *squidclamav-6.5 (15 Jan 2012)
 



1.1                  net-proxy/squidclamav/squidclamav-6.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/squidclamav-6.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-proxy/squidclamav/squidclamav-6.6.ebuild?rev=1.1&content-type=text/plain

Index: squidclamav-6.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidclamav/squidclamav-6.6.ebuild,v 1.1 2012/05/29 06:02:24 flameeyes Exp $

EAPI=4

inherit libtool autotools

DESCRIPTION="HTTP Antivirus for Squid based on ClamAv and ICAP"
HOMEPAGE="http://squidclamav.darold.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="net-proxy/c-icap"
DEPEND="${RDEPEND}"

src_prepare() {
	# version 6.3 causes maintainer-mode rebuild from tarball, and
	# contains acinclude.m4 with libtool macros which cause trouble.
	rm acinclude.m4 || die
	eautoreconf
	elibtoolize
}

src_install() {
	emake DESTDIR="${D}" install
	find "${D}" -name '*.la' -delete || die

	# delete its own documentation installed
	rm -r "${D}"/usr/share/${PN} || die

	dodoc README AUTHORS ChangeLog

	# Fix configuration file to adapt to the Gentoo configuration
	sed -i \
		-e '/clamd_local/s:\.ctl:.sock:' \
		"${D}"/etc/squidclamav.conf || die
}

pkg_postinst() {
	elog "Starting from version 6, Squid Clamav is now a module for the c-icap"
	elog "server, which is called from squid, rather than being a redirector"
	elog "directly."
	elog ""
	elog "To enable the service, you should add this to your c-icap.conf file:"
	elog ""
	elog "    Service clamav squidclamav.so"
	elog ""
	elog "And then this to squid.conf (for a local ICAP server):"
	elog ""
	elog "    icap_enable on"
	elog ""
	elog "    # not strictly needed, but useful for special access"
	elog "    icap_send_client_ip on"
	elog "    icap_send_client_username on"
	elog ""
	elog "    icap_service clamav respmod_precache bypass=0 icap://localhost:1344/clamav"
	elog "    adaptation_access clamav allow all"
}