[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-lite: ChangeLog pcsc-lite-1.5.5.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/08/02 06:25:57

  Modified:             ChangeLog
  Added:                pcsc-lite-1.5.5.ebuild
  Log:
  Version bump.
  (Portage version: 13874-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 sys-apps/pcsc-lite/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	31 Jul 2009 14:52:25 -0000	1.71
+++ ChangeLog	2 Aug 2009 06:25:57 -0000	1.72
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pcsc-lite
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.71 2009/07/31 14:52:25 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.72 2009/08/02 06:25:57 arfrever Exp $
+
+*pcsc-lite-1.5.5 (02 Aug 2009)
+
+  02 Aug 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +pcsc-lite-1.5.5.ebuild:
+  Version bump.
 
   31 Jul 2009; <chainsaw@g.o> pcsc-lite-1.5.4.ebuild:
   Marked stable on AMD64 as requested by Arfrever Frehtes Taifersar Arahesis



1.1                  sys-apps/pcsc-lite/pcsc-lite-1.5.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.5.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.5.5.ebuild?rev=1.1&content-type=text/plain

Index: pcsc-lite-1.5.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.5.5.ebuild,v 1.1 2009/08/02 06:25:57 arfrever Exp $

EAPI="2"

inherit multilib

DESCRIPTION="PC/SC Architecture smartcard middleware library"
HOMEPAGE="http://www.linuxnet.com/middle.html"

if [[ "${PV}" = "9999" ]]; then
	inherit subversion autotools
	ESVN_REPO_URI="svn://svn.debian.org/pcsclite/trunk"
	S="${WORKDIR}/trunk"
else
	STUPID_NUM="3082"
	MY_P="${PN}-${PV/_/-}"
	SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${MY_P}.tar.bz2"
	S="${WORKDIR}/${MY_P}"
fi

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="hal static usb"

RDEPEND="usb? ( virtual/libusb:0 )
	hal? ( sys-apps/hal )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

pkg_setup() {
	if use hal && use usb; then
		ewarn "The usb and hal USE flags cannot be enabled at the same time"
		ewarn "Disabling the effect of USE=usb"
	fi
}

if [[ "${PV}" == "9999" ]]; then
	src_prepare() {
		S="${WORKDIR}/trunk/PCSC"
		cd "${S}"
		AT_M4DIR="m4" eautoreconf
	}
fi

src_configure() {
	local myconf
	if use hal; then
		myconf="--enable-libhal --disable-libusb"
	else
		myconf="--disable-libhal $(use_enable usb libusb)"
	fi

	econf \
		--docdir="/usr/share/doc/${PF}" \
		--enable-usbdropdir="/usr/$(get_libdir)/readers/usb" \
		${myconf} \
		$(use_enable static)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	prepalldocs

	dodoc AUTHORS DRIVERS HELP README SECURITY ChangeLog

	newinitd "${FILESDIR}/pcscd-init" pcscd
	newconfd "${FILESDIR}/pcscd-confd" pcscd
}