[gentoo-commits] gentoo-x86 commit in net-dialup/lrzsz: ChangeLog lrzsz-0.12.20-r3.ebuild

[Alin Nastac (mrness)]

mrness      09/07/09 23:46:22

  Modified:             ChangeLog
  Added:                lrzsz-0.12.20-r3.ebuild
  Log:
  Use eautoreconf (#226789).
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.20                 net-dialup/lrzsz/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/lrzsz/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/lrzsz/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/lrzsz/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dialup/lrzsz/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	9 May 2009 13:27:07 -0000	1.19
+++ ChangeLog	9 Jul 2009 23:46:22 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for net-dialup/lrzsz
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dialup/lrzsz/ChangeLog,v 1.19 2009/05/09 13:27:07 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/lrzsz/ChangeLog,v 1.20 2009/07/09 23:46:22 mrness Exp $
+
+*lrzsz-0.12.20-r3 (09 Jul 2009)
+
+  09 Jul 2009; Alin Năstac <mrness@g.o>
+  +files/lrzsz-autotools.patch, +lrzsz-0.12.20-r3.ebuild:
+  Use eautoreconf (#226789).
 
   09 May 2009; Alin Năstac <mrness@g.o> -lrzsz-0.12.20-r1.ebuild:
   Remove obsolete revision.



1.1                  net-dialup/lrzsz/lrzsz-0.12.20-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/lrzsz/lrzsz-0.12.20-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/lrzsz/lrzsz-0.12.20-r3.ebuild?rev=1.1&content-type=text/plain

Index: lrzsz-0.12.20-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/lrzsz/lrzsz-0.12.20-r3.ebuild,v 1.1 2009/07/09 23:46:22 mrness Exp $

EAPI="2"

inherit autotools flag-o-matic eutils toolchain-funcs

DESCRIPTION="Communication package providing the X, Y, and ZMODEM file transfer protocols"
HOMEPAGE="http://www.ohse.de/uwe/software/lrzsz.html"
SRC_URI="http://www.ohse.de/uwe/releases/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

DEPEND="nls? ( virtual/libintl )"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-autotools.patch
	epatch "${FILESDIR}"/${PN}-implicit-decl.patch

	# automake is unhappy if this is missing
	>> config.rpath
	# This is too old.  Remove it so automake puts in a newer copy.
	rm -f missing
	# Autoheader does not like seeing this file.
	rm -f acconfig.h

	eautoreconf
}

src_configure() {
	tc-export CC
	append-flags -Wstrict-prototypes
	econf $(use_enable nls) || die "econf failed"
}

src_test() {
	#Don't use check target.
	#See bug #120748 before changing this function.
	make vcheck || die "tests failed"
}

src_install() {
	emake \
		DESTDIR="${D}" \
		install || die "make install failed"

	local x
	for x in {r,s}{b,x,z} ; do
		dosym l${x} /usr/bin/${x}
		dosym l${x:0:1}z.1 /usr/share/man/man1/${x}.1
		[ "${x:1:1}" = "z" ] || dosym l${x:0:1}z.1 /usr/share/man/man1/l${x}.1
	done

	dodoc AUTHORS COMPATABILITY ChangeLog NEWS README* THANKS TODO
}