[gentoo-commits] gentoo-x86 commit in media-plugins/alsa-plugins: alsa-plugins-1.0.20.ebuild ChangeLog

[Steve Dibb (beandog)]

beandog     09/05/06 18:05:46

  Modified:             ChangeLog
  Added:                alsa-plugins-1.0.20.ebuild
  Log:
  Version bump
  (Portage version: 2.2_rc31/cvs/Linux x86_64)

Revision  Changes    Path
1.96                 media-plugins/alsa-plugins/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.96&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?rev=1.96&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/ChangeLog?r1=1.95&r2=1.96

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v
retrieving revision 1.95
retrieving revision 1.96
diff -u -r1.95 -r1.96
--- ChangeLog	31 Mar 2009 09:36:48 -0000	1.95
+++ ChangeLog	6 May 2009 18:05:46 -0000	1.96
@@ -1,6 +1,11 @@
 # ChangeLog for media-plugins/alsa-plugins
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.95 2009/03/31 09:36:48 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/ChangeLog,v 1.96 2009/05/06 18:05:46 beandog Exp $
+
+*alsa-plugins-1.0.20 (06 May 2009)
+
+  06 May 2009; Steve Dibb <beandog@g.o> +alsa-plugins-1.0.20.ebuild:
+  Version bump
 
   31 Mar 2009; Raúl Porcel <armin76@g.o> alsa-plugins-1.0.16.ebuild,
   alsa-plugins-1.0.17-r1.ebuild:



1.1                  media-plugins/alsa-plugins/alsa-plugins-1.0.20.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.20.ebuild?rev=1.1&content-type=text/plain

Index: alsa-plugins-1.0.20.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-plugins/alsa-plugins/alsa-plugins-1.0.20.ebuild,v 1.1 2009/05/06 18:05:46 beandog Exp $

EAPI=2

MY_P="${P/_/}"

inherit autotools flag-o-matic

DESCRIPTION="ALSA extra plugins"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/plugins/${MY_P}.tar.bz2"

LICENSE="GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="debug ffmpeg jack libsamplerate pulseaudio speex"

RDEPEND=">=media-libs/alsa-lib-${PV}
	ffmpeg? ( media-video/ffmpeg
		media-libs/alsa-lib[alsa_pcm_plugins_rate] )
	jack? ( >=media-sound/jack-audio-connection-kit-0.98 )
	libsamplerate? (
		media-libs/libsamplerate
		media-libs/alsa-lib[alsa_pcm_plugins_rate] )
	pulseaudio? ( media-sound/pulseaudio )
	speex? ( media-libs/speex
		media-libs/alsa-lib[alsa_pcm_plugins_rate] )
	!media-plugins/alsa-jack"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# For some reasons the polyp/pulse plugin does fail with alsaplayer with a
	# failed assert. As the code works just fine with asserts disabled, for now
	# disable them waiting for a better solution.
	sed -i -e '/AM_CFLAGS/s:-Wall:-DNDEBUG -Wall:' \
		"${S}/pulse/Makefile.am"

	eautoreconf

	# Bug #256119
	epatch "${FILESDIR}/${PN}-1.0.19-missing-avutil.patch"
}

src_configure() {
	use debug || append-flags -DNDEBUG

	econf \
		$(use_enable ffmpeg avcodec) \
		$(use_enable jack) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable pulseaudio) \
		$(use_with speex speex lib) \
		--disable-dependency-tracking \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install

	cd "${S}/doc"
	dodoc upmix.txt vdownmix.txt README-pcm-oss
	use jack && dodoc README-jack
	use libsamplerate && dodoc samplerate.txt
	use pulseaudio && dodoc README-pulse
	use ffmpeg && dodoc lavcrate.txt a52.txt
}