[gentoo-commits] gentoo-x86 commit in dev-python/logilab-common: ChangeLog logilab-common-0.43.0.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/07/24 21:48:43

  Modified:             ChangeLog
  Added:                logilab-common-0.43.0.ebuild
  Log:
  Version bump. Don't check FEATURES (bug #278955).
  (Portage version: 13850-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.43                 dev-python/logilab-common/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/logilab-common/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/logilab-common/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	4 Jun 2009 13:01:39 -0000	1.42
+++ ChangeLog	24 Jul 2009 21:48:43 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/logilab-common
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.42 2009/06/04 13:01:39 idl0r Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/ChangeLog,v 1.43 2009/07/24 21:48:43 arfrever Exp $
+
+*logilab-common-0.43.0 (24 Jul 2009)
+
+  24 Jul 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@g.o>
+  +logilab-common-0.43.0.ebuild:
+  Version bump. Don't check FEATURES (bug #278955).
 
 *logilab-common-0.41.0 (04 Jun 2009)
 



1.1                  dev-python/logilab-common/logilab-common-0.43.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/logilab-common/logilab-common-0.43.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/logilab-common/logilab-common-0.43.0.ebuild?rev=1.1&content-type=text/plain

Index: logilab-common-0.43.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/logilab-common/logilab-common-0.43.0.ebuild,v 1.1 2009/07/24 21:48:43 arfrever Exp $

EAPI="2"

inherit distutils eutils python

DESCRIPTION="useful miscellaneous modules used by Logilab projects"
HOMEPAGE="http://www.logilab.org/projects/common/"
SRC_URI="ftp://ftp.logilab.org/pub/common/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="test"

DEPEND="test? ( dev-python/egenix-mx-base )"
RDEPEND=""

PYTHON_MODNAME="logilab"
# Extra documentation (html/pdf) needs some love

src_prepare() {
	distutils_src_prepare

	epatch "${FILESDIR}/${PN}-0.41.0-remove-broken-tests.patch"
}

src_test() {
	python_version

	# Install temporarily.
	local tpath="${T}/test"
	local lpath="${tpath}/lib/python"

	# setuptools would fail if the directory doesn't exist.
	mkdir -p "${lpath}" || die

	# We also have to add ${lpath} to PYTHONPATH else the installation would
	# fail.
	PYTHONPATH="${lpath}" ${python} setup.py install --home="${tpath}" || \
		die "test copy failed"

	# Get a rid of precompiled files to ensure we run our _modified_ tests
	find ${lpath} -type f -name '*.pyc' -exec rm {} ';'

	# Remove a botched tests.
	# To support test w/o setuptools.
	if [[ -d "${lpath}/${PN/-//}" ]]; then
		pushd "${lpath}/${PN/-//}" >/dev/null || die
	else
		pushd "${lpath}/${P/-/_}-py${PYVER}.egg/${PN/-//}" >/dev/null || die
	fi

	# Bug 223079
	if [[ "${EUID}" -eq 0 ]]; then
		rm test/unittest_fileutils.py || die
	fi

	popd >/dev/null || die

	# It picks up the tests relative to the current dir, so cd in. Do
	# not cd in too far though (to logilab/common for example) or some
	# relative/absolute module location tests fail.
	pushd "${lpath}" >/dev/null || die
	PYTHONPATH="${lpath}" ${python} "${tpath}/bin/pytest" -v || die "tests failed"
	popd >/dev/null || die
}

src_install() {
	distutils_src_install

	doman doc/pytest.1 || die "doman failed"

	# Remove unittests since they're just needed during build-time
	rm -rf "${D}/$(python_get_sitedir)/${PN/-//}/test" || die
}