[gentoo-commits] gentoo-x86 commit in app-misc/emelfm2: ChangeLog emelfm2-0.4.1.ebuild

[Ben de Groot (yngwin)]

yngwin      08/09/27 02:18:42

  Modified:             ChangeLog
  Added:                emelfm2-0.4.1.ebuild
  Log:
  Version bump. Fixes bug 219188.
  (Portage version: 2.2_rc11/cvs/Linux 2.6.26.5 i686)

Revision  Changes    Path
1.20                 app-misc/emelfm2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	20 Apr 2008 16:49:51 -0000	1.19
+++ ChangeLog	27 Sep 2008 02:18:41 -0000	1.20
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/emelfm2
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v 1.19 2008/04/20 16:49:51 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/ChangeLog,v 1.20 2008/09/27 02:18:41 yngwin Exp $
+
+*emelfm2-0.4.1 (27 Sep 2008)
+
+  27 Sep 2008; Ben de Groot <yngwin@g.o> +emelfm2-0.4.1.ebuild:
+  Version bump. Fixes bug 219188.
 
 *emelfm2-0.4 (20 Apr 2008)
 



1.1                  app-misc/emelfm2/emelfm2-0.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.1.ebuild?rev=1.1&content-type=text/plain

Index: emelfm2-0.4.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/emelfm2/emelfm2-0.4.1.ebuild,v 1.1 2008/09/27 02:18:41 yngwin Exp $

inherit eutils toolchain-funcs multilib

DESCRIPTION="A file manager that implements the popular two-pane design"
HOMEPAGE="http://emelfm2.net"
SRC_URI="http://${PN}.net/rel/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="acl unicode fam"

RESTRICT="test"

RDEPEND=">=x11-libs/gtk+-2.12
	fam? ( virtual/fam )
	acl? ( sys-apps/acl )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i -e "s:${PN}/${PN}_48.png:${PN}:" \
		docs/desktop_environment/${PN}.desktop || die "sed failed."
	sed -e "s:(PREFIX)/lib:(PREFIX)/$(get_libdir):" -e "s:strip:true:g" \
		-i Makefile || die "sed failed."
}

src_compile() {
	# These options need >=x11-libs/gtk-2.12 which we depend upon
	local myconf="USE_LATEST=1 WITH_TRANSPARENCY=1"

	if use acl; then
		myconf="${myconf} WITH_ACL=1"
	fi

	if use unicode; then
		myconf="${myconf} FILES_UTF8ONLY=1"
	fi

	if use fam; then
		if has_version "app-admin/gamin"; then
			myconf="${myconf} USE_GAMIN=1"
		else
			myconf="${myconf} USE_FAM=1"
		fi
	else
		myconf="${myconf} USE_FAM=0"
	fi

	tc-export CC
	emake ICON_DIR="/usr/share/pixmaps/${PN}" ${myconf} || die "emake failed."
}

src_install() {
	emake PREFIX="${D}/usr" install || die "emake install failed."
	newicon icons/${PN}_48.png ${PN}.png
	prepalldocs
}