Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Justin Lecher (jlec)" <jlec@g.o>
Subject: gentoo-x86 commit in sys-fs/aufs3: ChangeLog aufs3-3_p20120619.ebuild
Date: Tue, 19 Jun 2012 18:56:35 +0000 (UTC)
jlec        12/06/19 18:56:35

  Modified:             ChangeLog
  Added:                aufs3-3_p20120619.ebuild
  Log:
  sys-fs/aufs3: Version BUmp
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 sys-fs/aufs3/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	31 May 2012 16:13:46 -0000	1.18
+++ ChangeLog	19 Jun 2012 18:56:35 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/aufs3
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v 1.18 2012/05/31 16:13:46 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/ChangeLog,v 1.19 2012/06/19 18:56:35 jlec Exp $
+
+*aufs3-3_p20120619 (19 Jun 2012)
+
+  19 Jun 2012; Justin Lecher <jlec@g.o> files/aufs3-base-x-rcN.patch,
+  files/aufs3-standalone-x-rcN.patch, +aufs3-3_p20120619.ebuild:
+  Version BUmp
 
 *aufs3-3_p20120531 (31 May 2012)
 



1.1                  sys-fs/aufs3/aufs3-3_p20120619.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/aufs3-3_p20120619.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/aufs3/aufs3-3_p20120619.ebuild?rev=1.1&content-type=text/plain

Index: aufs3-3_p20120619.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/aufs3/aufs3-3_p20120619.ebuild,v 1.1 2012/06/19 18:56:35 jlec Exp $

EAPI=4

inherit linux-mod multilib toolchain-funcs eutils

AUFS_VERSION="${PV%%_p*}"
# highest branch version
PATCH_MAX_VER=4
# highest supported version
KERN_MAX_VER=5
# highest util branch version
UTIL_MAX_VER=0

DESCRIPTION="An entirely re-designed and re-implemented Unionfs"
HOMEPAGE="http://aufs.sourceforge.net/"
SRC_URI="http://dev.gentoo.org/~jlec/distfiles/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc fuse pax_kernel hfs inotify kernel-patch nfs ramfs"

DEPEND="dev-vcs/git"
RDEPEND="
	!sys-fs/aufs
	!sys-fs/aufs2"

S="${WORKDIR}"/${PN}-standalone

MODULE_NAMES="aufs(misc:${S})"

pkg_setup() {
	CONFIG_CHECK="${CONFIG_CHECK} ~EXPERIMENTAL"
	use inotify && CONFIG_CHECK="${CONFIG_CHECK} ~FSNOTIFY"
	use nfs && CONFIG_CHECK="${CONFIG_CHECK} EXPORTFS"
	use fuse && CONFIG_CHECK="${CONFIG_CHECK} ~FUSE_FS"
	use hfs && CONFIG_CHECK="${CONFIG_CHECK} ~HFSPLUS_FS"

	# this is needed so merging a binpkg ${PN} is possible w/out a kernel unpacked on the system
	[ -n "$PKG_SETUP_HAS_BEEN_RAN" ] && return

	get_version
	kernel_is lt 3 0 0 && die "kernel too old, Please use sys-fs/aufs2"
	kernel_is gt 3 ${KERN_MAX_VER} 99 && die "kernel too new"

	linux-mod_pkg_setup

	if [[ "${KV_MINOR}" -gt "${PATCH_MAX_VER}" ]]; then
		PATCH_BRANCH="x-rcN"
	else
		PATCH_BRANCH="${KV_MINOR}"
	fi

	if [[ "${PATCH_BRANCH}" == "x-rcN" ]]; then
		UTIL_BRANCH="x-rcN"
	elif [[ "${KV_MINOR}" -gt "${UTIL_MAX_VER}" ]]; then
		UTIL_BRANCH="${UTIL_MAX_VER}"
	else
		UTIL_BRANCH="${KV_MINOR}"
	fi

	if ! ( patch -p1 --dry-run --force -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-standalone-${PATCH_BRANCH}.patch >/dev/null && \
		patch -p1 --dry-run --force -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-base-${PATCH_BRANCH}.patch >/dev/null ); then
		if use kernel-patch; then
			cd ${KV_DIR}
			ewarn "Patching your kernel..."
			patch --no-backup-if-mismatch --force -p1 -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-standalone-${PATCH_BRANCH}.patch >/dev/null
			patch --no-backup-if-mismatch --force -p1 -R -d ${KV_DIR} < "${FILESDIR}"/${PN}-base-${PATCH_BRANCH}.patch >/dev/null
			epatch "${FILESDIR}"/${PN}-{base,standalone}-${PATCH_BRANCH}.patch
			ewarn "You need to compile your kernel with the applied patch"
			ewarn "to be able to load and use the aufs kernel module"
		else
			eerror "You need to apply a patch to your kernel to compile and run the ${PN} module"
			eerror "Either enable the kernel-patch useflag to do it with this ebuild"
			eerror "or apply ${FILESDIR}/${PN}-base-${PATCH_BRANCH}.patch and"
			eerror "${FILESDIR}/${PN}-standalone-${PATCH_BRANCH}.patch by hand"
			die "missing kernel patch, please apply it first"
		fi
	fi
	export PKG_SETUP_HAS_BEEN_RAN=1
}

set_config() {
	for option in $*; do
		grep -q "^CONFIG_AUFS_${option} =" config.mk || die "${option} is not a valid config option"
		sed "/^CONFIG_AUFS_${option}/s:=:= y:g" -i config.mk || die
	done
}

src_prepare() {
	local module_branch=origin/${PN}.${PATCH_BRANCH}
	local util_branch=origin/${PN}.${UTIL_BRANCH}

	einfo "Using for module creation branch ${module_branch}"
	git checkout -q -b local-gentoo ${module_branch} || die

	# All config options to off
	sed "s:= y:=:g" -i config.mk || die

	set_config RDU BRANCH_MAX_127 SBILIST

	use debug && set_config DEBUG
	use fuse && set_config BR_FUSE POLL
	use hfs && set_config BR_HFSPLUS
	use inotify && set_config HNOTIFY HFSNOTIFY
	use nfs && set_config EXPORT
	use nfs && use amd64 && set_config INO_T_64
	use ramfs && set_config BR_RAMFS

	use pax_kernel && epatch "${FILESDIR}"/pax.patch

	sed -i "s:aufs.ko usr/include/linux/aufs_type.h:aufs.ko:g" Makefile || die
	sed -i "s:__user::g" include/linux/aufs_type.h || die

	cd "${WORKDIR}"/${PN/3}-util

	einfo "Using for utils building branch ${util_branch}"
	git checkout -b local-gentoo ${util_branch} || die
	sed -i "/LDFLAGS += -static -s/d" Makefile || die
	sed -i -e "s:m 644 -s:m 644:g" -e "s:/usr/lib:/usr/$(get_libdir):g" libau/Makefile || die
}

src_compile() {
	local ARCH=x86

	emake CC=$(tc-getCC) CONFIG_AUFS_FS=m KDIR=${KV_DIR}

	cd "${WORKDIR}"/${PN/3}-util
	emake CC=$(tc-getCC) AR=$(tc-getAR) KDIR=${KV_DIR} C_INCLUDE_PATH="${S}"/include
}

src_install() {
	linux-mod_src_install

	insinto /usr/share/doc/${PF}

	use doc && doins -r Documentation

	dodoc Documentation/filesystems/aufs/README

	cd "${WORKDIR}"/${PN/3}-util
	emake DESTDIR="${D}" KDIR=${KV_DIR} install

	newdoc README README-utils
}





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in x11-themes/faenza-icon-theme: ChangeLog faenza-icon-theme-1.2-r1.ebuild
Next by thread:
gentoo-x86 commit in sys-fs/aufs3/files: aufs3-standalone-x-rcN.patch aufs3-base-x-rcN.patch
Previous by date:
gentoo-x86 commit in x11-themes/faenza-icon-theme: ChangeLog faenza-icon-theme-1.2-r1.ebuild
Next by date:
gentoo-x86 commit in sys-fs/aufs3/files: aufs3-standalone-x-rcN.patch aufs3-base-x-rcN.patch


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.