[gentoo-commits] gentoo-x86 commit in media-gfx/nip2: ChangeLog nip2-7.20.7.ebuild

[Peter Volkov (pva)]

pva         09/12/22 11:11:05

  Modified:             ChangeLog
  Added:                nip2-7.20.7.ebuild
  Log:
  Version bump. Thank upstream (John) for helping us to fix test failures.
  (Portage version: 2.1.7.15/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 media-gfx/nip2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/nip2/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	29 Sep 2009 11:50:06 -0000	1.17
+++ ChangeLog	22 Dec 2009 11:11:05 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/nip2
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.17 2009/09/29 11:50:06 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.18 2009/12/22 11:11:05 pva Exp $
+
+*nip2-7.20.7 (22 Dec 2009)
+
+  22 Dec 2009; Peter Volkov <pva@g.o> +nip2-7.20.7.ebuild:
+  Version bump. Thank upstream (John) for helping us to fix test failures.
 
   29 Sep 2009; Markus Meier <maekke@g.o> nip2-7.18.2.ebuild:
   amd64/x86 stable, bug #286512



1.1                  media-gfx/nip2/nip2-7.20.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/nip2/nip2-7.20.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/nip2/nip2-7.20.7.ebuild?rev=1.1&content-type=text/plain

Index: nip2-7.20.7.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/nip2-7.20.7.ebuild,v 1.1 2009/12/22 11:11:05 pva Exp $

EAPI="2"
inherit eutils autotools fdo-mime versionator

# TODO: goffice we need 0.7 which is not in portage ATM

MY_MAJ_VER=$(get_version_component_range 1-2)
DESCRIPTION="VIPS Image Processing Graphical User Interface"
SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/${MY_MAJ_VER}/${P}.tar.gz"
HOMEPAGE="http://vips.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="fftw gsl test"

RDEPEND="
	>=dev-libs/glib-2.14:2
	dev-libs/libxml2
	x11-misc/xdg-utils
	>=media-libs/vips-${MY_MAJ_VER}
	>=x11-libs/gtk+-2.18:2
	gsl? ( sci-libs/gsl )
	fftw? ( sci-libs/fftw:3.0 )"
DEPEND="${RDEPEND}
	=sys-devel/bison-2.3*
	sys-devel/flex
	test? ( media-libs/vips[lcms] )"

src_prepare() {
	epatch "${FILESDIR}/${PN}-7.16.4-fftw3-build.patch"
	eautoreconf
}

src_configure() {
	econf \
		--disable-update-desktop \
		$(use_with gsl) \
		$(use_with fftw fftw3)
}

src_test() {
	if ! use gsl; then
		ewarn "Some tests require USE=gsl. Disabling test_math.ws tests."
		rm test/workspaces/test_math.ws
	fi
	make check || die
}

src_install() {
	make DESTDIR="${D}" install || die "install failed"
	dodoc AUTHORS ChangeLog NEWS README* || die
	# icon for .desktop
	insinto /usr/share/icons/hicolor/128x128/apps
	newins share/nip2/data/vips-128.png nip2.png || die
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}