dev-zero    08/10/15 10:22:58

  Modified:             ChangeLog
  Added:                xerces-c-3.0.0.ebuild
  Removed:              xerces-c-3.0.0_beta2.ebuild
  Log:
  Version bump (bug #240424).
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27 x86_64)

Revision  Changes    Path
1.65                 dev-libs/xerces-c/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	12 Oct 2008 14:19:16 -0000	1.64
+++ ChangeLog	15 Oct 2008 10:22:58 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/xerces-c
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.64 2008/10/12 14:19:16 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.65 2008/10/15 10:22:58 dev-zero Exp $
+
+*xerces-c-3.0.0 (15 Oct 2008)
+
+  15 Oct 2008; Tiziano Müller <dev-zero@g.o>
+  -xerces-c-3.0.0_beta2.ebuild, +xerces-c-3.0.0.ebuild:
+  Version bump (bug #240424).
 
   12 Oct 2008; nixnut <nixnut@g.o> xerces-c-2.8.0-r1.ebuild:
   Stable on ppc wrt bug 241500



1.1                  dev-libs/xerces-c/xerces-c-3.0.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.0.ebuild?rev=1.1&content-type=text/plain

Index: xerces-c-3.0.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-3.0.0.ebuild,v 1.1 2008/10/15 10:22:58 dev-zero Exp $

EAPI="1"

inherit eutils

DESCRIPTION="A validating XML parser written in a portable subset of C++."
HOMEPAGE="http://xerces.apache.org/xerces-c/"
SRC_URI="mirror://apache/xerces/c/sources/${P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="curl debug doc iconv icu libwww +threads elibc_Darwin elibc_FreeBSD"

RDEPEND="icu? ( <dev-libs/icu-3.8 )
	curl? ( net-misc/curl )
	libwww? ( net-libs/libwww )
	virtual/libiconv"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${P}

pkg_setup() {
	export ICUROOT="/usr"

	if use iconv && use icu ; then
		ewarn "This package can use iconv or icu for loading messages"
		ewarn "and transcoding, but not both. ICU will precede."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# disable building broken samples
	sed -i \
		-e 's|src tests samples|src tests|' \
		Makefile.in || die "sed failed"

	sed -i \
		-e 's|$(prefix)/msg|$(DESTDIR)/$(prefix)/share/xerces-c/msg|' \
		src/xercesc/util/MsgLoaders/MsgCatalog/Makefile.in || die "sed failed"
}

src_compile() {
	local mloader="inmemory"
	use iconv && mloader="iconv"
	use icu && mloader="icu"

	local transcoder="gnuiconv"
	use elibc_FreeBSD && transcoder="iconv"
	use elibc_Darwin && transcoder="macosunicodeconverter"
	use icu && transcoder="icu"

	# 'cfurl' is only available on OSX and 'socket' isn't supposed to work.
	# But the docs aren't clear about it, so we would need some testing...
	local netaccessor="socket"
	use elibc_Darwin && netaccessor="cfurl"
	use libwww && netaccessor="libwww"
	use curl && netaccessor="curl"

	econf \
		$(use_enable debug) \
		$(use_enable threads) \
		--enable-msgloader-${mloader} \
		--enable-netaccessor-${netaccessor} \
		--enable-transcoder-${transcoder} \
		|| die "econf failed"

	emake || die "emake failed"

	if use doc ; then
		cd "${S}/doc"
		doxygen || die "making docs failed"
	fi
}

src_install () {
	emake DESTDIR="${D}" install || die "emake failed"

	cd "${S}"
	doenvd "${FILESDIR}/50xerces-c"

	if use doc; then
		insinto /usr/share/doc/${PF}
		rm -rf samples/config* samples/Makefile* samples/runConfigure samples/install-sh samples/*/Makefile*
		doins -r samples
		dohtml -r doc/html/*
	fi

	dodoc CREDITS KEYS NOTICE README version.incl
}