[gentoo-commits] gentoo-x86 commit in media-plugins/vdr-xineliboutput: ChangeLog vdr-xineliboutput-1.0.0.ebuild

[Matthias Schwarzott (zzam)]

zzam        08/04/24 20:03:29

  Modified:             ChangeLog
  Added:                vdr-xineliboutput-1.0.0.ebuild
  Log:
  Version bumped. Changes based on ebuild from mpz in #gentoo-vdr.
  (Portage version: 2.1.5_rc6)

Revision  Changes    Path
1.38                 media-plugins/vdr-xineliboutput/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	18 Apr 2008 20:40:16 -0000	1.37
+++ ChangeLog	24 Apr 2008 20:03:29 -0000	1.38
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/vdr-xineliboutput
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v 1.37 2008/04/18 20:40:16 zzam Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/ChangeLog,v 1.38 2008/04/24 20:03:29 zzam Exp $
+
+*vdr-xineliboutput-1.0.0 (24 Apr 2008)
+
+  24 Apr 2008; Matthias Schwarzott <zzam@g.o>
+  +vdr-xineliboutput-1.0.0.ebuild:
+  Version bumped. Changes based on ebuild from mpz in #gentoo-vdr.
 
   18 Apr 2008; Matthias Schwarzott <zzam@g.o>
   vdr-xineliboutput-1.0.0_rc2.ebuild:



1.1                  media-plugins/vdr-xineliboutput/vdr-xineliboutput-1.0.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-1.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-1.0.0.ebuild?rev=1.1&content-type=text/plain

Index: vdr-xineliboutput-1.0.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/vdr-xineliboutput/vdr-xineliboutput-1.0.0.ebuild,v 1.1 2008/04/24 20:03:29 zzam Exp $

inherit vdr-plugin eutils multilib versionator

MY_PV=${PV/_/}
MY_P=${PN}-${MY_PV}

SO_VERSION="${PV%_p*}"
SO_VERSION="${SO_VERSION/_/}"

DESCRIPTION="Video Disk Recorder Xinelib PlugIn"
HOMEPAGE="http://sourceforge.net/projects/xineliboutput/"
SRC_URI="mirror://sourceforge/${PN#vdr-}/${MY_P}-1.tgz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="fbcon X libextractor"

RDEPEND=">=media-video/vdr-1.4.0
		>=media-libs/xine-lib-1.1.1
		media-libs/jpeg
		libextractor? ( >=media-libs/libextractor-0.5.20 )
		X? (
			x11-proto/xextproto
			x11-proto/xf86vidmodeproto
			x11-proto/xproto
			x11-proto/renderproto
		)"

DEPEND="${RDEPEND}
		sys-kernel/linux-headers
		X? (
			x11-libs/libX11
			x11-libs/libXv
			x11-libs/libXext
			x11-libs/libXrender
		)"

S=${WORKDIR}/${MY_P#vdr-}

VDR_CONFD_FILE=${FILESDIR}/confd-1.0.0_pre6

NO_GETTEXT_HACK=1

use_onoff() {
	if use "$1"; then
		echo 1
	else
		echo 0
	fi
}

src_unpack() {
	vdr-plugin_src_unpack

	cd "${S}"

	XINE_PLUGIN_DIR=$(xine-config --plugindir)
	if [[ ${XINE_PLUGIN_DIR} = "" ]]; then
		eerror "Could not find xine plugin dir"
		die "Could not find xine plugin dir"
	fi
	# stop some automagic overwriting the stuff we set
	sed -e '/XINELIBOUTPUT_VDRPLUGIN = 1/s/^/#/' \
		-e '/HAVE_EXTRACTOR_H = 1/s/^/#/' \
		-i Makefile

	cat >>Make.config <<-EOF
		XINELIBOUTPUT_XINEPLUGIN = 1
		XINELIBOUTPUT_VDRPLUGIN = 1

		XINELIBOUTPUT_FB = $(use_onoff fbcon)
		XINELIBOUTPUT_X11 = $(use_onoff X)

		HAVE_XRENDER = 1
		HAVE_XDPMS = 1
		HAVE_EXTRACTOR_H = $(use_onoff libextractor)
	EOF

	# patching makefile to work with this
	# $ rm ${outdir}/file; cp file ${outdir}/file
	# work in the sandbox
	sed -i Makefile \
		-e 's:XINEPLUGINDIR.*=.*:XINEPLUGINDIR = '"${WORKDIR}/lib:" \
		-e 's:VDRINCDIR.*=.*:VDRINCDIR ?= /usr/include:'
	mkdir -p "${WORKDIR}/lib"
}

src_install() {
	vdr-plugin_src_install

	use fbcon && dobin vdr-fbfe
	use X && dobin vdr-sxfe

	# There may be no sub-plugin, depending on use-flags
	insinto ${VDR_PLUGIN_DIR}
	local f
	for f in libxineliboutput*.so.${SO_VERSION}; do
		[[ -f "$f" ]] || continue
		doins "${f}" || die "could not install sub-plugin ${f}"
	done

	insinto "${XINE_PLUGIN_DIR}"
	doins xineplug_inp_*.so

	insinto "${XINE_PLUGIN_DIR}"/post
	doins xineplug_post_*.so
}



-- 
gentoo-commits@l.g.o mailing list