[gentoo-commits] gentoo-x86 commit in app-mobilephone/sobexsrv: ChangeLog sobexsrv-1.0.1.ebuild

[Christian Birchinger (joker)]

joker       07/10/26 15:58:37

  Modified:             ChangeLog
  Added:                sobexsrv-1.0.1.ebuild
  Log:
  Version bump and 64bit fixes
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.12                 app-mobilephone/sobexsrv/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	16 Feb 2007 21:50:06 -0000	1.11
+++ ChangeLog	26 Oct 2007 15:58:37 -0000	1.12
@@ -1,6 +1,12 @@
 # ChangeLog for app-mobilephone/sobexsrv
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog,v 1.11 2007/02/16 21:50:06 joker Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/sobexsrv/ChangeLog,v 1.12 2007/10/26 15:58:37 joker Exp $
+
+*sobexsrv-1.0.1 (26 Oct 2007)
+
+  26 Oct 2007; Christian Birchinger <joker@g.o>
+  +sobexsrv-1.0.1.ebuild:
+  Version bump and 64bit fixes.
 
   16 Feb 2007; Christian Birchinger <joker@g.o>
   sobexsrv-1.0.0_pre4.ebuild:



1.1                  app-mobilephone/sobexsrv/sobexsrv-1.0.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/sobexsrv/sobexsrv-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-mobilephone/sobexsrv/sobexsrv-1.0.1.ebuild?rev=1.1&content-type=text/plain

Index: sobexsrv-1.0.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/sobexsrv/sobexsrv-1.0.1.ebuild,v 1.1 2007/10/26 15:58:37 joker Exp $

inherit eutils

MY_P="${P/_pre/pre}"

IUSE="gtk"

DESCRIPTION="Scripting/Secure OBEX Server (for BlueZ Linux)"
SRC_URI="http://www.mulliner.org/bluetooth/${MY_P}.tar.gz
	 http://dev.gentoo.org/~joker/${P}-fix64.patch"
HOMEPAGE="http://www.mulliner.org/bluetooth/sobexsrv.php"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DEPEND="dev-libs/openobex
	net-wireless/bluez-libs"

RDEPEND="${DEPEND}
	net-wireless/bluez-utils
	gtk? ( >=dev-python/pygtk-2.2 )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	enewgroup sobexsrv
	enewuser sobexsrv -1 -1 /var/spool/sobexsrv sobexsrv
}

src_unpack() {
	unpack ${A}

	cd "${S}"

	epatch "${DISTDIR}/${P}"-fix64.patch || die "fix64 patch failed"

	sed -e 's:/usr/man/man8:/usr/share/man/man8:' \
	    -i Makefile

	sed -e 's/^CFLAGS =/CFLAGS +=/' \
	    -e 's/^CC =/CC ?=/' \
	    -i src/Makefile
}

src_compile() {
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHOR CHANGELOG CONFIG README SECURITY TODO

	use gtk || rm "${D}/usr/bin/sobexsrv_handler"

	newinitd "${FILESDIR}/init.d_sobexsrv" sobexsrv
	newconfd "${FILESDIR}/conf.d_sobexsrv" sobexsrv

	keepdir /var/spool/sobexsrv
	fowners sobexsrv:sobexsrv /var/spool/sobexsrv
}

pkg_postinst() {
	elog
	elog "/usr/bin/sobexsrv is *NOT* installed set-uid root by"
	elog "default. suid is required for the chroot option (-R)."
	elog
	elog "Execute the following commands to enable suid:"
	elog
	elog "chown root:sobexsrv /usr/bin/sobexsrv"
	elog "chmod 4710 /usr/bin/sobexsrv"
	elog
}



-- 
gentoo-commits@g.o mailing list