[gentoo-commits] gentoo-x86 commit in app-pda/synce-core: synce-core-0.16.ebuild metadata.xml ChangeLog Manifest

[Samuli Suominen (ssuominen)]

ssuominen    12/06/15 07:52:42

  Added:                synce-core-0.16.ebuild metadata.xml ChangeLog
                        Manifest
  Log:
  Initial commit.
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-pda/synce-core/synce-core-0.16.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/synce-core-0.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/synce-core-0.16.ebuild?rev=1.1&content-type=text/plain

Index: synce-core-0.16.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/synce-core/synce-core-0.16.ebuild,v 1.1 2012/06/15 07:52:42 ssuominen Exp $

EAPI=4

PYTHON_DEPEND="python? 2:2.7"

inherit flag-o-matic python

DESCRIPTION="Base libraries, including RAPI protocol, tools and dccm daemon"
HOMEPAGE="http://sourceforge.net/projects/synce/"
SRC_URI="mirror://sourceforge/synce/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python static-libs"

# AC_PATH_PROG -> pppd -> net-dialup/ppp
# AC_PATH_PROG -> ifconfig -> sys-apps/net-tools
RDEPEND=">=dev-libs/dbus-glib-0.98
	>=dev-libs/glib-2.28
	!dev-libs/libsynce
	net-dialup/ppp
	sys-apps/net-tools
	|| ( >=sys-fs/udev-171-r6[gudev] <sys-fs/udev-171[extras] )
	python? ( >=dev-python/pyrex-0.9.6 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# AC_PATH_PROG -> dhclient ->
	local dhclient=true
	type -P dhclient >/dev/null && dhclient=dhclient
	sed -i -e "s:dhclient:${dhclient}:" configure || die
}

src_configure() {
	append-cflags -fno-strict-aliasing

	# hal OR udev -> udev -> dbus -> build all of odccm, udev, bluetooth
	econf \
		$(use_enable static-libs static) \
		--enable-dccm-file-support \
		--enable-odccm-support \
		--disable-hal-support \
		--enable-udev-support \
		--enable-bluetooth-support \
		$(use_enable python python-bindings)
}

src_install() {
	emake DESTDIR="${D}" install

	dodoc BUGS ChangeLog README* TODO
	newdoc bluetooth/README README.bluetooth

	# prune_libtool_files() from eutils.eclass fails wrt #421197
	find "${ED}" -name '*.la' -exec rm -f {} +

	# Always remove static archive from site-packages
	use static-libs && find "${ED}" -name pyrapi2.a -exec rm -f {} +
}



1.1                  app-pda/synce-core/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>pda</herd>
</pkgmetadata>



1.1                  app-pda/synce-core/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-pda/synce-core
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-pda/synce-core/ChangeLog,v 1.1 2012/06/15 07:52:42 ssuominen Exp $

*synce-core-0.16 (15 Jun 2012)

  15 Jun 2012; Samuli Suominen <ssuominen@g.o> +synce-core-0.16.ebuild:
  Initial commit.




1.1                  app-pda/synce-core/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-pda/synce-core/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST synce-core-0.16.tar.gz 703275 RMD160 7a352ff1c4a6db11622a2920114722405d12b703 SHA1 e74a35f410060b01eb0ac1e1ac4cfdf8a2a58d76 SHA256 e1b120bbbc9728b43ff4d3c82f521dd0e55560356c9e2ce2f059cc5f44edd641
EBUILD synce-core-0.16.ebuild 1855 RMD160 09c91229c853a6b261695e98f704cbda270bfbfa SHA1 2f49302798182ca47ebd87d91ef895f79fa78774 SHA256 44fe1dec6a708f20dd1c188b1640d32e80e11245c221984f83239ad91305e85b
MISC ChangeLog 249 RMD160 3eeef11147ecf082ccae45123e0b77b8d05f6d92 SHA1 d375c8c35e06dc5531f2e0f63aaa1968166ba96d SHA256 80b5c169c3c16fa4928eda70bdbe48f09d3e8729364d18aeb15127ce6fd911a3
MISC metadata.xml 156 RMD160 6a6d0f6bfe83e3a54c2d72444564ed6ab19857fe SHA1 5b9cb277159d763c133920e483df8d3d587cf7e2 SHA256 7f72b73f6e0d6e26603d85e52cca524711faddf6b516640104c3b82aab4754fb