[gentoo-commits] gentoo-x86 commit in app-arch/file-roller: ChangeLog file-roller-2.22.2.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/04/11 15:54:42

  Modified:             ChangeLog
  Added:                file-roller-2.22.2.ebuild
  Log:
  bump to 2.22.2. Don't use sync IO, raise glib and nautilus deps.
  (Portage version: 2.1.5_rc2)

Revision  Changes    Path
1.233                app-arch/file-roller/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.233&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.233&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/ChangeLog?r1=1.232&r2=1.233

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v
retrieving revision 1.232
retrieving revision 1.233
diff -u -r1.232 -r1.233
--- ChangeLog	7 Apr 2008 23:05:41 -0000	1.232
+++ ChangeLog	11 Apr 2008 15:54:42 -0000	1.233
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/file-roller
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.232 2008/04/07 23:05:41 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.233 2008/04/11 15:54:42 eva Exp $
+
+*file-roller-2.22.2 (11 Apr 2008)
+
+  11 Apr 2008; Gilles Dartiguelongue <eva@g.o>
+  +file-roller-2.22.2.ebuild:
+  bump to 2.22.2. Don't use sync IO, raise glib and nautilus deps.
 
 *file-roller-2.22.1 (07 Apr 2008)
 



1.1                  app-arch/file-roller/file-roller-2.22.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/file-roller-2.22.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/file-roller/file-roller-2.22.2.ebuild?rev=1.1&content-type=text/plain

Index: file-roller-2.22.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-2.22.2.ebuild,v 1.1 2008/04/11 15:54:42 eva Exp $

inherit eutils gnome2

DESCRIPTION="archive manager for GNOME"
HOMEPAGE="http://fileroller.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="nautilus"

RDEPEND=">=dev-libs/glib-2.15.0
	>=x11-libs/gtk+-2.10
	>=gnome-base/libgnome-2.6
	>=gnome-base/libgnomeui-2.6
	>=gnome-base/gnome-vfs-2.10
	>=gnome-base/libglade-2.4
	>=gnome-base/gconf-2
	nautilus? ( >=gnome-base/nautilus-2.22.2 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	>=dev-util/pkgconfig-0.19
	>=app-text/gnome-doc-utils-0.3.2"

DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF} --disable-scrollkeeper"

	if ! use nautilus ; then
		G2CONF="${G2CONF} --disable-nautilus-actions"
	fi
}

src_unpack() {
	gnome2_src_unpack

	# Use absolute path to GNU tar since star doesn't have the same
	# options.  On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
	epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch

	# use a local rpm2cpio script to avoid the dep
	epatch "${FILESDIR}"/${PN}-2.10-use_fr_rpm2cpio.patch
}

src_install() {
	gnome2_src_install
	dobin "${FILESDIR}"/rpm2cpio-file-roller
}

pkg_postinst() {
	elog "${PN} is a frontend for several archiving utility. If you want a"
	elog "particular achive format support, see ${HOMEPAGE}"
	elog "and install the relevant package."
	elog
	elog "for example:"
	elog "  7-zip   - app-arch/p7zip"
	elog "  ace     - app-arch/unace"
	elog "  arj     - app-arch/arj"
	elog "  lzma    - app-arch/lzma"
	elog "  lzop    - app-arch/lzop"
	elog "  cpio    - app-arch/cpio"
	elog "  iso     - app-arch/cdrtools"
	elog "  jar,zip - app-arch/zip and app-arch/unzip"
	elog "  lha     - app-arch/lha"
	elog "  rar     - app-arch/unrar"
	elog "  rpm     - app-arch/rpm"
	elog "  unstuff - app-arch/stuffit"
	elog "  zoo     - app-arch/zoo"
}



-- 
gentoo-commits@l.g.o mailing list