[gentoo-commits] gentoo-x86 commit in media-sound/xwax: xwax-1.1.ebuild ChangeLog

[Joe Sapp (nixphoeni)]

nixphoeni    12/01/30 01:14:47

  Modified:             ChangeLog
  Added:                xwax-1.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.38                 media-sound/xwax/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	28 Jan 2012 14:44:54 -0000	1.37
+++ ChangeLog	30 Jan 2012 01:14:47 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/xwax
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.37 2012/01/28 14:44:54 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/ChangeLog,v 1.38 2012/01/30 01:14:47 nixphoeni Exp $
+
+*xwax-1.1 (29 Jan 2012)
+
+  29 Jan 2012; Joe Sapp <nixphoeni@g.o> +xwax-1.1.ebuild:
+  Version bump
 
   28 Jan 2012; Pawel Hajdan jr <phajdan.jr@g.o> xwax-1.0.ebuild:
   x86 stable wrt bug #400415



1.1                  media-sound/xwax/xwax-1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/xwax-1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/xwax/xwax-1.1.ebuild?rev=1.1&content-type=text/plain

Index: xwax-1.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/xwax/xwax-1.1.ebuild,v 1.1 2012/01/30 01:14:47 nixphoeni Exp $

EAPI=4
inherit toolchain-funcs

DESCRIPTION="Digital vinyl emulation software"
HOMEPAGE="http://www.xwax.co.uk/"
SRC_URI="http://www.xwax.co.uk/releases/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="alsa jack oss cdda mp3 +fallback"
REQUIRED_USE="|| ( cdda mp3 fallback )
	|| ( alsa jack oss )"

RDEPEND="sys-libs/glibc
	media-libs/libsdl
	media-libs/sdl-ttf
	media-fonts/dejavu
	alsa? ( media-libs/alsa-lib )
	jack? ( media-sound/jack-audio-connection-kit )
	cdda? ( media-sound/cdparanoia )
	mp3? ( || ( media-sound/mpg123 media-sound/mpg321 ) )
	fallback? ( virtual/ffmpeg )"
DEPEND="${RDEPEND}"

DOCS="README CHANGES"

src_prepare() {
	# Remove the forced optimization from 'CFLAGS' and 'LDFLAGS' in
	# the Makefile
	# Also remove the dependency on the .version target so we don't need
	# git just to build
	sed -i -e 's/\(^\(LD\|C\)FLAGS.*\)-O[0-9]\(.*\)/\1\3/g' \
		-e 's/^xwax\.o:.*\.version//' \
		Makefile || die "sed failed"

	# Replace any decoder commands in the import script, if necessary
	if [[ `use mp3` ]]; then
		# mpg123 is upstream's default
		if has_version media-sound/mpg123; then
			TO="mpg123"
			FROM="mpg321"
		# Otherwise, use mpg321
		else
			TO="mpg321"
			FROM="mpg123"
		fi
		debug-print "found ${TO}"
		sed -i -e "s:${FROM}:${TO}:g" import || \
			die "problem converting xwax-import to use ${TO}"
	fi
}

src_configure() {
	tc-export CC
	econf \
		--prefix "${EROOT}usr" \
		$(use_enable alsa) \
		$(use_enable jack) \
		$(use_enable oss)
}

src_compile() {
	# EXECDIR is the default directory in which xwax will look for
	# the 'xwax-import' and 'xwax-scan' scripts
	emake EXECDIR="\$(BINDIR)" VERSION="${PV}"
}

src_install() {
	# This is easier than setting all the environment variables
	# needed, running the sed script required to get the man directory
	# correct, and removing the GPL-2 after a 'make install' run
	dobin xwax || die "failed to install xwax"
	newbin import xwax-import || die "failed to install xwax-import"
	newbin scan xwax-scan || die "failed to install xwax-scan"
	doman xwax.1 || die "failed to install man page"

	dodoc ${DOCS} || die "failed to install docs"
}