[gentoo-commits] gentoo-x86 commit in net-libs/libinfinity: metadata.xml ChangeLog libinfinity-0.2.0.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    09/04/08 19:54:27

  Added:                metadata.xml ChangeLog libinfinity-0.2.0.ebuild
  Log:
  Initial commit (ebuild written by me) for new version of gobby.
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-libs/libinfinity/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>no-herd</herd>
<maintainer>
  <email>dev-zero@g.o</email>
</maintainer>
<maintainer>
  <email>humpback@g.o</email>
</maintainer>
<use>
  <flag name='server'>
    Build and install the server binary including init.d/conf.d-scripts.
    Needed if you want to host an infinote server for gobby.
  </flag>
</use>
</pkgmetadata>



1.1                  net-libs/libinfinity/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-libs/libinfinity
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/ChangeLog,v 1.1 2009/04/08 19:54:27 dev-zero Exp $

*libinfinity-0.2.0 (08 Apr 2009)

  08 Apr 2009; Tiziano Müller <dev-zero@g.o>
  +files/infinoted.confd-0.2, +files/infinoted.initd-0.2, +metadata.xml,
  +libinfinity-0.2.0.ebuild:
  Initial commit (ebuild written by me) for new version of gobby.




1.1                  net-libs/libinfinity/libinfinity-0.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/libinfinity-0.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/libinfinity/libinfinity-0.2.0.ebuild?rev=1.1&content-type=text/plain

Index: libinfinity-0.2.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libinfinity/libinfinity-0.2.0.ebuild,v 1.1 2009/04/08 19:54:27 dev-zero Exp $

EAPI="2"

inherit eutils

DESCRIPTION="An implementation of the Infinote protocol written in GObject-based C."
HOMEPAGE="http://gobby.0x539.de/"
SRC_URI="http://releases.0x539.de/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="avahi doc gtk server"

RDEPEND=">=sys-libs/e2fsprogs-libs-1.41.4
	dev-libs/glib:2
	dev-libs/libxml2
	net-libs/gnutls
	>=net-misc/gsasl-0.2.21
	avahi? ( net-dns/avahi )
	gtk? ( >=x11-libs/gtk+-2.12:2 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.23
	doc? ( dev-util/gtk-doc )"

pkg_setup() {
	if use server ; then
		enewgroup infinote 100
		enewuser infinote 100 /bin/bash /var/lib/infinote infinote
	fi
}

src_configure() {
	econf \
		$(use_enable doc gtk-doc) \
		$(use_with gtk inftextgtk) \
		$(use_with gtk infgtk) \
		$(use_with server infinoted) \
		$(use_with avahi)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS NEWS README TODO

	if use server ; then
		newinitd "${FILESDIR}/infinoted.initd-0.2" infinoted
		newconfd "${FILESDIR}/infinoted.confd-0.2" infinoted

		keepdir /var/lib/infinote
		fowners infinote:infinote /var/lib/infinote
		fperms 770 /var/lib/infinote

		elog "Add local users who should have local access to the documents"
		elog "created by infinoted to the infinote group."
		elog "The documents are saved in /var/lib/infinote per default."
	fi
}