[gentoo-commits] gentoo-x86 commit in sys-fs/mdadm: mdadm-3.2.4.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      12/05/11 00:35:53

  Modified:             ChangeLog
  Added:                mdadm-3.2.4.ebuild
  Log:
  Version bump #415411 by Matthew Marlowe.
  
  (Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

Revision  Changes    Path
1.150                sys-fs/mdadm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.150&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?rev=1.150&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/ChangeLog?r1=1.149&r2=1.150

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v
retrieving revision 1.149
retrieving revision 1.150
diff -u -r1.149 -r1.150
--- ChangeLog	16 Feb 2012 03:10:04 -0000	1.149
+++ ChangeLog	11 May 2012 00:35:53 -0000	1.150
@@ -1,6 +1,11 @@
 # ChangeLog for sys-fs/mdadm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.149 2012/02/16 03:10:04 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/ChangeLog,v 1.150 2012/05/11 00:35:53 vapier Exp $
+
+*mdadm-3.2.4 (11 May 2012)
+
+  11 May 2012; Mike Frysinger <vapier@g.o> +mdadm-3.2.4.ebuild:
+  Version bump #415411 by Matthew Marlowe.
 
 *mdadm-3.2.3-r1 (16 Feb 2012)
 



1.1                  sys-fs/mdadm/mdadm-3.2.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/mdadm-3.2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/mdadm/mdadm-3.2.4.ebuild?rev=1.1&content-type=text/plain

Index: mdadm-3.2.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/mdadm/mdadm-3.2.4.ebuild,v 1.1 2012/05/11 00:35:53 vapier Exp $

EAPI="4"
inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="A useful tool for running RAID systems - it can be used as a replacement for the raidtools"
HOMEPAGE="http://neil.brown.name/blog/mdadm"
SRC_URI="mirror://kernel/linux/utils/raid/mdadm/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="static"

DEPEND=""
RDEPEND="!<sys-apps/baselayout-2
	>=sys-apps/util-linux-2.16"

# The tests edit values in /proc and run tests on software raid devices.
# Thus, they shouldn't be run on systems with active software RAID devices.
RESTRICT="test"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.2.1-mdassemble.patch #211426
	sed -i 's:/run/mdadm:/var/run/mdadm:g' *.[ch] Makefile || die
}

mdadm_emake() {
	emake \
		CC="$(tc-getCC)" \
		CWFLAGS="-Wall" \
		CXFLAGS="${CFLAGS}" \
		"$@"
}

src_compile() {
	use static && append-ldflags -static
	mdadm_emake all mdassemble
}

src_test() {
	mdadm_emake test

	sh ./test || die
}

src_install() {
	emake DESTDIR="${D}" install
	into /
	dosbin mdassemble
	dodoc ChangeLog INSTALL TODO README* ANNOUNCE-${PV}

	insinto /etc
	newins mdadm.conf-example mdadm.conf
	newinitd "${FILESDIR}"/mdadm.rc mdadm
	newconfd "${FILESDIR}"/mdadm.confd mdadm
	newinitd "${FILESDIR}"/mdraid.rc mdraid
	newconfd "${FILESDIR}"/mdraid.confd mdraid

	# do not rely on /lib -> /libXX link
	sed -i \
		-e "s:/lib/rcscripts/:/$(get_libdir)/rcscripts/:" \
		"${D}"/etc/init.d/*
}

pkg_postinst() {
	elog "If you're not relying on kernel auto-detect of your RAID devices,"
	elog "you need to add 'mdraid' to your 'boot' runlevel:"
	elog "rc-update add mdraid boot"
}