[gentoo-commits] gentoo-x86 commit in media-sound/lastfmplayer: lastfmplayer-1.5.1.31879-r3.ebuild ChangeLog lastfmplayer-1.5.1.31879-r2.ebuild

[Markos Chandras (hwoarang)]

hwoarang    09/03/22 23:42:49

  Modified:             ChangeLog
  Added:                lastfmplayer-1.5.1.31879-r3.ebuild
  Removed:              lastfmplayer-1.5.1.31879-r2.ebuild
  Log:
  New patch for qt-4.5 compatibility. Removing old ebuild
  (Portage version: 2.2_rc26/cvs/Linux x86_64)

Revision  Changes    Path
1.36                 media-sound/lastfmplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lastfmplayer/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lastfmplayer/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lastfmplayer/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	17 Feb 2009 20:07:23 -0000	1.35
+++ ChangeLog	22 Mar 2009 23:42:49 -0000	1.36
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/lastfmplayer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v 1.35 2009/02/17 20:07:23 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/ChangeLog,v 1.36 2009/03/22 23:42:49 hwoarang Exp $
+
+*lastfmplayer-1.5.1.31879-r3 (22 Mar 2009)
+
+  22 Mar 2009; Markos Chandras <hwoarang@g.o>
+  -files/makefile-qt45.patch, +files/volumeslider_h-qt45.patch,
+  -lastfmplayer-1.5.1.31879-r2.ebuild, +lastfmplayer-1.5.1.31879-r3.ebuild:
+  New patch for qt-4.5 compatibility. Removing old ebuild due to ugly
+  workaround
 
 *lastfmplayer-1.5.1.31879-r2 (17 Feb 2009)
 



1.1                  media-sound/lastfmplayer/lastfmplayer-1.5.1.31879-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.1.31879-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.1.31879-r3.ebuild?rev=1.1&content-type=text/plain

Index: lastfmplayer-1.5.1.31879-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/lastfmplayer/lastfmplayer-1.5.1.31879-r3.ebuild,v 1.1 2009/03/22 23:42:49 hwoarang Exp $

EAPI="2"

inherit eutils multilib qt4

MY_P="${P/lastfmplayer/lastfm}.dfsg"

DESCRIPTION="A player for last.fm radio streams"
HOMEPAGE="http://www.last.fm/help/player"
SRC_URI="mirror://debian/pool/main/l/lastfm/lastfm_${PV}.dfsg.orig.tar.gz
	mirror://debian/pool/main/l/lastfm/lastfm_${PV}.dfsg-1.diff.gz"
#http://cdn.last.fm/client/src/${MY_P}.src.tar.bz2

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ipod"
RESTRICT="mirror"

RDEPEND="|| ( ( x11-libs/qt-gui:4 x11-libs/qt-sql:4 ) x11-libs/qt:4 )
	media-libs/libsamplerate
	sci-libs/fftw
	media-libs/libmad
	ipod? ( >=media-libs/libgpod-0.5.2 )
	media-libs/alsa-lib"
DEPEND="${RDEPEND}
	app-arch/sharutils"

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}"/volumeslider_h-qt45.patch
)

src_prepare() {
	qt4_src_prepare
	cd "${WORKDIR}"
	epatch lastfm_${PV}.dfsg-1.diff
	cd "${S}"
	for i in $(< debian/patches/series); do
		epatch debian/patches/$i
	done
	if ! use ipod ; then
		sed -i '/src\/mediadevices\/ipod/d' LastFM.pro || die "sed failed"
	fi
}

src_compile() {
	emake || die "emake failed"
	cd i18n; lrelease *.ts
}

src_install() {
	# Docs
	dodoc ChangeLog README debian/README.source || die "dodoc failed"
	doman debian/lastfm.1 || die "doman failed"

	# Copied from debian/rules
	uudecode -o - debian/icons.tar.gz.uu | tar -xzf -
	uudecode -o - debian/trayicons22.tar.gz.uu | tar -xzf -
	insinto /usr/share
	doins -r icons
	insinto /usr/share/lastfm/icons
	doins user_*.png

	sed -i -e "s,/usr/lib,/usr/$(get_libdir),g" debian/lastfm.install
	# make directories
	for i in $(<debian/lastfm.install); do [ ${i:0:1} == / ] && dodir $i; done
	# debian installation
	sed -i -e "s:^:mv :" -e 's: /:${D}/:' debian/lastfm.install
	bash debian/lastfm.install

	# copied..
	mv "${D}"/usr/bin/lastfm.sh "${D}"/usr/bin/lastfm
	fperms 755 /usr/bin/lastfm
	rm -f "${D}"/usr/share/lastfm/icons/{*profile24,systray_mac}.png
}

pkg_postinst() {
	elog "To use the Last.fm player with a mozilla based browser:"
	elog " 1. Go to about:config in the browser"
	elog " 2. Right-click on the page"
	elog " 3. Select New and then String"
	elog " 4. For the name: network.protocol-handler.app.lastfm"
	elog " 5. For the value: /usr/bin/lastfm"
	elog
	elog "If you experience awkward fonts or widgets, try running qtconfig."
}