[gentoo-commits] gentoo-x86 commit in net-libs/webkit-gtk: ChangeLog webkit-gtk-1.1.8.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    09/05/30 20:09:33

  Modified:             ChangeLog
  Added:                webkit-gtk-1.1.8.ebuild
  Log:
  Bump to 1.1.8, also fix bug 259061
  (Portage version: 2.2_rc33/cvs/Linux i686)

Revision  Changes    Path
1.29                 net-libs/webkit-gtk/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	24 May 2009 13:56:31 -0000	1.28
+++ ChangeLog	30 May 2009 20:09:33 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/webkit-gtk
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.28 2009/05/24 13:56:31 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.29 2009/05/30 20:09:33 nirbheek Exp $
+
+*webkit-gtk-1.1.8 (30 May 2009)
+
+  30 May 2009; Nirbheek Chauhan <nirbheek@g.o>
+  +webkit-gtk-1.1.8.ebuild:
+  Bump to 1.1.8, also fix bug 259061
 
   24 May 2009; Nirbheek Chauhan <nirbheek@g.o>
   webkit-gtk-1.1.7.ebuild:



1.1                  net-libs/webkit-gtk/webkit-gtk-1.1.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.8.ebuild?rev=1.1&content-type=text/plain

Index: webkit-gtk-1.1.8.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.1.8.ebuild,v 1.1 2009/05/30 20:09:33 nirbheek Exp $

EAPI="2"

MY_P="webkit-${PV}"
DESCRIPTION="Open source web browser engine"
HOMEPAGE="http://www.webkitgtk.org/"
SRC_URI="http://www.webkitgtk.org/${MY_P}.tar.gz"

LICENSE="LGPL-2 LGPL-2.1 BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86 ~x86-fbsd"
# geoclue
IUSE="coverage debug doc gnome-keyring +gstreamer pango"

# use sqlite, svg by default
RDEPEND="
	dev-libs/libxml2
	dev-libs/libxslt
	media-libs/jpeg
	media-libs/libpng
	x11-libs/cairo

	>=x11-libs/gtk+-2.10
	>=dev-libs/icu-3.8.1-r1
	>=net-libs/libsoup-2.25.90
	>=dev-db/sqlite-3
	>=app-text/enchant-0.22

	gnome-keyring? ( >=gnome-base/gnome-keyring-2.26.0 )
	gstreamer? (
		media-libs/gstreamer:0.10
		media-libs/gst-plugins-base:0.10 )
	pango? ( x11-libs/pango )
	!pango? (
		media-libs/freetype:2
		media-libs/fontconfig )
"
DEPEND="${RDEPEND}
	sys-devel/gettext
	dev-util/gperf
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.10 )"

S="${WORKDIR}/${MY_P}"

src_prepare() {
	sed -ie 's/-O2//g' "${S}"/configure* || die "sed failed"
}

src_configure() {
	# It doesn't compile on alpha without this in LDFLAGS
	use alpha && append-ldflags "-Wl,--no-relax"

	local myconf

	myconf="--enable-svg-filters
		$(use_enable gnome-keyring gnomekeyring)
		$(use_enable gstreamer video)
		$(use_enable debug)
		$(use_enable coverage)"

	# USE-flag controlled font backend because upstream default is freetype
	# Remove USE-flag once font-backend becomes pango upstream
	if use pango; then
		ewarn "You have enabled the incomplete pango backend"
		ewarn "Please file any and all bugs *upstream*"
		myconf="${myconf} --with-font-backend=pango"
	else
		myconf="${myconf} --with-font-backend=freetype"
	fi

	econf ${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "Install failed"
	dodoc WebKit/gtk/{NEWS,ChangeLog} || die "dodoc failed"
}