[gentoo-commits] gentoo-x86 commit in app-editors/bluefish: ChangeLog bluefish-2.0.0_rc3.ebuild bluefish-2.0.0_rc1.ebuild bluefish-2.0.0_rc2.ebuild

[Daniel Pielmeier (billie)]

billie      10/02/02 18:25:03

  Modified:             ChangeLog
  Added:                bluefish-2.0.0_rc3.ebuild
  Removed:              bluefish-2.0.0_rc1.ebuild bluefish-2.0.0_rc2.ebuild
  Log:
  Version bump. Remove old.
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.69                 app-editors/bluefish/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.69&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.69&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?r1=1.68&r2=1.69

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v
retrieving revision 1.68
retrieving revision 1.69
diff -u -r1.68 -r1.69
--- ChangeLog	25 Jan 2010 22:30:26 -0000	1.68
+++ ChangeLog	2 Feb 2010 18:25:02 -0000	1.69
@@ -1,6 +1,13 @@
 # ChangeLog for app-editors/bluefish
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.68 2010/01/25 22:30:26 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.69 2010/02/02 18:25:02 billie Exp $
+
+*bluefish-2.0.0_rc3 (02 Feb 2010)
+
+  02 Feb 2010; Daniel Pielmeier <billie@g.o>
+  -bluefish-2.0.0_rc1.ebuild, -bluefish-2.0.0_rc2.ebuild,
+  +bluefish-2.0.0_rc3.ebuild:
+  Version bump. Remove old.
 
 *bluefish-2.0.0_rc2 (25 Jan 2010)
 



1.1                  app-editors/bluefish/bluefish-2.0.0_rc3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc3.ebuild?rev=1.1&content-type=text/plain

Index: bluefish-2.0.0_rc3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc3.ebuild,v 1.1 2010/02/02 18:25:02 billie Exp $

EAPI=2

inherit autotools eutils fdo-mime

IUSE="gucharmap nls python spell"

MY_P=${P/_/-}

DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
SRC_URI="http://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
HOMEPAGE="http://bluefish.openoffice.nl/"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"

RDEPEND="
	dev-libs/libpcre
	x11-libs/gtk+:2
	spell? ( app-text/enchant[aspell] )"

DEPEND="${RDEPEND}
	dev-libs/glib:2
	dev-libs/libxml2
	dev-util/pkgconfig
	x11-libs/pango
	gucharmap? ( gnome-extra/gucharmap )
	nls? ( sys-devel/gettext dev-util/intltool )
	python? ( dev-lang/python )"

S=${WORKDIR}/${MY_P}

src_prepare () {
	# Fixes automagic installation of charmap plugin
	# Upstream bug: https://bugzilla.gnome.org/show_bug.cgi?id=570990
	epatch "${FILESDIR}"/${PN}-2.0.0_rc1-gucharmap-automagic.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-update-databases \
		--disable-xml-catalog-update \
		--enable-splash-screen \
		$(use_enable nls) \
		$(use_enable spell spell-check) \
		$(use_enable gucharmap charmap) \
		$(use_enable python)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	einfo "Adding XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
		--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
		--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
		/etc/xml/catalog \
		|| ewarn "Failed to add XML catalog entries."
}

pkg_postrm() {
	einfo "Removing XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--del 'Bluefish/DTD/Bflang' \
		--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
		--del 'http://bluefish.openoffice.nl/DTD' \
		/etc/xml/catalog \
		|| ewarn "Failed to remove XML catalog entries."
}