[gentoo-commits] gentoo-x86 commit in app-admin/abrt: abrt-2.0.6.ebuild ChangeLog metadata.xml

[Alexandre Rostovtsev (tetromino)]

tetromino    11/11/16 07:44:24

  Added:                abrt-2.0.6.ebuild ChangeLog metadata.xml
  Log:
  Add Fedora's automatic crash reporter tool from the gnome overlay.
  
  (Portage version: 2.2.0_alpha74/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-admin/abrt/abrt-2.0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/abrt-2.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/abrt-2.0.6.ebuild?rev=1.1&content-type=text/plain

Index: abrt-2.0.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/abrt/abrt-2.0.6.ebuild,v 1.1 2011/11/16 07:44:24 tetromino Exp $

PYTHON_DEPEND="2:2.6"
EAPI="4"

# Need gnome2-utils for gnome2_icon_cache_update
inherit autotools eutils gnome2-utils python systemd

DESCRIPTION="Automatic bug detection and reporting tool"
HOMEPAGE="https://fedorahosted.org/abrt/"
SRC_URI="https://fedorahosted.org/released/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

COMMON_DEPEND="dev-libs/btparser
	>=dev-libs/glib-2.21:2
	dev-libs/libreport
	dev-libs/libxml2
	dev-libs/nss
	sys-apps/dbus
	sys-fs/inotify-tools
	x11-libs/gtk+:2
	x11-libs/libnotify"
RDEPEND="${COMMON_DEPEND}
	app-arch/cpio
	dev-libs/elfutils
	sys-devel/gdb"
DEPEND="${COMMON_DEPEND}
	app-text/asciidoc
	app-text/xmlto
	>=dev-util/intltool-0.35.0
	>=dev-util/pkgconfig-0.9.0
	>=sys-devel/gettext-0.17"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup

	enewgroup abrt
	enewuser abrt -1 -1 -1 abrt
}

src_prepare() {
	# Disable redhat-specific code not usable in gentoo, or that requires
	# bugs.gentoo.org infra support.
	epatch "${FILESDIR}/${PN}-2.0.6-gentoo.patch"

	# Using a server response as a format string is a bad idea
	epatch "${FILESDIR}/${PN}-2.0.6-format-security.patch"

	# Fixes building with glib-2.31, will be in next release
	epatch "${FILESDIR}/${P}-glib-2.31.patch"

	# -Werror should not be used by default
	sed -e 's/-Werror\( \|$\)//g' \
		-i src/applet/Makefile.* src/cli/Makefile.* src/daemon/Makefile.* \
		   src/gui-gtk/Makefile.* src/hooks/Makefile.* src/lib/Makefile.* \
		   src/plugins/Makefile.* || die "sed failed"

	mkdir m4
	eautoreconf

	ln -sfn $(type -P true) py-compile
	python_convert_shebangs -r 2 src
}

src_configure() {
	# Configure checks for python.pc; our python-2.7 installs python-2.7.pc,
	# while python-2.6 does not install any pkgconfig file.
	export PYTHON_CFLAGS=$(python-config --includes)
	export PYTHON_LIBS=$(python-config --libs)

	myeconfargs=( "--localstatedir=${EPREFIX}/var" )
	# --disable-debug enables debug!
	use debug && myeconfargs=( "${myeconfargs[@]}" --enable-debug )
	systemd_to_myeconfargs
	econf "${myeconfargs[@]}"
}

src_install() {
	default

	keepdir /var/run/abrt
	# /var/spool/abrt is created by dev-libs/libreport

	diropts -m 700 -o abrt -g abrt
	keepdir /var/spool/abrt-upload

	diropts -m 775 -o abrt -g abrt
	keepdir /var/cache/abrt-di

	find "${D}" -name '*.la' -exec rm -f {} + || die

	newinitd "${FILESDIR}/${PN}-2.0.5-init" abrt
	newconfd "${FILESDIR}/${PN}-2.0.5-conf" abrt
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	python_mod_optimize abrt_exception_handler.py
	elog "To start the bug detection service on an openrc-based system, do"
	elog "# /etc/init.d/abrt start"
}

pkg_postrm() {
	gnome2_icon_cache_update
	python_mod_cleanup abrt_exception_handler.py
}



1.1                  app-admin/abrt/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-admin/abrt
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/abrt/ChangeLog,v 1.1 2011/11/16 07:44:24 tetromino Exp $

*abrt-2.0.6 (16 Nov 2011)

  16 Nov 2011; Alexandre Rostovtsev <tetromino@g.o>
  +files/abrt-2.0.5-conf, +files/abrt-2.0.5-init, +abrt-2.0.6.ebuild,
  +files/abrt-2.0.6-format-security.patch, +files/abrt-2.0.6-gentoo.patch,
  +files/abrt-2.0.6-glib-2.31.patch, +metadata.xml:
  Add Fedora's automatic crash reporter tool from the gnome overlay.




1.1                  app-admin/abrt/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/abrt/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>gnome</herd>
</pkgmetadata>