grozin      12/06/22 07:35:14

  Modified:             ChangeLog
  Added:                fricas-1.1.7-r1.ebuild
  Removed:              fricas-1.1.7.ebuild
  Log:
  fix a bug in src/graph/view3D/smoothShade3d.c
  
  (Portage version: 2.2.0_alpha110/cvs/Linux i686)

Revision  Changes    Path
1.15                 sci-mathematics/fricas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	21 Jun 2012 08:24:23 -0000	1.14
+++ ChangeLog	22 Jun 2012 07:35:14 -0000	1.15
@@ -1,6 +1,12 @@
 # ChangeLog for sci-mathematics/fricas
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v 1.14 2012/06/21 08:24:23 grozin Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/ChangeLog,v 1.15 2012/06/22 07:35:14 grozin Exp $
+
+*fricas-1.1.7-r1 (22 Jun 2012)
+
+  22 Jun 2012; Andrey Grozin <grozin@g.o> -fricas-1.1.7.ebuild,
+  +fricas-1.1.7-r1.ebuild, +files/fricas-1.1.7.patch:
+  fix a bug in src/graph/view3D/smoothShade3d.c
 
 *fricas-1.1.7 (21 Jun 2012)
 



1.1                  sci-mathematics/fricas/fricas-1.1.7-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/fricas-1.1.7-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/fricas/fricas-1.1.7-r1.ebuild?rev=1.1&content-type=text/plain

Index: fricas-1.1.7-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/fricas/fricas-1.1.7-r1.ebuild,v 1.1 2012/06/22 07:35:14 grozin Exp $
EAPI=4
inherit eutils multilib elisp-common

DESCRIPTION="FriCAS is a fork of Axiom computer algebra system"
HOMEPAGE="http://${PN}.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}-full.tar.bz2"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

# Supported lisps, number 0 is the default
LISPS=( sbcl cmucl     gcl ecl    clisp clozurecl )
# . means just dev-lisp/${LISP}; foo-x.y.z means >=dev-lisp/foo-x.y.z
DEPS=(  .    cmucl-20b .   ecls-9 .     .         )
# command name: . means just ${LISP}
COMS=(  .    lisp      .   .      .     ccl       )

IUSE="${LISPS[*]} X emacs gmp"
RDEPEND="X? ( x11-libs/libXpm x11-libs/libICE )
	emacs? ( virtual/emacs )
	gmp? ( dev-libs/gmp )"

# Generating lisp deps
n=${#LISPS[*]}
for ((n--; n > 0; n--)); do
	LISP=${LISPS[$n]}
	DEP=${DEPS[$n]}
	if [ "${DEP}" = "." ]; then
		DEP="dev-lisp/${LISP}"
	else
		DEP=">=dev-lisp/${DEP}"
	fi
	RDEPEND="${RDEPEND} ${LISP}? ( ${DEP} ) !${LISP}? ("
done
RDEPEND="${RDEPEND} dev-lisp/${LISPS[0]}"
n=${#LISPS[*]}
for ((n--; n > 0; n--)); do
	RDEPEND="${RDEPEND} )"
done

DEPEND="${RDEPEND}"

# necessary for clisp and gcl
RESTRICT="strip"

src_prepare() {
	# fix a bug in src/graph/view3D/smoothShade3d.c
	epatch "${FILESDIR}"/${P}.patch
}

src_configure() {
	local LISP n
	LISP=sbcl
	n=${#LISPS[*]}
	for ((n--; n > 0; n--)); do
		if use ${LISPS[$n]}; then
			LISP=${COMS[$n]}
			if [ "${LISP}" = "." ]; then
				LISP=${LISPS[$n]}
			fi
		fi
	done
	einfo "Using lisp: ${LISP}"

	# aldor is not yet in portage
	econf --disable-aldor --with-lisp=${LISP} $(use_with X x) $(use_with gmp)
}

src_compile() {
	# bug #300132
	emake -j1
}

src_test() {
	emake -j1 all-input
}

src_install() {
	emake -j1 DESTDIR="${D}" install
	dodoc README FAQ

	if use emacs; then
		sed -e "s|(setq load-path (cons (quote \"/usr/$(get_libdir)/fricas/emacs\") load-path)) ||" \
			-i "${D}"/usr/bin/efricas \
			|| die "sed efricas failed"
		elisp-install ${PN} "${D}"/usr/$(get_libdir)/${PN}/emacs/*.el
		elisp-site-file-install "${FILESDIR}"/64${PN}-gentoo.el
	else
		rm "${D}"/usr/bin/efricas || die "rm efricas failed"
	fi
	rm -r "${D}"/usr/$(get_libdir)/${PN}/emacs || die "rm -r emacs failed"
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}