[gentoo-commits] gentoo-x86 commit in net-misc/rdesktop: ChangeLog rdesktop-1.6.0-r2.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    09/06/30 09:43:15

  Modified:             ChangeLog
  Added:                rdesktop-1.6.0-r2.ebuild
  Log:
  Fix automagic dependency on libsamplerate, bug #275851. Also clean ebuild a bit
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.112                net-misc/rdesktop/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rdesktop/ChangeLog?rev=1.112&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rdesktop/ChangeLog?rev=1.112&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rdesktop/ChangeLog?r1=1.111&r2=1.112

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v
retrieving revision 1.111
retrieving revision 1.112
diff -u -r1.111 -r1.112
--- ChangeLog	21 May 2008 14:13:19 -0000	1.111
+++ ChangeLog	30 Jun 2009 09:43:15 -0000	1.112
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/rdesktop
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.111 2008/05/21 14:13:19 voyageur Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/ChangeLog,v 1.112 2009/06/30 09:43:15 voyageur Exp $
+
+*rdesktop-1.6.0-r2 (30 Jun 2009)
+
+  30 Jun 2009; Bernard Cafarelli <voyageur@g.o>
+  +rdesktop-1.6.0-r2.ebuild, +files/rdesktop-1.6.0-sound_configure.patch:
+  Fix automagic dependency on libsamplerate, bug #275851. Also clean ebuild
+  a bit
 
 *rdesktop-1.6.0-r1 (21 May 2008)
 



1.1                  net-misc/rdesktop/rdesktop-1.6.0-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rdesktop/rdesktop-1.6.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/rdesktop/rdesktop-1.6.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: rdesktop-1.6.0-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rdesktop/rdesktop-1.6.0-r2.ebuild,v 1.1 2009/06/30 09:43:15 voyageur Exp $

EAPI=2

inherit autotools eutils

MY_PV=${PV/_/-}

DESCRIPTION="A Remote Desktop Protocol Client"
HOMEPAGE="http://rdesktop.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="alsa ao debug ipv6 libsamplerate oss pcsc-lite"

S=${WORKDIR}/${PN}-${MY_PV}

RDEPEND=">=dev-libs/openssl-0.9.6b
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXau
	x11-libs/libXdmcp
	alsa? ( media-libs/alsa-lib )
	ao? ( >=media-libs/libao-0.8.6 )
	libsamplerate? ( media-libs/libsamplerate )
	pcsc-lite? ( sys-apps/pcsc-lite )"
DEPEND="${RDEPEND}
	x11-libs/libXt"

src_prepare() {
	# Prevent automatic stripping
	local strip="$(echo '$(STRIP) $(DESTDIR)$(bindir)/rdesktop')"
	sed -i -e "s:${strip}::" Makefile.in \
		|| die "sed failed in Makefile.in"

	# Automagic dependency on libsamplerate
	epatch "${FILESDIR}"/${P}-sound_configure.patch
	eautoreconf
}

src_configure() {
	if use ao; then
		sound_conf=$(use_with ao sound libao)
	else if use alsa; then
			sound_conf=$(use_with alsa sound alsa)
		else
			sound_conf=$(use_with oss sound oss)
		fi
	fi

	econf \
		--with-openssl=/usr \
		$(use_with debug) \
		$(use_with ipv6) \
		$(use_with libsamplerate) \
		$(use_enable pcsc-lite smartcard) \
		${sound_conf} \
		|| die "configuration failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "installation failed"
	dodoc doc/HACKING doc/TODO doc/keymapping.txt

	# For #180313 - applies to versions >= 1.5.0
	# Fixes sf.net bug
	# http://sourceforge.net/tracker/index.php?func=detail&aid=1725634&group_id=24366&atid=381349
	# check for next version to see if this needs to be removed
	insinto /usr/share/rdesktop/keymaps
	newins "${FILESDIR}/rdesktop-keymap-additional" additional
	newins "${FILESDIR}/rdesktop-keymap-cs" cs
	newins "${FILESDIR}/rdesktop-keymap-sk" sk
}