[gentoo-commits] gentoo-x86 commit in dev-python/astng: ChangeLog astng-0.21.1.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    11/01/17 22:53:07

  Modified:             ChangeLog
  Added:                astng-0.21.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha15_p12/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 dev-python/astng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astng/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astng/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astng/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/astng/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	6 Jan 2011 21:47:05 -0000	1.47
+++ ChangeLog	17 Jan 2011 22:53:07 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/astng
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/astng/ChangeLog,v 1.47 2011/01/06 21:47:05 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/astng/ChangeLog,v 1.48 2011/01/17 22:53:07 arfrever Exp $
+
+*astng-0.21.1 (17 Jan 2011)
+
+  17 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -astng-0.20.1.ebuild, -astng-0.20.2.ebuild, +astng-0.21.1.ebuild:
+  Version bump.
 
   06 Jan 2011; Brent Baude <ranger@g.o> astng-0.20.3.ebuild:
   Marking astng-0.20.3 ppc for bug 341607



1.1                  dev-python/astng/astng-0.21.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astng/astng-0.21.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/astng/astng-0.21.1.ebuild?rev=1.1&content-type=text/plain

Index: astng-0.21.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/astng/astng-0.21.1.ebuild,v 1.1 2011/01/17 22:53:07 arfrever Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"

inherit distutils

DESCRIPTION="Abstract Syntax Tree New Generation for logilab packages"
HOMEPAGE="http://www.logilab.org/projects/astng/ http://pypi.python.org/pypi/logilab-astng"
SRC_URI="ftp://ftp.logilab.org/pub/astng/logilab-${P}.tar.gz mirror://pypi/l/logilab-astng/logilab-${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos ~x86-macos"
IUSE="test"

# Version specified in __pkginfo__.py.
RDEPEND=">=dev-python/logilab-common-0.53.0"
DEPEND="${RDEPEND}
	dev-python/setuptools
	test? ( >=dev-python/egenix-mx-base-3.0.0 )"

S="${WORKDIR}/logilab-${P}"

DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"

PYTHON_MODNAME="logilab/astng"

src_prepare() {
	distutils_src_prepare

	conversion() {
		[[ "${PYTHON_ABI}" == 2.* ]] && return
		find -name "*.py" ! -name "setup.py" -print | xargs 2to3-${PYTHON_ABI} -nw --no-diffs
	}
	python_execute_function -s conversion
}

src_test() {
	testing() {
		local tpath="${T}/test-${PYTHON_ABI}"
		local spath="${tpath}$(python_get_sitedir)"

		mkdir -p "${spath}/logilab" || return 1
		cp -r "$(python_get_sitedir)/logilab/common" "${spath}/logilab" || return 1

		"$(PYTHON)" setup.py install --root="${tpath}" || die "Installation for tests failed with $(python_get_implementation) $(python_get_version)"

		# pytest uses tests placed relatively to the current directory.
		pushd "${spath}/logilab/astng" > /dev/null || return 1
		if [[ "${PYTHON_ABI}" == 3.* ]]; then
			# Support for Python 3 is experimental. Some tests are known to fail.
			PYTHONPATH="${spath}" pytest -v
		else
			PYTHONPATH="${spath}" pytest -v || return 1
		fi
		popd > /dev/null || return 1
	}
	python_execute_function -s testing
}

src_install() {
	distutils_src_install

	deletion_of_unneeded_files() {
		# Avoid collision with dev-python/logilab-common.
		rm -f "${ED}$(python_get_sitedir)/logilab/__init__.py" || return 1

		# Don't install tests.
		rm -fr "${ED}$(python_get_sitedir)/logilab/astng/test" || return 1
	}
	python_execute_function -q deletion_of_unneeded_files
}