[gentoo-commits] gentoo-x86 commit in media-sound/snd: snd-12.8.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    12/02/07 08:00:49

  Modified:             ChangeLog
  Added:                snd-12.8.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.60                 media-sound/snd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/snd/ChangeLog?rev=1.60&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/snd/ChangeLog?rev=1.60&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/snd/ChangeLog?r1=1.59&r2=1.60

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/snd/ChangeLog,v
retrieving revision 1.59
retrieving revision 1.60
diff -u -r1.59 -r1.60
--- ChangeLog	4 Jan 2012 09:36:29 -0000	1.59
+++ ChangeLog	7 Feb 2012 08:00:49 -0000	1.60
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/snd
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/ChangeLog,v 1.59 2012/01/04 09:36:29 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/ChangeLog,v 1.60 2012/02/07 08:00:49 radhermit Exp $
+
+*snd-12.8 (07 Feb 2012)
+
+  07 Feb 2012; Tim Harder <radhermit@g.o> +snd-12.8.ebuild:
+  Version bump.
 
 *snd-12.7 (04 Jan 2012)
 



1.1                  media-sound/snd/snd-12.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/snd/snd-12.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/snd/snd-12.8.ebuild?rev=1.1&content-type=text/plain

Index: snd-12.8.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/snd/snd-12.8.ebuild,v 1.1 2012/02/07 08:00:49 radhermit Exp $

EAPI="4"

inherit multilib flag-o-matic autotools

DESCRIPTION="Snd is a sound editor"
HOMEPAGE="http://ccrma.stanford.edu/software/snd/"
SRC_URI="ftp://ccrma-ftp.stanford.edu/pub/Lisp/${P}.tar.gz"

SLOT="0"
LICENSE="as-is"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
IUSE="alsa doc fam fftw gmp gsl gtk jack ladspa motif opengl oss portaudio pulseaudio readline ruby +s7"

RDEPEND="media-libs/audiofile
	alsa? ( media-libs/alsa-lib )
	fam? ( virtual/fam )
	fftw? ( sci-libs/fftw )
	gmp? ( dev-libs/gmp
		dev-libs/mpc
		dev-libs/mpfr )
	gsl? ( sci-libs/gsl )
	gtk? ( x11-libs/gtk+:3
		x11-libs/pango
		x11-libs/cairo
		opengl? ( x11-libs/gtkglext ) )
	jack? ( media-sound/jack-audio-connection-kit )
	ladspa? ( media-libs/ladspa-sdk )
	motif? ( >=x11-libs/openmotif-2.3:0 )
	opengl? ( virtual/opengl )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )
	readline? ( sys-libs/readline )
	ruby? ( dev-lang/ruby )"

REQUIRED_USE="^^ (
		( !ruby !s7 )
		( ruby !s7 )
		( !ruby s7 )
	)"

pkg_setup() {
	if ! use gtk && ! use motif ; then
		ewarn "Warning: no graphic toolkit selected (gtk or motif)."
		ewarn "Upstream suggests to enable one of the toolkits (or both)"
		ewarn "or only the command line utilities will be helpful."
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-12.6-as-needed.patch
	sed -i -e "s:-O2 ::" configure.ac || die
	eautoreconf
}

src_configure() {
	# Workaround executable sections QA warning (bug #348754)
	append-ldflags -Wl,-z,noexecstack

	local myconf
	if use opengl ; then
		myconf+=" --with-just-gl"
	else
		myconf+=" --without-gl"
	fi

	if ! use ruby && ! use s7 ; then
		myconf+=" --without-extension-language"
	fi

	econf \
		$(use_with alsa) \
		$(use_with fam) \
		$(use_with fftw) \
		$(use_with gmp) \
		$(use_with gsl) \
		$(use_with gtk) \
		$(use_with jack) \
		$(use_with ladspa) \
		$(use_with motif) \
		$(use_with oss) \
		$(use_with portaudio) \
		$(use_with pulseaudio) \
		$(use_enable readline) \
		$(use_with ruby) \
		$(use_with s7) \
		--with-float-samples \
		${myconf}

}

src_compile() {
	emake snd

	# Do not compile ruby extensions for command line programs since they fail
	sed -i -e "s:HAVE_RUBY 1:HAVE_RUBY 0:" mus-config.h

	for i in sndinfo audinfo sndplay ; do
	   emake ${i}
	done
}

src_install () {
	dobin snd sndplay sndinfo audinfo

	if use ruby ; then
		insinto /usr/share/snd
		doins *.rb
	fi

	if use s7 ; then
		insinto /usr/share/snd
		doins *.scm
	fi

	dodoc README.Snd HISTORY.Snd NEWS
	use doc && dohtml -r *.html pix/*.png tutorial
}