[gentoo-commits] gentoo-x86 commit in dev-java/eclipse-ecj: ChangeLog eclipse-ecj-3.3.0-r1.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    07/09/07 17:24:44

  Modified:             ChangeLog
  Added:                eclipse-ecj-3.3.0-r1.ebuild
  Log:
  Use java-pkg_dolauncher instead of the hand written wrapper script.
  (Portage version: 2.1.3.7)

Revision  Changes    Path
1.21                 dev-java/eclipse-ecj/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/eclipse-ecj/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/eclipse-ecj/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/eclipse-ecj/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/eclipse-ecj/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	27 Jul 2007 13:01:38 -0000	1.20
+++ ChangeLog	7 Sep 2007 17:24:44 -0000	1.21
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/eclipse-ecj
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/eclipse-ecj/ChangeLog,v 1.20 2007/07/27 13:01:38 nichoj Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/eclipse-ecj/ChangeLog,v 1.21 2007/09/07 17:24:44 betelgeuse Exp $
+
+*eclipse-ecj-3.3.0-r1 (07 Sep 2007)
+
+  07 Sep 2007; Petteri Räty <betelgeuse@g.o>
+  +eclipse-ecj-3.3.0-r1.ebuild:
+  Use java-pkg_dolauncher instead of the hand written wrapper script.
 
 *eclipse-ecj-3.3.0 (27 Jul 2007)
 



1.1                  dev-java/eclipse-ecj/eclipse-ecj-3.3.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/eclipse-ecj/eclipse-ecj-3.3.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/eclipse-ecj/eclipse-ecj-3.3.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: eclipse-ecj-3.3.0-r1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/eclipse-ecj/eclipse-ecj-3.3.0-r1.ebuild,v 1.1 2007/09/07 17:24:44 betelgeuse Exp $

inherit eutils java-utils-2

MY_PN="ecj"
DMF="R-${PV}-200706251500"
S="${WORKDIR}"

DESCRIPTION="Eclipse Compiler for Java"
HOMEPAGE="http://www.eclipse.org/"
SRC_URI="http://download.eclipse.org/eclipse/downloads/drops/${DMF/.0}/${MY_PN}src.zip"

LICENSE="EPL-1.0"
KEYWORDS="~amd64 ~ppc ~x86"
SLOT="3.3"
IUSE=""

RDEPEND=">=virtual/jre-1.4"
DEPEND=">=virtual/jdk-1.4
	sys-apps/findutils
	app-arch/unzip"

src_unpack() {
	unpack ${A}
	cd ${S}

	# own package
	rm -f org/eclipse/jdt/core/JDTCompilerAdapter.java
	rm -fr org/eclipse/jdt/internal/antadapter

	# what the heck...?! java6
	rm -fr org/eclipse/jdt/internal/compiler/tool/ \
		org/eclipse/jdt/internal/compiler/apt/

	# gcj feature
	epatch ${FILESDIR}/${P}-gcj.patch
}

src_compile() {
	local javac="javac" java="java" jar="jar"

	mkdir -p bootstrap
	cp -a org bootstrap

	einfo "bootstrapping ${MY_PN} with javac"

	cd ${S}/bootstrap
	${javac} $(find org/ -name '*.java') || die "${MY_PN} bootstrap failed!"

	find org/ -name '*.class' -o -name '*.properties' -o -name '*.rsc' | \
		xargs ${jar} cf ${MY_PN}.jar

	einfo "build ${MY_PN} with bootstrapped ${MY_PN}"

	cd ${S}
	${java} -classpath bootstrap/${MY_PN}.jar \
		org.eclipse.jdt.internal.compiler.batch.Main -encoding ISO-8859-1 org \
		|| die "${MY_PN} build failed!"
	find org/ -name '*.class' -o -name '*.properties' -o -name '*.rsc' | \
		xargs ${jar} cf ${MY_PN}.jar
}

src_install() {
	java-pkg_dojar ${MY_PN}.jar
	java-pkg_dolauncher ${MY_PN}-${SLOT} --main \
		org.eclipse.jdt.internal.compiler.batch.Main
}

pkg_postinst() {
	ewarn "to get the compiler adapter of ecj for ant do"
	ewarn "	# emerge ant-eclipse-ecj"
}



-- 
gentoo-commits@g.o mailing list