[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-panel: ChangeLog gnome-panel-2.26.3.ebuild gnome-panel-2.26.1.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/07/09 21:14:08

  Modified:             ChangeLog
  Added:                gnome-panel-2.26.3.ebuild
  Removed:              gnome-panel-2.26.1.ebuild
  Log:
  Version bump. Raise dependency of gnome-desktop to 2.26, bug #272225. Small fixes, notably critical warning (bug #272012), translation updates.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.283                gnome-base/gnome-panel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?rev=1.283&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?rev=1.283&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?r1=1.282&r2=1.283

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v
retrieving revision 1.282
retrieving revision 1.283
diff -u -r1.282 -r1.283
--- ChangeLog	3 Jun 2009 23:09:10 -0000	1.282
+++ ChangeLog	9 Jul 2009 21:14:07 -0000	1.283
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.282 2009/06/03 23:09:10 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.283 2009/07/09 21:14:07 eva Exp $
+
+*gnome-panel-2.26.3 (09 Jul 2009)
+
+  09 Jul 2009; Gilles Dartiguelongue <eva@g.o>
+  -gnome-panel-2.26.1.ebuild, +gnome-panel-2.26.3.ebuild:
+  Version bump. Raise dependency of gnome-desktop to 2.26, bug #272225.
+  Small fixes, notably critical warning (bug #272012), translation updates.
 
   03 Jun 2009; Gilles Dartiguelongue <eva@g.o>
   gnome-panel-2.26.2.ebuild:



1.1                  gnome-base/gnome-panel/gnome-panel-2.26.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.26.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.26.3.ebuild?rev=1.1&content-type=text/plain

Index: gnome-panel-2.26.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.26.3.ebuild,v 1.1 2009/07/09 21:14:07 eva Exp $

EAPI="2"
GCONF_DEBUG="no"

inherit autotools eutils gnome2

MY_P="${PN}-2.24.2"
MY_P_PO="${PN}-2.26.1"
DESCRIPTION="The GNOME panel"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
	mirror://gentoo/${MY_P}-logout+po.tar.bz2
	mirror://gentoo/${MY_P_PO}-po.patch.bz2"

LICENSE="GPL-2 FDL-1.1 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc eds networkmanager policykit"

RDEPEND=">=gnome-base/gnome-desktop-2.26.0
	>=x11-libs/pango-1.15.4
	>=dev-libs/glib-2.18.0
	>=x11-libs/gtk+-2.15.1
	>=dev-libs/libgweather-2.24.1
	dev-libs/libxml2
	>=gnome-base/libglade-2.5
	>=gnome-base/libgnome-2.13
	>=gnome-base/libgnomeui-2.5.4
	>=gnome-base/libbonoboui-2.1.1
	>=gnome-base/orbit-2.4
	>=x11-libs/libwnck-2.19.5
	>=gnome-base/gconf-2.6.1
	>=gnome-base/gnome-menus-2.11.1
	>=gnome-base/libbonobo-2.20.4
	gnome-base/librsvg
	>=dev-libs/dbus-glib-0.71
	>=sys-apps/dbus-1.1.2
	x11-libs/libXau
	>=x11-libs/cairo-1.0.0
	eds? ( >=gnome-extra/evolution-data-server-1.6 )
	networkmanager? ( >=net-misc/networkmanager-0.6 )
	policykit? (
		>=sys-auth/policykit-0.7
		>=gnome-extra/policykit-gnome-0.7 )"
DEPEND="${RDEPEND}
	>=dev-lang/perl-5
	gnome-base/gnome-common
	>=app-text/gnome-doc-utils-0.3.2
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40
	~app-text/docbook-xml-dtd-4.1.2
	>=dev-util/gtk-doc-am-1
	doc? ( >=dev-util/gtk-doc-1 )"

DOCS="AUTHORS ChangeLog HACKING NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-static
		--disable-scrollkeeper
		--disable-schemas-install
		--with-in-process-applets=clock,notification-area,wncklet
		$(use_enable policykit polkit)
		$(use_enable networkmanager network-manager)
		$(use_enable eds)"
}

src_prepare() {
	gnome2_src_prepare

	# Allow logout/shutdown without gnome-session 2.24, bug #246170
	epatch "${WORKDIR}/${MY_P}-logout.patch"
	epatch "${WORKDIR}/${MY_P_PO}-po.patch"
	echo "gnome-panel/panel-logout.c" >> po/POTFILES.in

	# Fixes build on BSD, bug #256859
	epatch "${FILESDIR}/${PN}-2.24.3-daylight.patch"

	# Fixes shutdown without gdm, bug #259138
	epatch "${FILESDIR}/${PN}-2.24.3-shutdown.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"

	# FIXME: tarball generated with broken gtk-doc, revisit me.
	if use doc; then
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
			-i gtk-doc.make || die "sed 1 failed"
	else
		sed "/^TARGET_DIR/i \GTKDOC_REBASE=$(type -P true)" \
			-i gtk-doc.make || die "sed 2 failed"
	fi

	# Make it libtool-1 compatible, bug #271652
	rm -v m4/lt* m4/libtool.m4 || die "removing libtool macros failed"

	AT_M4DIR="m4" eautoreconf
}

pkg_postinst() {
	local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
	local gconftool="${ROOT}usr/bin/gconftool-2"

	if [ -e "$entries" ]; then
		einfo "setting panel gconf defaults..."

		GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"

		"${gconftool}" --direct --config-source \
			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
	fi

	# Calling this late so it doesn't process the GConf schemas file we already
	# took care of.
	gnome2_pkg_postinst
}