aidecoe     11/10/27 11:57:59

  Modified:             ChangeLog
  Added:                plymouth-0.9_pre20111013-r1.ebuild
  Log:
  sys-boot/plymouth-0.9_pre: Fixes bug #388459.
  
  Set local state dir to /var and not /var/lib.
  
  (Portage version: 2.1.10.31/cvs/Linux x86_64)

Revision  Changes    Path
1.17                 sys-boot/plymouth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	18 Oct 2011 17:54:55 -0000	1.16
+++ ChangeLog	27 Oct 2011 11:57:59 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for sys-boot/plymouth
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.16 2011/10/18 17:54:55 aidecoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/ChangeLog,v 1.17 2011/10/27 11:57:59 aidecoe Exp $
+
+*plymouth-0.9_pre20111013-r1 (27 Oct 2011)
+
+  27 Oct 2011; Amadeusz Żołnowski <aidecoe@g.o>
+  +plymouth-0.9_pre20111013-r1.ebuild:
+  Set local state dir to /var and not /var/lib. Fixes bug #388459.
 
   18 Oct 2011; Amadeusz Żołnowski <aidecoe@g.o>
   plymouth-0.8.3-r2.ebuild, plymouth-0.8.3-r4.ebuild, plymouth-0.8.3-r5.ebuild,



1.1                  sys-boot/plymouth/plymouth-0.9_pre20111013-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.9_pre20111013-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/plymouth/plymouth-0.9_pre20111013-r1.ebuild?rev=1.1&content-type=text/plain

Index: plymouth-0.9_pre20111013-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/plymouth/plymouth-0.9_pre20111013-r1.ebuild,v 1.1 2011/10/27 11:57:59 aidecoe Exp $

EAPI=4

inherit autotools-utils

DESCRIPTION="Graphical boot animation (splash) and logger"
HOMEPAGE="http://cgit.freedesktop.org/plymouth/"
SRC_URI="
	http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/${P}.tar.bz2
	http://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE_VIDEO_CARDS="video_cards_intel video_cards_nouveau video_cards_radeon"
IUSE="${IUSE_VIDEO_CARDS} gdm +libkms +openrc +pango static-libs"

CDEPEND=">=media-libs/libpng-1.2.16
	>=x11-libs/gtk+-2.12:2
	pango? ( >=x11-libs/pango-1.21 )
	video_cards_intel? ( x11-libs/libdrm[video_cards_intel] )
	video_cards_nouveau? ( x11-libs/libdrm[video_cards_nouveau] )
	video_cards_radeon? ( x11-libs/libdrm[video_cards_radeon] )
	"
DEPEND="${CDEPEND}
	dev-util/pkgconfig
	"
RDEPEND="${CDEPEND}
	>=sys-kernel/dracut-008-r1[dracut_modules_plymouth]
	openrc? ( sys-boot/plymouth-openrc-plugin )
	"

DOCS=(AUTHORS README TODO)
PATCHES=(
	"${FILESDIR}"/${PV}-gentoo-fb-path.patch
	)

src_prepare() {
	autotools-utils_src_prepare
	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--with-system-root-install
		--localstatedir=/var
		$(use_enable libkms)
		$(use_enable pango)
		$(use_enable gdm gdm-transition)
		$(use_enable video_cards_intel libdrm_intel)
		$(use_enable video_cards_nouveau libdrm_nouveau)
		$(use_enable video_cards_radeon libdrm_radeon)
		)
	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	if use static-libs; then
		mv "${D}/$(get_libdir)"/libply{,-splash-core}.a \
			"${D}/usr/$(get_libdir)"/ || die 'mv *.a files failed'
		gen_usr_ldscript libply.so libply-splash-core.so
	else
		local la
		for la in "${D}/usr/$(get_libdir)"/plymouth/{*.la,renderers/*.la}; do
			einfo "Removing left ${la#${D}}"
			rm "${la}" || die "rm '${la}'"
		done
	fi

	insinto /usr/share/plymouth
	newins "${DISTDIR}"/gentoo-logo.png bizcom.png
}

pkg_postinst() {
	elog "Follow instructions on"
	elog ""
	elog "  http://dev.gentoo.org/~aidecoe/doc/en/plymouth.xml"
	elog ""
	elog "to set up Plymouth."
}