[gentoo-commits] gentoo-x86 commit in games-arcade/ultrastar-ng: ChangeLog ultrastar-ng-0.2.0.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    07/11/02 19:39:38

  Modified:             ChangeLog
  Added:                ultrastar-ng-0.2.0.ebuild
  Log:
  version bump - ebuild patch from Vincent via bug #197876
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.2                  games-arcade/ultrastar-ng/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	6 Jul 2007 20:58:10 -0000	1.1
+++ ChangeLog	2 Nov 2007 19:39:37 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/ultrastar-ng
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog,v 1.1 2007/07/06 20:58:10 tupone Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog,v 1.2 2007/11/02 19:39:37 mr_bones_ Exp $
+
+*ultrastar-ng-0.2.0 (02 Nov 2007)
+
+  02 Nov 2007; Michael Sterrett <mr_bones_@g.o>
+  +ultrastar-ng-0.2.0.ebuild:
+  version bump - ebuild patch from Vincent via bug #197876
 
 *ultrastar-ng-0.1.4 (06 Jul 2007)
 



1.1                  games-arcade/ultrastar-ng/ultrastar-ng-0.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/ultrastar-ng/ultrastar-ng-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-arcade/ultrastar-ng/ultrastar-ng-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: ultrastar-ng-0.2.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit eutils games

MY_PN=UltraStar-ng
MY_P=${MY_PN}-${PV}

DESCRIPTION="SingStar GPL clone"
HOMEPAGE="http://sourceforge.net/projects/ultrastar-ng/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="novideo opengl xine debug alsa gstreamer portaudio"

RDEPEND="gnome-base/librsvg
	dev-libs/boost
	x11-libs/pango
	media-libs/sdl-image
	media-libs/sdl-gfx
	xine? ( media-libs/xine-lib )
	!xine? ( media-libs/gstreamer )
	opengl? (
		virtual/opengl
		virtual/glu
	)
	alsa? ( media-libs/alsa-lib )
	portaudio? ( media-libs/portaudio )
	gstreamer? ( >=media-libs/gstreamer-0.10 )
	!novideo? ( media-libs/smpeg )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	games_pkg_setup
	if use opengl && ! built_with_use media-libs/libsdl opengl; then
		eerror "opengl flag set, but libsdl wasn't build with opengl support"
	fi
}

src_compile() {
	local myconf

	if use novideo; then
		myconf="--with-video=disable"
	else
		myconf="--with-video=smpeg"
	fi
	if use opengl; then
		myconf="$myconf --with-graphic-driver=opengl"
	else
		myconf="$myconf --with-graphic-driver=sdl"
	fi
	if use xine; then
		myconf="$myconf --with-audio=xine"
	else
		myconf="$myconf --with-audio=gstreamer"
	fi

	
	egamesconf \
		${myconf} \
		$(use_enable debug) \
		$(use_enable portaudio record-portaudio) \
		$(use_enable gstreamer record-gst) \
		$(use_enable alsa record-alsa) \
		|| die
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	keepdir "${GAMES_DATADIR}"/${PN}/songs
	mv "${D}${GAMES_DATADIR}"/{applications,pixmaps} "${D}"/usr/share/
	dodoc AUTHORS ChangeLog README TODO
	prepgamesdirs
}



-- 
gentoo-commits@g.o mailing list