ssuominen    12/06/19 06:50:48

  Modified:             ChangeLog
  Added:                psmisc-22.18.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.132                sys-process/psmisc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/psmisc/ChangeLog?rev=1.132&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/psmisc/ChangeLog?rev=1.132&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/psmisc/ChangeLog?r1=1.131&r2=1.132

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-process/psmisc/ChangeLog,v
retrieving revision 1.131
retrieving revision 1.132
diff -u -r1.131 -r1.132
--- ChangeLog	19 Jun 2012 06:48:54 -0000	1.131
+++ ChangeLog	19 Jun 2012 06:50:48 -0000	1.132
@@ -1,6 +1,11 @@
 # ChangeLog for sys-process/psmisc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/ChangeLog,v 1.131 2012/06/19 06:48:54 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/ChangeLog,v 1.132 2012/06/19 06:50:48 ssuominen Exp $
+
+*psmisc-22.18 (19 Jun 2012)
+
+  19 Jun 2012; Samuli Suominen <ssuominen@g.o> +psmisc-22.18.ebuild:
+  Version bump.
 
   19 Jun 2012; Samuli Suominen <ssuominen@g.o> psmisc-22.16.ebuild:
   ppc64 stable wrt #420047



1.1                  sys-process/psmisc/psmisc-22.18.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/psmisc/psmisc-22.18.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-process/psmisc/psmisc-22.18.ebuild?rev=1.1&content-type=text/plain

Index: psmisc-22.18.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-process/psmisc/psmisc-22.18.ebuild,v 1.1 2012/06/19 06:50:48 ssuominen Exp $

EAPI=4

DESCRIPTION="A set of tools that use the proc filesystem"
HOMEPAGE="http://psmisc.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
IUSE="ipv6 nls selinux X"

RDEPEND=">=sys-libs/ncurses-5.7-r7
	nls? ( virtual/libintl )
	selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.2.6b
	nls? ( sys-devel/gettext )"

DOCS="AUTHORS ChangeLog NEWS README"

src_configure() {
	econf \
		$(use_enable selinux) \
		--disable-harden-flags \
		$(use_enable ipv6) \
		$(use_enable nls)
}

src_compile() {
	# peekfd is a fragile crap hack #330631
	nonfatal emake -C src peekfd || touch src/peekfd{.o,}
	emake
}

src_install() {
	default

	use X || rm -f "${ED}"/usr/bin/pstree.x11

	[[ -s ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/bin/peekfd
	[[ -e ${ED}/usr/bin/peekfd ]] || rm -f "${ED}"/usr/share/man/man1/peekfd.1

	# fuser is needed by init.d scripts
	dodir /bin
	mv -vf "${ED}"/usr/bin/fuser "${ED}"/bin || die
}