[gentoo-commits] gentoo-x86 commit in app-text/apvlv: ChangeLog apvlv-0.1.2.ebuild

[Tim Harder (radhermit)]

radhermit    11/07/14 09:29:12

  Modified:             ChangeLog
  Added:                apvlv-0.1.2.ebuild
  Log:
  Version bump. Use new github site and update to EAPI 4.
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.14                 app-text/apvlv/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	21 Mar 2011 07:38:21 -0000	1.13
+++ ChangeLog	14 Jul 2011 09:29:11 -0000	1.14
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/apvlv
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v 1.13 2011/03/21 07:38:21 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/ChangeLog,v 1.14 2011/07/14 09:29:11 radhermit Exp $
+
+*apvlv-0.1.2 (14 Jul 2011)
+
+  14 Jul 2011; Tim Harder <radhermit@g.o> +apvlv-0.1.2.ebuild:
+  Version bump. Use new github site and update to EAPI 4.
 
   21 Mar 2011; Tim Harder <radhermit@g.o> -apvlv-0.0.9.8.ebuild,
   -apvlv-0.1.0.ebuild:



1.1                  app-text/apvlv/apvlv-0.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/apvlv-0.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/apvlv/apvlv-0.1.2.ebuild?rev=1.1&content-type=text/plain

Index: apvlv-0.1.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/apvlv-0.1.2.ebuild,v 1.1 2011/07/14 09:29:11 radhermit Exp $

EAPI=4

inherit eutils cmake-utils

MY_P="${P}-Source"
DESCRIPTION="Alf's PDF Viewer Like Vim"
HOMEPAGE="http://naihe2010.github.com/apvlv/"
SRC_URI="https://github.com/downloads/naihe2010/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug djvu"

RDEPEND=">=x11-libs/gtk+-2.10.4:2
	>=app-text/poppler-0.12.3-r3[cairo]
	djvu? ( app-text/djvu )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# bug #349979
	EPATCH_OPTS="-l"
	has_version ">=app-text/poppler-0.15.0" && epatch "${FILESDIR}"/${PN}-0.1.0-poppler-0.16.patch

	# Remove prefixes so it works with the cmake-utils eclass
	sed -i -e "s:APVLV_::" CMakeLists.txt src/CMakeLists.txt || die

	# Don't install tex file
	sed -i -e "s:Startup.tex::" CMakeLists.txt || die
}

src_configure() {
	mycmakeargs=(
		-DSYSCONFDIR=/etc/${PN}
		-DDOCDIR=/usr/share/${PN}
		-DMANDIR=/usr/share/man
		-DWITH_UMD=OFF
		$(cmake-utils_use_enable debug)
		$(cmake-utils_use_with djvu)
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dodoc AUTHORS NEWS README THANKS TODO
	newicon icons/pdf.png ${PN}.png
	make_desktop_entry ${PN} "Alf's PDF Viewer Like Vim" ${PN} "Office;Viewer"
}