[gentoo-commits] gentoo-x86 commit in media-sound/moc: ChangeLog moc-2.5.0_alpha3-r1.ebuild

[Samuli Suominen (drac)]

drac        08/03/05 19:04:58

  Modified:             ChangeLog
  Added:                moc-2.5.0_alpha3-r1.ebuild
  Log:
  aac USE for media-libs/faad2 by Hendrik Iben, bug 211805.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.48                 media-sound/moc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/moc/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/moc/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/moc/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	1 Mar 2008 10:21:00 -0000	1.47
+++ ChangeLog	5 Mar 2008 19:04:57 -0000	1.48
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/moc
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.47 2008/03/01 10:21:00 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.48 2008/03/05 19:04:57 drac Exp $
+
+*moc-2.5.0_alpha3-r1 (05 Mar 2008)
+
+  05 Mar 2008; Samuli Suominen <drac@g.o>
+  +files/moc-2.5.0_alpha3-faad2.patch, +moc-2.5.0_alpha3-r1.ebuild:
+  aac USE for media-libs/faad2 by Hendrik Iben, bug 211805.
 
 *moc-2.5.0_alpha3 (01 Mar 2008)
 



1.1                  media-sound/moc/moc-2.5.0_alpha3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/moc/moc-2.5.0_alpha3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/moc/moc-2.5.0_alpha3-r1.ebuild?rev=1.1&content-type=text/plain

Index: moc-2.5.0_alpha3-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/moc-2.5.0_alpha3-r1.ebuild,v 1.1 2008/03/05 19:04:57 drac Exp $

inherit autotools eutils

MY_P=${P/_/-}

DESCRIPTION="Music On Console - ncurses interface for playing audio files"
HOMEPAGE="http://moc.daper.net"
SRC_URI="ftp://ftp.daper.net/pub/soft/${PN}/unstable/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa aac jack mad musepack vorbis flac wavpack sndfile modplug timidity sid ffmpeg speex libsamplerate curl debug"

RDEPEND="media-libs/libao
	alsa? ( media-libs/alsa-lib )
	aac? ( media-libs/faad2 )
	jack? ( media-sound/jack-audio-connection-kit )
	mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
	musepack? ( media-libs/libmpcdec >=media-libs/taglib-1.3 )
	vorbis? ( >=media-libs/libvorbis-1 )
	flac? ( media-libs/flac )
	wavpack? ( >=media-sound/wavpack-4.31 )
	sndfile? ( >=media-libs/libsndfile-1 )
	modplug? ( >=media-libs/libmodplug-0.7 )
	timidity? ( media-libs/libtimidity media-sound/timidity++ )
	sid? ( >=media-libs/libsidplay-2 )
	ffmpeg? ( media-video/ffmpeg )
	speex? ( >=media-libs/speex-1 )
	libsamplerate? ( >=media-libs/libsamplerate-0.1 )
	curl? ( >=net-misc/curl-7.12.2 )"
DEPEND="${RDEPEND}"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-faad2.patch
	AT_M4DIR="m4" eautoreconf
}

src_compile() {
	econf --without-rcc \
		$(use_with aac) \
		$(use_with jack) \
		$(use_with mad mp3) \
		$(use_with musepack) \
		$(use_with vorbis) \
		$(use_with flac) \
		$(use_with wavpack) \
		$(use_with sndfile) \
		$(use_with modplug) \
		$(use_with timidity) \
		$(use_with sid sidplay2) \
		$(use_with ffmpeg) \
		$(use_with speex) \
		$(use_with libsamplerate samplerate) \
		$(use_with curl) \
		$(use_enable debug)
	emake || die "emake failed."
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README THANKS TODO *.example
	rm -rf "${D}"/usr/share/doc/${PN}
}



-- 
gentoo-commits@l.g.o mailing list