Gentoo Logo
Gentoo Spaceship




Note: Due to technical difficulties, the Archives are currently not up to date. GMANE provides an alternative service for most mailing lists.
c.f. bug 424647
List Archive: gentoo-commits
Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Headers:
To: gentoo-commits@g.o
From: "Anthony G. Basile (blueness)" <blueness@g.o>
Subject: gentoo-x86 commit in net-libs/axtls: axtls-1.4.6.ebuild ChangeLog metadata.xml
Date: Sat, 26 May 2012 05:58:11 +0000 (UTC)
blueness    12/05/26 05:58:11

  Added:                axtls-1.4.6.ebuild ChangeLog metadata.xml
  Log:
  Move from axTLS and version bump
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-libs/axtls/axtls-1.4.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/axtls-1.4.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/axtls-1.4.6.ebuild?rev=1.1&content-type=text/plain

Index: axtls-1.4.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/axtls/axtls-1.4.6.ebuild,v 1.1 2012/05/26 05:58:11 blueness Exp $

EAPI="4"

inherit savedconfig toolchain-funcs user

################################################################################
# axtls CONFIG MINI-HOWTO
#
# Note: axtls is highly configurable and uses mconf, like the linux kernel.
# You can configure it in a couple of ways:
#
# 1) USE="-savedconfig" and set/unset the remaining flags to obtain the features
# you want, and possibly a lot more.
#
# 2) You can create your own configuration file by doing
#
#	FEATURES="keepwork" USE="savedconfig -*" emerge axtls
#	cd /var/tmp/portage/net-libs/axtls*/work/axTLS
#	make menuconfig
#
# Now configure axtls as you want.  Finally save your config file:
#
#	cp config/.config /etc/portage/savedconfig/net-libs/axtls-${PV}
#
# where ${PV} is the current version.  You can then run emerge again with
# your configuration by doing
#
#	USE="savedconfig" emerge axtls
#
################################################################################

MY_PN=${PN/tls/TLS}

DESCRIPTION="Embedded client/server TLSv1 SSL library and small HTTP(S) server"
HOMEPAGE="http://axtls.sourceforge.net/"
SRC_URI="mirror://sourceforge/axtls/${MY_PN}-${PV}.tar.gz"
S="${WORKDIR}/${MY_PN}"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="httpd cgi-lua cgi-php static doc"

# TODO: add ipv6, and c#, java, lua, perl bindings
# Currently these all have some issue
DEPEND="doc? ( app-doc/doxygen )"
RDEPEND="
	httpd? (
		cgi-lua? ( dev-lang/lua )
		cgi-php? ( dev-lang/php[cgi] )
	)"

#Note1: static, cgi-* makes no sense if httpd is not given
REQUIRED_USE="
	static? ( httpd )
	cgi-lua? ( httpd )
	cgi-php? ( httpd )"

AXTLS_GROUP="axtls"
AXTLS_USER="axtls"

pkg_setup() {
	use httpd && {
		ebegin "Creating axtls user and group"
		enewgroup ${AXTLS_GROUP}
		enewuser ${AXTLS_USER} -1 -1 -1 ${AXTLS_GROUP}
	}
}

src_prepare() {
	tc-export CC

	#Use CC as the host compiler for mconf
	sed -i -e "s:^HOSTCC.*:HOSTCC=${CC}:" \
		"${S}"/config/Rules.mak

	#We want CONFIG_DEBUG to avoid stripping
	#but not for debugging info
	sed -i -e 's: -g::' \
		"${S}"/config/Rules.mak
	sed -i -e 's: -g::' \
		"${S}"/config/makefile.conf
}

use_flag_config() {
	cp "${FILESDIR}"/config "${S}"/config/.config

	#Respect CFLAGS/LDFLAGS
	sed -i -e "s:^CONFIG_EXTRA_CFLAGS_OPTIONS.*$:CONFIG_EXTRA_CFLAGS_OPTIONS=\"${CFLAGS}\":" \
		"${S}"/config/.config
	sed -i -e "s:^CONFIG_EXTRA_LDFLAGS_OPTIONS.*$:CONFIG_EXTRA_LDFLAGS_OPTIONS=\"${LDLAGS}\":" \
		"${S}"/config/.config

	#The logic is that the default config file enables everything and we disable
	#here with sed unless a USE flags says to keep it
	if use httpd; then
		if ! use static; then
			sed -i -e 's:^CONFIG_HTTP_STATIC_BUILD:# CONFIG_HTTP_STATIC_BUILD:' \
				"${S}"/config/.config
		fi
		if ! use cgi-php && ! use cgi-lua; then
			sed -i -e 's:^CONFIG_HTTP_HAS_CGI:# CONFIG_HTTP_HAS_CGI:' \
				"${S}"/config/.config
		fi
		if ! use cgi-php; then
			sed -i -e 's:,.php::' "${S}"/config/.config
		fi
		if ! use cgi-lua; then
			sed -i -e 's:\.lua,::' \
				-e 's:lua:php:' \
				-e 's:^CONFIG_HTTP_ENABLE_LUA:# CONFIG_HTTP_ENABLE_LUA:' \
				"${S}"/config/.config
		fi
	else
		sed -i -e 's:^CONFIG_AXHTTPD:# CONFIG_AXHTTPD:' \
			"${S}"/config/.config
	fi

	yes "n" | emake -j1 oldconfig > /dev/null
}

src_configure() {
	tc-export CC

	if use savedconfig; then
		restore_config config/.config
		if [ -f config/.config ]; then
			ewarn "Using saved config, all other USE flags ignored"
		else
			ewarn "No saved config, seeding with the default"
			cp "${FILESDIR}"/config "${S}"/config/.config
		fi
		yes "" | emake -j1 oldconfig > /dev/null
	else
		use_flag_config
	fi
}

src_compile() {
	default
	if use doc; then
		emake docs
		mv www README
	fi
}

src_install() {
	if use savedconfig; then
		save_config config/.config
	fi

	emake PREFIX="${ED}/usr" install
	if [ -f "${ED}"/usr/bin/htpasswd ]; then
		mv "${ED}"/usr/bin/{,ax}htpasswd
	fi

	if use httpd; then
		newinitd "${FILESDIR}"/axhttpd.initd axhttpd
		newconfd "${FILESDIR}"/axhttpd.confd axhttpd
	fi

	docompress -x /usr/share/doc/${PF}/README
	dodoc -r README

	if use doc; then
		dodoc -r docsrc/html
	fi
}



1.1                  net-libs/axtls/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-libs/axtls
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/axtls/ChangeLog,v 1.1 2012/05/26 05:58:11 blueness Exp $

*axtls-1.4.6 (26 May 2012)

  26 May 2012; Anthony G. Basile <blueness@g.o> +axtls-1.4.6.ebuild,
  +files/axhttpd.confd, +files/axhttpd.initd, +files/config, +metadata.xml:
  Move from axTLS and version bump

  07 Apr 2012; Anthony G. Basile <blueness@g.o> axTLS-1.4.5.ebuild,
  +files/axTLS-add-missing-include.patch:
  Add missing #include header for bigint_impl.h
  http://sourceforge.net/tracker/?func=detail&aid=3515628&group_id=171217&atid=
  857113

  07 Apr 2012; Anthony G. Basile <blueness@g.o> files/config:
  Increase max X509 CA certs and chain length to work with ca-certificates

  07 Apr 2012; Anthony G. Basile <blueness@g.o> axTLS-1.4.5.ebuild:
  Add missing depend on doxygen if USE=doc

*axTLS-1.4.5 (06 Apr 2012)

  06 Apr 2012; Anthony G. Basile <blueness@g.o> +axTLS-1.4.5.ebuild,
  +files/axhttpd.confd, +files/axhttpd.initd, +files/config, +metadata.xml:
  Initial commit




1.1                  net-libs/axtls/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/axtls/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <maintainer>
    <email>blueness@g.o</email>
    <name>Anthony G. Basile</name>
  </maintainer>
  <use>
    <flag name="httpd">Enables axhttpd web server component</flag>
    <flag name="static">Statically build axhttpd server</flag>
    <flag name="cgi-lua">Enables lua backed cgi for axhttpd server</flag>
    <flag name="cgi-php">Enables php backed cgi for axhttpd server</flag>
  </use>
</pkgmetadata>





Navigation:
Lists: gentoo-commits: < Prev By Thread Next > < Prev By Date Next >
Previous by thread:
gentoo-x86 commit in net-libs/axtls/files: - New directory
Next by thread:
gentoo-x86 commit in net-libs/axtls/files: axhttpd.confd config axhttpd.initd
Previous by date:
gentoo-x86 commit in net-libs/axtls/files: - New directory
Next by date:
gentoo-x86 commit in net-libs/axtls/files: axhttpd.confd config axhttpd.initd


Updated Jun 26, 2012

Summary: Archive of the gentoo-commits mailing list.

Donate to support our development efforts.

Copyright 2001-2013 Gentoo Foundation, Inc. Questions, Comments? Contact us.