[gentoo-commits] gentoo-x86 commit in app-emulation/qemu: ChangeLog qemu-0.10.4.ebuild

[Luca Barbato (lu_zero)]

lu_zero     09/05/19 07:27:03

  Modified:             ChangeLog
  Added:                qemu-0.10.4.ebuild
  Log:
  New version
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.65                 app-emulation/qemu/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/qemu/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	17 May 2009 21:20:30 -0000	1.64
+++ ChangeLog	19 May 2009 07:27:03 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/qemu
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.64 2009/05/17 21:20:30 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.65 2009/05/19 07:27:03 lu_zero Exp $
+
+*qemu-0.10.4 (19 May 2009)
+
+  19 May 2009; Luca Barbato <lu_zero@g.o> +qemu-0.10.4.ebuild:
+  New version
 
   17 May 2009; Diego E. Pettenò <flameeyes@g.o> qemu-0.10.3.ebuild,
   +files/qemu-ifdown, +files/qemu-ifup:



1.1                  app-emulation/qemu/qemu-0.10.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/qemu/qemu-0.10.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/qemu/qemu-0.10.4.ebuild?rev=1.1&content-type=text/plain

Index: qemu-0.10.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-0.10.4.ebuild,v 1.1 2009/05/19 07:27:03 lu_zero Exp $

EAPI="2"

inherit eutils flag-o-matic toolchain-funcs linux-info

DESCRIPTION="QEMU emulator and ABI wrapper"
HOMEPAGE="http://www.qemu.org"
SRC_URI="http://download.savannah.gnu.org/releases/qemu/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="alsa esd gnutls ncurses pulseaudio +sdl vde kqemu kvm"

COMMON_TARGETS="i386 x86_64 arm cris m68k mips mipsel mips64 mips64el ppc ppc64 sh4 sh4eb sparc"

IUSE_SOFTMMU_TARGETS="${COMMON_TARGETS} ppcemb"
IUSE_USER_TARGETS="${COMMON_TARGETS} alpha armeb ppc64abi32 sparc64 sparc32plus"

for target in ${IUSE_SOFTMMU_TARGETS}; do
	IUSE="${IUSE} +qemu_softmmu_targets_${target}"
done

for target in ${IUSE_USER_TARGETS}; do
	IUSE="${IUSE} +qemu_user_targets_${target}"
done

RDEPEND="!app-emulation/qemu-softmmu
	!app-emulation/qemu-user
	!<app-emulation/qemu-0.10.3
	sys-libs/zlib
	alsa? ( >=media-libs/alsa-lib-1.0.13 )
	esd? ( media-sound/esound )
	pulseaudio? ( media-sound/pulseaudio )
	gnutls? ( net-libs/gnutls )
	ncurses? ( sys-libs/ncurses )
	sdl? ( >=media-libs/libsdl-1.2.11 )
	vde? ( net-misc/vde )
	kvm? ( >=sys-kernel/linux-headers-2.6.29 )
	kqemu? ( >=app-emulation/kqemu-1.4.0_pre1 )"
#	fdt? ( sys-apps/dtc )

DEPEND="${RDEPEND}
		gnutls? ( dev-util/pkgconfig )
		app-text/texi2html"

src_prepare() {
	# avoid fdt till an updated release appears
	sed -i -e 's:fdt="yes":fdt="no":' configure
	# prevent docs to get automatically installed
	sed -i '/$(DESTDIR)$(docdir)/d' Makefile
	# Alter target makefiles to accept CFLAGS set via flag-o
	sed -i 's/^\(C\|OP_C\|HELPER_C\)FLAGS=/\1FLAGS+=/' \
		Makefile Makefile.target tests/Makefile
	[[ -x /sbin/paxctl ]] && \
		sed -i 's/^VL_LDFLAGS=$/VL_LDFLAGS=-Wl,-z,execheap/' \
			Makefile.target
	# avoid strip
	sed -i 's/$(INSTALL) -m 755 -s/$(INSTALL) -m 755/' \
		Makefile Makefile.target */Makefile
	epatch "${FILESDIR}/${P}-nopl-fix.patch"
}

src_configure() {
	local mycc conf_opts audio_opts softmmu_targets user_targets target_list

	for target in ${IUSE_SOFTMMU_TARGETS} ; do
		use "qemu_softmmu_targets_${target}" && \
			softmmu_targets="${softmmu_targets} ${target}-softmmu"
	done

	for target in ${IUSE_USER_TARGETS} ; do
		use "qemu_user_targets_${target}" && \
			user_targets="${user_targets} ${target}-linux-user"
	done

	conf_opts="--disable-darwin-user --disable-bsd-user"

	if test ! -z "${softmmu_targets}" ; then
		einfo "Building following softmmu targets: ${softmmu_targets}"
		use gnutls || conf_opts="$conf_opts --disable-vnc-tls"
		use ncurses || conf_opts="$conf_opts --disable-curses"
		use sdl || conf_opts="$conf_opts --disable-gfx-check --disable-sdl"
		use vde || conf_opts="$conf_opts --disable-vde"
		use kqemu || conf_opts="$conf_opts --disable-kqemu"
		use kvm || conf_opts="$conf_opts --disable-kvm"

		audio_opts="oss"
		use alsa && audio_opts="alsa $audio_opts"
		use esd && audio_opts="esd $audio_opts"
		use pulseaudio && audio_opts="pa $audio_opts"
		use sdl && audio_opts="sdl $audio_opts"
	else
		einfo "Disabling softmmu emulation (no softmmu targets specified)"
		conf_opts="$conf_opts --disable-system --disable-vnc-tls \
		--disable-curses --disable-gfx-check --disable-sdl --disable-vde \
		--disable-kqemu --disable-kvm"
	fi

	if test ! -z "${user_targets}" ; then
		einfo "Building following user targets: ${user_targets}"
		conf_opts="$conf_opts --enable-linux-user"
	else
		einfo "Disabling usermode emulation (no usermode targets specified)"
		conf_opts="--disable-linux-user"
	fi

#	use fdt || conf_opts="$conf_opts --disable-fdt"

	conf_opts="$conf_opts --prefix=/usr --disable-bluez"

	target_list="${softmmu_targets} ${user_targets}"

	filter-flags -fpie -fstack-protector

	./configure ${conf_opts} \
		--audio-drv-list="$audio_opts" \
		--kerneldir="${KV_DIR}" \
		--cc=$(tc-getCC) --host-cc=$(tc-getCC) \
		--target-list="${target_list}" \
		|| die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	exeinto /etc/qemu
	doexe \
		"${FILESDIR}/qemu-ifup" \
		"${FILESDIR}/qemu-ifdown" \
		|| die "qemu interface scripts failed"

	dodoc pc-bios/README
	dodoc qemu-doc.html
	dodoc qemu-tech.html
}

pkg_postinst() {
	elog "You will need the Universal TUN/TAP driver compiled into your"
	elog "kernel or loaded as a module to use the virtual network device"
	elog "if using -net tap.  You will also need support for 802.1d"
	elog "Ethernet Bridging and a configured bridge if using the provided"
	elog "qemu-ifup script from /etc/qemu."
	echo
}