[gentoo-commits] gentoo-x86 commit in dev-ada/qtada: ChangeLog qtada-1.0.4.ebuild

[George Shapovalov (george)]

george      08/08/23 20:13:40

  Modified:             ChangeLog
  Added:                qtada-1.0.4.ebuild
  Log:
  added new version, only builds with gnat-gpl-2007, as 1.0.3
  (Portage version: 2.2_rc8/cvs/Linux 2.6.25-gentoo-r4 x86_64)

Revision  Changes    Path
1.2                  dev-ada/qtada/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-ada/qtada/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-ada/qtada/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-ada/qtada/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ada/qtada/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	20 May 2008 09:32:07 -0000	1.1
+++ ChangeLog	23 Aug 2008 20:13:40 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ada/qtada
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ada/qtada/ChangeLog,v 1.1 2008/05/20 09:32:07 george Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ada/qtada/ChangeLog,v 1.2 2008/08/23 20:13:40 george Exp $
+
+*qtada-1.0.4 (23 Aug 2008)
+
+  23 Aug 2008; George Shapovalov <george@g.o> +qtada-1.0.4.ebuild:
+  added new version, only builds with gnat-gpl-2007, as 1.0.3 (might be Ok
+  with -2008 on x86 only)
 
 *qtada-1.0.3 (20 May 2008)
 



1.1                  dev-ada/qtada/qtada-1.0.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-ada/qtada/qtada-1.0.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-ada/qtada/qtada-1.0.4.ebuild?rev=1.1&content-type=text/plain

Index: qtada-1.0.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ada/qtada/qtada-1.0.4.ebuild,v 1.1 2008/08/23 20:13:40 george Exp $

# We only need gnat.eclass for a few vars and helper functions.
# We will not use src_* functions though.
inherit eutils multilib gnat

IUSE=""

DESCRIPTION="Ada bindings for Qt library"
HOMEPAGE="http://www.qtada.com/"
SRC_URI="http://download.qtada.com/${PN}-gpl-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"

# qtada is quite picky atm. For example this version will only compile with
# the specified gnat, not even gnat-gcc-4.3.0 for example.
RDEPEND="=dev-lang/gnat-gpl-4.1.3.2007*
	dev-ada/asis-gpl
	>=x11-libs/qt-core-4.4.1
	>=x11-libs/qt-gui-4.4.1"

DEPEND="${RDEPEND}"

S="${WORKDIR}/${PN}-gpl-${PV}"

#LIBDIR=/usr/lib/ada/i686-pc-linux-gnu-gnat-gpl-4.1/qtada

pkg_setup() {
	local ActiveGnat=$(get_active_profile)
	if [[ ! ${ActiveGnat:((-12))} == "gnat-gpl-4.1" ]]; then
		ewarn "This version of qtada can only be compiled with gnat-gpl-4.1"
		die   "Please switch to  gnat-gpl-4.1 and try again"
	fi
#	if ! built_with_use ">=x11-libs/qt-4.0" accessibility ; then
#		die "Rebuild qt-4 with USE=accessibility"
#	fi
}

# As this version of qtada only compiles with gnat-gpl-4.1 and we already
# verified that it is active, we do not switch profiles or do any majic here.
# We simplt run build once, just need to set some path appropriately.
src_compile() {
	econf --datadir=${AdalibDataDir}/${PN} \
		--includedir=${AdalibSpecsDir}/${PN} \
		--libdir=${AdalibLibTop}/$(get_active_profile)/${PN} || die "econf failed"
	emake || die "make failed"
}

src_install() {
	# set common part of the path
	local InstTop=${AdalibLibTop}/$(get_active_profile)

	# run upstream setup
	einstall \
		libdir=${D}/${InstTop}/${PN} \
		bindir=${D}/${InstTop}/bin \
		includedir=${D}/${AdalibSpecsDir} || die "install failed"

	# move .ali file together with .so's
	mv "${D}"/${InstTop}/${PN}/${PN}/*.ali "${D}"/${InstTop}/${PN}/
	rmdir "${D}"/${InstTop}/${PN}/${PN}/

	# arrange and fix gpr files
	mv "${D}"/${InstTop}/${PN}/gnat "${D}"/${InstTop}/gpr
	sed -i -e "s:/usr/include:${AdalibSpecsDir}:" \
		-e "s:/usr/lib:${InstTop}/${PN}:" \
		-e "s:${PN}/${PN}:${PN}" "${D}"/${InstTop}/gpr/*.gpr

	# Create an environment file
	local SpecFile="${D}/usr/share/gnat/eselect/${PN}/$(get_active_profile)"
	dodir /usr/share/gnat/eselect/${PN}/
	echo "PATH=${InstTop}/bin" > "${SpecFile}"
	echo "ADA_INCLUDE_PATH=${AdalibSpecsDir}/${PN}/core" >> "${SpecFile}"
	echo "ADA_OBJECTS_PATH=${InstTop}/${PN}" >> "${SpecFile}"
	echo "ADA_PROJECT_PATH=${InstTop}/gpr" >> "${SpecFile}"

	# install docs
	dodoc AUTHORS NEWS README
	mv "${D}"/usr/examples/${PN} "${D}"/usr/share/doc/${PF}/examples
	rmdir "${D}"/usr/examples/
}