Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Arfrever Frehtes Taifersar Arahesis (arfrever)" <arfrever@g.o>
Subject: gentoo-x86 commit in dev-python/logilab-common: ChangeLog logilab-common-0.54.0.ebuild
Date: Mon, 17 Jan 2011 17:59:21 +0000 (UTC)
arfrever    11/01/17 17:59:21

  Modified:             ChangeLog
  Added:                logilab-common-0.54.0.ebuild
  Log:
  Version bump. Fixed test failures with Python 2.7 (bug #293913).
  
  (Portage version: 2.2.0_alpha15_p12/cvs/Linux x86_64)

Revision  Changes    Path
1.85                 dev-python/logilab-common/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.85&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.85&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/ChangeLog?r1=1.84&r2=1.85

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v
retrieving revision 1.84
retrieving revision 1.85
diff -u -r1.84 -r1.85
--- ChangeLog	8 Jan 2011 01:33:59 -0000	1.84
+++ ChangeLog	17 Jan 2011 17:59:21 -0000	1.85
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/logilab-common
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.84 2011/01/08 01:33:59 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.85 2011/01/17 17:59:21 arfrever Exp $
+
+*logilab-common-0.54.0 (17 Jan 2011)
+
+  17 Jan 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  -logilab-common-0.50.3.ebuild, -logilab-common-0.51.1.ebuild,
+  -files/logilab-common-0.51.1-python-2.7.patch, +logilab-common-0.54.0.ebuild:
+  Version bump. Fixed test failures with Python 2.7 (bug #293913).
 
   08 Jan 2011; Brent Baude <ranger@g.o> logilab-common-0.52.1.ebuild:
   Marking logilab-common-0.52.1 ppc for bug 345487



1.1                  dev-python/logilab-common/logilab-common-0.54.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/logilab-common-0.54.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/logilab-common/logilab-common-0.54.0.ebuild?rev=1.1&content-type=text/plain

Index: logilab-common-0.54.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/logilab-common-0.54.0.ebuild,v 1.1 2011/01/17 17:59:21 arfrever Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"

inherit distutils

DESCRIPTION="Useful miscellaneous modules used by Logilab projects"
HOMEPAGE="http://www.logilab.org/projects/common/ http://pypi.python.org/pypi/logilab-common"
SRC_URI="ftp://ftp.logilab.org/pub/common/${P}.tar.gz mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="test"

# dev-python/unittest2 is not required with Python >=3.2.
RDEPEND="dev-python/setuptools
	dev-python/unittest2"
# Tests using dev-python/psycopg are skipped when dev-python/psycopg isn't installed.
DEPEND="${RDEPEND}
	test? (
		dev-python/egenix-mx-base
		!dev-python/psycopg[-mxdatetime]
	)"

PYTHON_MODNAME="logilab"

src_test() {
	testing() {
		# Install temporarily.
		local tpath="${T}/test-${PYTHON_ABI}"
		local spath="${tpath}${EPREFIX}$(python_get_sitedir)"

		"$(PYTHON)" setup.py build -b "build-${PYTHON_ABI}" install --root="${tpath}" || die "Installation for tests failed with $(python_get_implementation) $(python_get_version)"

		# pytest uses tests placed relatively to the current directory.
		pushd "${spath}" > /dev/null || return 1
		if [[ "${PYTHON_ABI}" == 3.* ]]; then
			# Support for Python 3 is experimental. Some tests are known to fail.
			PYTHONPATH="${spath}" "$(PYTHON)" "${tpath}${EPREFIX}/usr/bin/pytest" -v
		else
			PYTHONPATH="${spath}" "$(PYTHON)" "${tpath}${EPREFIX}/usr/bin/pytest" -v || return 1
		fi
		popd > /dev/null || return 1
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	python_generate_wrapper_scripts -E -f -q "${ED}usr/bin/pytest"

	doman doc/pytest.1 || die "doman failed"

	delete_tests() {
		rm -fr "${ED}$(python_get_sitedir)/${PN/-//}/test"
	}
	python_execute_function -q delete_tests
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in dev-libs/glib: glib-2.26.1-r1.ebuild ChangeLog glib-2.26.0-r1.ebuild
Next by thread:
gentoo-x86 commit in dev-python/logilab-common: ChangeLog logilab-common-0.54.0.ebuild
Previous by date:
gentoo-x86 commit in dev-libs/glib: glib-2.26.1-r1.ebuild ChangeLog glib-2.26.0-r1.ebuild
Next by date:
gentoo-x86 commit in app-emulation/qemu-kvm: ChangeLog qemu-kvm-0.13.0-r1.ebuild qemu-kvm-0.13.0-r2.ebuild qemu-kvm-9999.ebuild


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.