[gentoo-commits] gentoo-x86 commit in dev-util/meld: meld-1.5.4.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       12/04/02 22:06:51

  Modified:             ChangeLog
  Added:                meld-1.5.4.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.10.54/cvs/Linux x86_64)

Revision  Changes    Path
1.138                dev-util/meld/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?rev=1.138&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?rev=1.138&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/ChangeLog?r1=1.137&r2=1.138

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v
retrieving revision 1.137
retrieving revision 1.138
diff -u -r1.137 -r1.138
--- ChangeLog	29 Jan 2012 10:54:23 -0000	1.137
+++ ChangeLog	2 Apr 2012 22:06:51 -0000	1.138
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/meld
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.137 2012/01/29 10:54:23 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.138 2012/04/02 22:06:51 pacho Exp $
+
+*meld-1.5.4 (02 Apr 2012)
+
+  02 Apr 2012; Pacho Ramos <pacho@g.o> +meld-1.5.4.ebuild:
+  Version bump.
 
 *meld-1.5.3 (29 Jan 2012)
 



1.1                  dev-util/meld/meld-1.5.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/meld-1.5.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/meld/meld-1.5.4.ebuild?rev=1.1&content-type=text/plain

Index: meld-1.5.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.5.4.ebuild,v 1.1 2012/04/02 22:06:51 pacho Exp $

EAPI="4"
GCONF_DEBUG="no"
PYTHON_DEPEND="2:2.5"

inherit python gnome2 eutils multilib

DESCRIPTION="A graphical diff and merge tool"
HOMEPAGE="http://meldmerge.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="doc gnome"

RDEPEND="
	>=dev-python/pygtk-2.14:2
	>=dev-python/pygobject-2.8:2
	gnome? ( >=dev-python/gconf-python-2.22:2 )
"
DEPEND="${RDEPEND}
	dev-util/intltool
	app-text/scrollkeeper"

pkg_setup() {
	DOCS="NEWS"
	# Needed for optimizing python modules against proper interpreter
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	gnome2_src_prepare

	# fix the prefix so its not in */local/*
	sed -e "s:/usr/local:${EPREFIX}/usr:" \
		-e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
		-i INSTALL || die "sed 1 failed"

	# don't install anything to /usr/share/doc/meld
	sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
		-i INSTALL || die "sed 2 failed"

	# let the python eclass handle python objects
	sed -e '/$(PYTHON) .* .import compileall;/s/\t/&#/g' \
		-i Makefile || die "sed 3 failed"

	# don't run scrollkeeper (with the wrong path),
	# leave that to gnome2.eclass #145833
	sed -e '/scrollkeeper-update/s/\t/&#/' \
		-i help/*/Makefile || die "sed 4 failed"

	# replace all calls to python by specific major version
	sed -e "s/\(PYTHON ?= \).*/\1$(PYTHON -2)/" \
		-i INSTALL || die "sed 6 failed"
	python_convert_shebangs 2 "${S}"/tools/*

	strip-linguas -i "${S}/po"
	local mylinguas=""
	for x in ${LINGUAS}; do
		mylinguas="${mylinguas} ${x}.po"
	done

	if [ -n "${mylinguas}" ]; then
		sed -e "s/PO:=.*/PO:=${mylinguas}/" \
			-i po/Makefile || die "sed 5 failed"
	fi
}

src_configure() {
	:
}

src_install() {
	gnome2_src_install
	python_convert_shebangs 2 "${ED}"usr/bin/meld
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_mod_optimize /usr/$(get_libdir)/meld
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/meld
}