[gentoo-commits] gentoo-x86 commit in app-emulation/open-vm-tools: ChangeLog open-vm-tools-0.0.20080808.109361-r1.ebuild open-vm-tools-0.0.20080808.109361.ebuild

[Mike Auty (ikelos)]

ikelos      08/10/19 13:06:00

  Modified:             ChangeLog
  Added:                open-vm-tools-0.0.20080808.109361-r1.ebuild
  Removed:              open-vm-tools-0.0.20080808.109361.ebuild
  Log:
  Bump to fix bug 231525.
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo i686)

Revision  Changes    Path
1.10                 app-emulation/open-vm-tools/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/open-vm-tools/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/open-vm-tools/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/open-vm-tools/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/open-vm-tools/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	31 Aug 2008 09:40:04 -0000	1.9
+++ ChangeLog	19 Oct 2008 13:06:00 -0000	1.10
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/open-vm-tools
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/open-vm-tools/ChangeLog,v 1.9 2008/08/31 09:40:04 ikelos Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/open-vm-tools/ChangeLog,v 1.10 2008/10/19 13:06:00 ikelos Exp $
+
+*open-vm-tools-0.0.20080808.109361-r1 (19 Oct 2008)
+
+  19 Oct 2008; Mike Auty <ikelos@g.o>
+  -open-vm-tools-0.0.20080808.109361.ebuild,
+  +open-vm-tools-0.0.20080808.109361-r1.ebuild:
+  Bump to fix bug 231525.
 
   31 Aug 2008; Mike Auty <ikelos@g.o> +files/10-vmware-tools:
   Add missing file 10-vmware-tools



1.1                  app-emulation/open-vm-tools/open-vm-tools-0.0.20080808.109361-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/open-vm-tools/open-vm-tools-0.0.20080808.109361-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/open-vm-tools/open-vm-tools-0.0.20080808.109361-r1.ebuild?rev=1.1&content-type=text/plain

Index: open-vm-tools-0.0.20080808.109361-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/open-vm-tools/open-vm-tools-0.0.20080808.109361-r1.ebuild,v 1.1 2008/10/19 13:06:00 ikelos Exp $

inherit pam eutils linux-mod versionator

MY_DATE="$(get_version_component_range 3)"
MY_BUILD="$(get_version_component_range 4)"
MY_PV="${MY_DATE:0:4}.${MY_DATE:4:2}.${MY_DATE:6:2}-${MY_BUILD}"
MY_P="${PN}-${MY_PV}"

S="${WORKDIR}/${MY_P}"

DESCRIPTION="Opensourced tools for VMware guests"
HOMEPAGE="http://open-vm-tools.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"

LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="X xinerama icu unity"
DEPEND="
		virtual/linux-sources
		sys-apps/ethtool
		X? (
			x11-libs/libX11
			x11-libs/gtk+
			)
		unity? (
			x11-libs/libXScrnSaver
			dev-libs/uriparser
		)
		xinerama? (
			x11-libs/libXinerama
			)
		!app-emulation/vmware-workstation-tools
		!app-emulation/vmware-server-tools
		!app-emulation/vmware-esx-tools
		sys-process/procps
		dev-libs/libdnet
		icu? ( dev-libs/icu )
		"

RDEPEND="${DEPEND/virtual\/linux\-sources/}
		 virtual/pam
		 X? (
			x11-base/xorg-server
			x11-drivers/xf86-video-vmware
			x11-drivers/xf86-input-vmmouse
		 )
		 unity? (
			x11-libs/libXScrnSaver
			dev-libs/uriparser
		 )
"

VMWARE_MOD_DIR="modules/linux"
VMWARE_MODULE_LIST="vmblock vmhgfs vmsync vmmemctl vmxnet"

pkg_setup() {

	linux-mod_pkg_setup
	MODULE_NAMES=""
	BUILD_TARGETS="auto-build HEADER_DIR=${KERNEL_DIR}/include BUILD_DIR=${KV_OUT_DIR}"

	for mod in ${VMWARE_MODULE_LIST};
	do
		if [[ "${mod}" == "vmxnet" ]];
		then
			MODTARGET="net"
		else
			MODTARGET="openvmtools"
		fi
		MODULE_NAMES="${MODULE_NAMES} ${mod}(${MODTARGET}:${S}/${VMWARE_MOD_DIR}/${mod})"
	done

	ewarn "If you're compiling for a hardened target, please use the hardened"
	ewarn "toolchain (see bug #200376, comment 18)."

	enewgroup vmware

}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/default-scripts.patch"
}

src_compile() {
	econf \
	--without-kernel-modules \
	$(use_with icu) \
	$(use_with X x) \
	$(use_enable unity) \
	$(use_enable xinerama multimon) \
	|| die "Error: econf failed!"

	linux-mod_src_compile

	emake || die
}

src_install() {

	linux-mod_src_install

	pamd_mimic_system vmware-guestd auth account

	emake install DESTDIR="${D}" || die "Failed to install"

	newinitd "${FILESDIR}/open-vm.initd" vmware-tools
	newconfd "${FILESDIR}/open-vm.confd" vmware-tools

	if use X;
	then
		exeinto /etc/X11/xinit/xinitrc.d
		doexe "${FILESDIR}/10-vmware-tools"

		elog "To be able to use the drag'n'drop feature of VMware for file"
		elog "exchange, you need to do this:"
		elog "	Add 'vmware-tools' to your default runlevel"
		elog "	Add the users which should have access to this function"
		elog "	to the group 'vmware'"
	fi
}