Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Jeremy Olexa (darkside)" <darkside@g.o>
Subject: gentoo-x86 commit in net-misc/mediatomb: ChangeLog mediatomb-0.12.0-r1.ebuild mediatomb-0.12.0.ebuild
Date: Tue, 30 Mar 2010 01:13:26 +0000
darkside    10/03/30 01:13:26

  Modified:             ChangeLog
  Added:                mediatomb-0.12.0-r1.ebuild
  Removed:              mediatomb-0.12.0.ebuild
  Log:
  minor revbump to grab new init/conf files from bug 264235 that I forgot
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 net-misc/mediatomb/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mediatomb/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mediatomb/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mediatomb/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mediatomb/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	29 Mar 2010 22:32:23 -0000	1.11
+++ ChangeLog	30 Mar 2010 01:13:26 -0000	1.12
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/mediatomb
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mediatomb/ChangeLog,v 1.11 2010/03/29 22:32:23 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mediatomb/ChangeLog,v 1.12 2010/03/30 01:13:26 darkside Exp $
+
+*mediatomb-0.12.0-r1 (30 Mar 2010)
+
+  30 Mar 2010; Jeremy Olexa <darkside@g.o> -mediatomb-0.12.0.ebuild,
+  +mediatomb-0.12.0-r1.ebuild, +files/mediatomb-0.12.0.confd,
+  +files/mediatomb-0.12.0.initd:
+  minor revbump to grab new init/conf files from bug 264235 that I forgot
 
   29 Mar 2010; Jeremy Olexa <darkside@g.o> +mediatomb-0.12.0.ebuild,
   +files/mediatomb-0.12.0.config, metadata.xml:



1.1                  net-misc/mediatomb/mediatomb-0.12.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mediatomb/mediatomb-0.12.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mediatomb/mediatomb-0.12.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: mediatomb-0.12.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mediatomb/mediatomb-0.12.0-r1.ebuild,v 1.1 2010/03/30 01:13:26 darkside Exp $

EAPI=2

inherit eutils linux-info

DESCRIPTION="MediaTomb is an open source UPnP MediaServer"
HOMEPAGE="http://www.mediatomb.cc/"
SRC_URI="mirror://sourceforge/mediatomb/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug +exif +ffmpeg inotify +javascript lastfm +mp4 mysql +taglib thumbnail"

DEPEND="
	mysql? ( virtual/mysql )
	!mysql? ( >=dev-db/sqlite-3 )
	javascript? ( dev-lang/spidermonkey )
	dev-libs/expat
	taglib? ( media-libs/taglib )
	!taglib? ( media-libs/id3lib )
	lastfm? ( >=media-libs/lastfmlib-0.4 )
	exif? ( media-libs/libexif )
	mp4? ( media-libs/libmp4v2 )
	ffmpeg? ( media-video/ffmpeg )
	thumbnail? ( media-video/ffmpegthumbnailer[jpeg] )
	net-misc/curl
	sys-apps/file
	sys-libs/zlib
	virtual/libiconv"

RDEPEND="${DEPEND}"

pkg_setup() {
	if use inotify; then
		if linux_config_exists; then
			if ! linux_chkconfig_present INOTIFY_USER; then
				ewarn "Please enable Inotify support in your kernel:"
				ewarn
				ewarn "  File systems --->"
				ewarn "    [*] Inotify support for userspace"
				ewarn
			fi
		fi
	fi
	enewgroup mediatomb
	enewuser mediatomb -1 -1 /dev/null mediatomb
}

src_configure() {
	if use thumbnail; then
		myconf="${myconf} --enable-ffmpegthumbnailer --enable-ffmpeg"
	else
		myconf="${myconf} $(use_enable thumbnail ffmpegthumbnailer) $(use_enable ffmpeg)"
	fi

	econf \
		$(use_enable debug tombdebug) \
		$(use_enable exif libexif) \
		$(use_enable inotify) \
		$(use_enable javascript libjs) \
		$(use_enable lastfm lastfmlib) \
		$(use_enable mp4 libmp4v2) \
		$(use_enable mysql) $(use_enable !mysql sqlite3) \
		$(use_enable taglib) $(use_enable !taglib id3lib) \
		--enable-curl \
		--enable-external-transcoding \
		--enable-libmagic \
		--enable-protocolinfo-extension \
		--enable-youtube \
		--enable-zlib \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed!"

	dodoc AUTHORS ChangeLog NEWS README TODO

	sed -e "s:#MYSQL#:$(use mysql && has_version dev-db/mysql[-minimal] && echo "mysql"):" \
		"${FILESDIR}/${P}.initd" > "${T}/mediatomb.initd" || die
	newinitd "${T}/mediatomb.initd" mediatomb || die
	newconfd "${FILESDIR}/${P}.confd" mediatomb || die

	insinto /etc/mediatomb
	newins "${FILESDIR}/${P}.config" config.xml || die
	fperms 0600 /etc/mediatomb/config.xml
	fowners mediatomb:mediatomb /etc/mediatomb/config.xml

	keepdir /var/lib/mediatomb
	fowners mediatomb:mediatomb /var/lib/mediatomb
}

pkg_postinst() {
	if use mysql; then
		elog "MediaTomb has been built with MySQL support and needs"
		elog "to be configured before being started."
		elog "For more information, please consult the MediaTomb"
		elog "documentation: http://mediatomb.cc/pages/documentation"
		elog
	fi

	elog "To configure MediaTomb edit:"
	elog "/etc/mediatomb/config.xml"
	elog
	elog "To start MediaTomb:"
	elog "/etc/init.d/mediatomb start"
	elog
	elog "To start MediaTomb at boot:"
	elog "rc-update add mediatomb default"
	elog
	elog "The MediaTomb web interface can be reached at:"
	elog "http://localhost:49152/"
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in sys-kernel/git-sources: ChangeLog git-sources-2.6.34_rc2-r4.ebuild git-sources-2.6.34_rc2-r3.ebuild
Next by thread:
gentoo-x86 commit in net-misc/mediatomb/files: mediatomb-0.12.0.confd mediatomb-0.12.0.initd
Previous by date:
gentoo-x86 commit in profiles/targets/desktop: make.defaults
Next by date:
gentoo-x86 commit in net-misc/mediatomb/files: mediatomb-0.12.0.confd mediatomb-0.12.0.initd


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.