[gentoo-commits] gentoo-x86 commit in dev-libs/glib: ChangeLog glib-2.18.2.ebuild

[Mart Raudsepp (leio)]

leio        08/10/19 02:16:37

  Modified:             ChangeLog
  Added:                glib-2.18.2.ebuild
  Log:
  New bug fix release, fixing wrong fallback order of mimetype icons and more
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoo x86_64)

Revision  Changes    Path
1.337                dev-libs/glib/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.337&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?rev=1.337&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/ChangeLog?r1=1.336&r2=1.337

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v
retrieving revision 1.336
retrieving revision 1.337
diff -u -r1.336 -r1.337
--- ChangeLog	18 Oct 2008 22:40:12 -0000	1.336
+++ ChangeLog	19 Oct 2008 02:16:37 -0000	1.337
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.336 2008/10/18 22:40:12 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.337 2008/10/19 02:16:37 leio Exp $
+
+*glib-2.18.2 (19 Oct 2008)
+
+  19 Oct 2008; Mart Raudsepp <leio@g.o> +glib-2.18.2.ebuild:
+  New bug fix release, fixing wrong fallback order of mimetype icons and
+  more
 
   18 Oct 2008; Brent Baude <ranger@g.o> glib-2.16.5.ebuild:
   Marking glib-2.16.5 ppc stable for bug 236971



1.1                  dev-libs/glib/glib-2.18.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.18.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/glib/glib-2.18.2.ebuild?rev=1.1&content-type=text/plain

Index: glib-2.18.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.18.2.ebuild,v 1.1 2008/10/19 02:16:37 leio Exp $

inherit gnome.org libtool eutils flag-o-matic

DESCRIPTION="The GLib library of C routines"
HOMEPAGE="http://www.gtk.org/"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="debug doc fam hardened selinux xattr"

RDEPEND="virtual/libc
		 virtual/libiconv
		 xattr? ( sys-apps/attr )
		 fam? ( virtual/fam )"
DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.16
		>=sys-devel/gettext-0.11
		doc?	(
					>=dev-libs/libxslt-1.0
					>=dev-util/gtk-doc-1.8
					~app-text/docbook-xml-dtd-4.1.2
				)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	if use ppc64 && use hardened ; then
		replace-flags -O[2-3] -O1
		epatch "${FILESDIR}/glib-2.6.3-testglib-ssp.patch"
	fi

	if use ia64 ; then
		# Only apply for < 4.1
		local major=$(gcc-major-version)
		local minor=$(gcc-minor-version)
		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
		fi
	fi

	# Don't fail gio tests when ran without userpriv, upstream bug 552912
	# This is only a temporary workaround, remove as soon as possible
	epatch "${FILESDIR}/${PN}-2.18.1-workaround-gio-test-failure-without-userpriv.patch"

	# Fix gmodule issues on fbsd; bug #184301
	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch

	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
}

src_compile() {
	local myconf

	epunt_cxx

	# Building with --disable-debug highly unrecommended.  It will build glib in
	# an unusable form as it disables some commonly used API.  Please do not
	# convert this to the use_enable form, as it results in a broken build.
	# -- compnerd (3/27/06)
	use debug && myconf="--enable-debug"

	# always build static libs, see #153807
	econf ${myconf}                 \
		  $(use_enable xattr)       \
		  $(use_enable doc man)     \
		  $(use_enable doc gtk-doc) \
		  $(use_enable fam)         \
		  $(use_enable selinux)     \
		  --enable-static           \
		  --with-threads=posix || die "configure failed"

	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "Installation failed"

	# Do not install charset.alias even if generated, leave it to libiconv
	rm -f "${D}/usr/lib/charset.alias"

	dodoc AUTHORS ChangeLog* NEWS* README
}