chainsaw    09/04/30 21:43:59

  Modified:             ChangeLog
  Added:                audacious-plugins-2.0_alpha3.ebuild
  Removed:              audacious-plugins-2.0_alpha2.ebuild
  Log:
  Okay, so maybe there was a little filedescriptor leak in that GIO plugin. The third alpha will work better then ever.
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.107                media-plugins/audacious-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	30 Apr 2009 16:41:33 -0000	1.106
+++ ChangeLog	30 Apr 2009 21:43:59 -0000	1.107
@@ -1,6 +1,13 @@
 # ChangeLog for media-plugins/audacious-plugins
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.106 2009/04/30 16:41:33 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/ChangeLog,v 1.107 2009/04/30 21:43:59 chainsaw Exp $
+
+*audacious-plugins-2.0_alpha3 (30 Apr 2009)
+
+  30 Apr 2009; <chainsaw@g.o> -audacious-plugins-2.0_alpha2.ebuild,
+  +audacious-plugins-2.0_alpha3.ebuild:
+  Okay, so maybe there was a little filedescriptor leak in that GIO plugin.
+  The third alpha will work better then ever.
 
 *audacious-plugins-2.0_alpha2 (30 Apr 2009)
 



1.1                  media-plugins/audacious-plugins/audacious-plugins-2.0_alpha3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.0_alpha3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.0_alpha3.ebuild?rev=1.1&content-type=text/plain

Index: audacious-plugins-2.0_alpha3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/audacious-plugins/audacious-plugins-2.0_alpha3.ebuild,v 1.1 2009/04/30 21:43:59 chainsaw Exp $

inherit eutils flag-o-matic

MY_P="${P/_/-}"
S="${WORKDIR}/${PN}-2.0-alpha2.1"
DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
HOMEPAGE="http://audacious-media-player.org/"
SRC_URI="http://distfiles.atheme.org/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="adplug alsa arts cdaudio esd flac gnome icecast ipv6 jack lirc mp3 mtp musepack nls oss pulseaudio scrobbler sdl sid sndfile sse2 timidity tta vorbis wavpack wma"

RDEPEND="app-arch/unzip
	>=dev-libs/libcdio-0.79-r1
	>=dev-libs/dbus-glib-0.60
	dev-libs/libxml2
	>=media-sound/audacious-2.0_alpha2
	>=net-misc/neon-0.26.4
	>=x11-libs/gtk+-2.14
	adplug? ( >=dev-cpp/libbinio-1.4 )
	alsa? ( >=media-libs/alsa-lib-1.0.16 )
	arts? ( kde-base/arts )
	cdaudio? ( >=media-libs/libcddb-1.2.1 )
	esd? ( >=media-sound/esound-0.2.38-r1 )
	flac? ( >=media-libs/libvorbis-1.0
		>=media-libs/flac-1.2.1-r1 )
	jack? ( >=media-libs/bio2jack-0.4
		media-sound/jack-audio-connection-kit )
	lirc? ( app-misc/lirc )
	mp3? ( media-libs/libmad )
	mtp? ( media-libs/libmtp )
	musepack? ( media-libs/libmpcdec media-libs/taglib )
	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
	scrobbler? ( net-misc/curl
		     media-libs/musicbrainz )
	sdl? (	>=media-libs/libsdl-1.2.5 )
	sid? ( media-libs/libsidplay )
	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
	timidity? ( media-sound/timidity++ )
	tta? ( media-libs/libid3tag )
	vorbis? ( >=media-libs/libvorbis-1.2.0
		  >=media-libs/libogg-1.1.3 )
	wavpack? ( >=media-sound/wavpack-4.41.0 )
	wma? ( >=media-libs/libmms-0.3 )"

DEPEND="${RDEPEND}
	nls? ( dev-util/intltool )
	>=dev-util/pkgconfig-0.9.0"

mp3_warning() {
	if ! useq mp3 ; then
		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
	fi
}

src_compile() {
	# This is masked in the portage tree, so I'll save you the
	# popup. Be good, bugs go upstream and we like patches.
	append-flags -DNOT_ALPHA_RELEASE

	mp3_warning

	econf \
		--enable-aac \
		--enable-chardet \
		--enable-dbus \
		--enable-modplug \
		--enable-neon \
		--disable-coreaudio \
		--disable-dockalbumart \
		--disable-projectm \
		--disable-projectm-1.0 \
		--disable-rootvis \
		$(use_enable adplug) \
		$(use_enable alsa) \
		$(use_enable alsa bluetooth) \
		$(use_enable arts) \
		$(use_enable cdaudio) \
		$(use_enable esd) \
		$(use_enable flac flacng) \
		$(use_enable flac filewriter_flac) \
		$(use_enable ipv6) \
		$(use_enable jack) \
		$(use_enable gnome gnomeshortcuts) \
		$(use_enable lirc) \
		$(use_enable mp3) \
		$(use_enable musepack) \
		$(use_enable mtp mtp_up) \
		$(use_enable nls) \
		$(use_enable oss) \
		$(use_enable pulseaudio pulse) \
		$(use_enable sdl paranormal) \
		$(use_enable sid) \
		$(use_enable sndfile) \
		$(use_enable sse2) \
		$(use_enable timidity) \
		$(use_enable tta) \
		$(use_enable vorbis) \
		$(use_enable vorbis filewriter_vorbis) \
		$(use_enable wavpack) \
		$(use_enable wma) \
		$(use_enable wma mms) \
		|| die

	emake || die "make failed"
}

src_install() {
	make DESTDIR="${D}" install || die
	dodoc AUTHORS
}

pkg_postinst() {
	mp3_warning
}