Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Samuli Suominen (ssuominen)" <ssuominen@g.o>
Subject: gentoo-x86 commit in x11-terms/xterm: ChangeLog xterm-281.ebuild
Date: Tue, 26 Jun 2012 17:30:06 +0000 (UTC)
ssuominen    12/06/26 17:30:06

  Modified:             ChangeLog
  Added:                xterm-281.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha111/cvs/Linux x86_64)

Revision  Changes    Path
1.358                x11-terms/xterm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/xterm/ChangeLog?rev=1.358&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/xterm/ChangeLog?rev=1.358&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/xterm/ChangeLog?r1=1.357&r2=1.358

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/xterm/ChangeLog,v
retrieving revision 1.357
retrieving revision 1.358
diff -u -r1.357 -r1.358
--- ChangeLog	24 Jun 2012 19:47:33 -0000	1.357
+++ ChangeLog	26 Jun 2012 17:30:06 -0000	1.358
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/xterm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/xterm/ChangeLog,v 1.357 2012/06/24 19:47:33 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/xterm/ChangeLog,v 1.358 2012/06/26 17:30:06 ssuominen Exp $
+
+*xterm-281 (26 Jun 2012)
+
+  26 Jun 2012; Samuli Suominen <ssuominen@g.o> +xterm-281.ebuild:
+  Version bump.
 
   24 Jun 2012; Agostino Sarubbo <ago@g.o> xterm-279.ebuild:
   Stable for x86, wrt bug #419473



1.1                  x11-terms/xterm/xterm-281.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/xterm/xterm-281.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/xterm/xterm-281.ebuild?rev=1.1&content-type=text/plain

Index: xterm-281.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/xterm/xterm-281.ebuild,v 1.1 2012/06/26 17:30:06 ssuominen Exp $

EAPI=4
inherit eutils multilib

DESCRIPTION="Terminal Emulator for X Windows"
HOMEPAGE="http://dickey.his.com/xterm/"
SRC_URI="ftp://invisible-island.net/${PN}/${P}.tgz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="toolbar truetype unicode Xaw3d"

COMMON_DEPEND="kernel_linux? ( sys-libs/libutempter )
	kernel_FreeBSD? ( || ( >=sys-freebsd/freebsd-lib-9.0 sys-libs/libutempter ) )
	>=sys-libs/ncurses-5.7-r7
	x11-apps/xmessage
	x11-libs/libX11
	x11-libs/libXaw
	x11-libs/libXft
	x11-libs/libxkbfile
	x11-libs/libXmu
	x11-libs/libXrender
	x11-libs/libXt
	unicode? ( x11-apps/luit )
	Xaw3d? ( x11-libs/libXaw3d )"
RDEPEND="${COMMON_DEPEND}
	media-fonts/font-misc-misc"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	x11-proto/kbproto
	x11-proto/xproto"

pkg_setup() {
	DEFAULTS_DIR="${EPREFIX}"/usr/share/X11/app-defaults
}

src_configure() {
	# looking for reason why crosscompile failed? try restoring this:
	# --x-libraries="${ROOT}usr/$(get_libdir)"
	# -ssuominen, 2011

	econf \
		--libdir="${EPREFIX}"/etc \
		--disable-full-tgetent \
		--with-app-defaults=${DEFAULTS_DIR} \
		--disable-setuid \
		--disable-setgid \
		--with-utempter \
		--with-x \
		$(use_with Xaw3d) \
		--disable-imake \
		--enable-256-color \
		--enable-broken-osc \
		--enable-broken-st \
		--enable-exec-xterm \
		$(use_enable truetype freetype) \
		--enable-i18n \
		--enable-load-vt-fonts \
		--enable-logging \
		$(use_enable toolbar) \
		$(use_enable unicode mini-luit) \
		$(use_enable unicode luit) \
		--enable-wide-chars \
		--enable-dabbrev \
		--enable-warnings
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc README{,.i18n} ctlseqs.txt
	dohtml xterm.log.html
	domenu *.desktop

	# Fix permissions -- it grabs them from live system, and they can
	# be suid or sgid like they were in pre-unix98 pty or pre-utempter days,
	# respectively (#69510).
	# (info from Thomas Dickey) - Donnie Berkholz <spyderous@g.o>
	fperms 0755 /usr/bin/xterm

	# restore the navy blue
	sed -i -e "s:blue2$:blue:" "${ED}"${DEFAULTS_DIR}/XTerm-color
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
proj/R_overlay:master commit in: roverlay/overlay/
Next by thread:
gentoo-x86 commit in www-apps/postfixadmin: ChangeLog postfixadmin-2.3.5.ebuild
Previous by date:
proj/R_overlay:master commit in: /
Next by date:
gentoo-x86 commit in www-apps/postfixadmin: ChangeLog postfixadmin-2.3.5.ebuild


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.